Discussion :

[AltusXL]

Bonjour à tous,

Je fais partis d'un atelier où chaque semaine, nous surveillons plusieurs points clés.
Afin de capitaliser le résultat de cette surveillance, j'ai donc créer un fichier excel.

Comme vous pourrez le voir dans ce fichier, 6 thèmes majeurs sont surveillés (contenant chacun plusieurs items notés avec la note de 1 ou 0), et 2 thèmes sont évalués par semaine.

Afin d'exploiter ces données, j'ai décider de calculer la valeur moyenne à l'année de chaque item (facile à faire) mais aussi de faire la valeur moyenne sur les 3 derniers passages (à peu près 2 mois glissant). Et c'est précisément là que j'ai besoin de votre aide.

Je ne parviens pas à trouver une formule capable de le faire, et mes connaissances en Excel sont limités à ce sujet. Savez-vous m'aidez ?

Merci à vous.

[jerome.vaussenat]

Salut,

Si j'ai bien compris, c'est en BF que tu veux la moyenne des 3 dernières valeurs saisies dans le grand tableau placé à gauche.

Je te propose cette formule à mettre en BF18:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOYENNE(DECALER(BE18;0;-(COLONNE()-EQUIV(9^9;A18:BC18)+6);1;8))

Pour comprndre ce qui est fait :
COLONNE() permet de connaitre le N° de la colonne où la formule est ecrite (ici, BF est la 58eme colonne)
EQUIV(9^9;A18:BC18) permet de connaitre la dernière colonne avec un contenu. Dans le cas de ton tableau, pour la ligne 18, c'est la colonne AD N° 33.

DECALER permet de créer une zone qui varie en fonction des éléments décrits ci-dessus. En gros, je créé une sélection de 1 ligne de haut, 8 colonnes de large. Cette zone se DECALE en fonction de la saisie faite à coté.
Et on fait une MOYENNE utilisant cette zone variable de 8 cellules.

En espérant que ç'est ce que tu veux faire.

[papouclo]

Bonjour,
Une autre proposition que celle de Jérôme.
J'ai donné le nom dates à la plage $D$3:$BC$3.
Se placer en BF18 (ou en n'imorte quelle cellule de la ligne 18) et définir les noms :
fin (date du dernier passage) par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=GRANDE.VALEUR((Data!$D18:$BC18<>"")*dates;1)

debut (date de l'antépénultième passage) par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=GRANDE.VALEUR((Data!$D18:$BC18<>"")*dates;3)

J'ai défini ici le nom debut en m'inspirant de la demande (troisième passage en partant de la fin) mais en s'appuyant sur le titre "deux mois glissant", on pourrait écrire pour définir debut :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOIS.DECALER(fin;-2)

On peut écire en BF18 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOYENNE.SI.ENS($D18:$BC18;dates;">="&debut;dates;"<="&fin)

à condition que la fonction MOYENNE.SI.ENS soit définie sinon on pourra écrire la formule:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS($D18:$BC18;dates;">="&debut;dates;"<="&fin)/3

La formule choisie se recopie vers le bas en colonne BF.
Cordialement
Claude

[78chris]

Bonjour

Question posée sur plusieurs forums mais AltusXl ne repasse plus...

[AltusXL]

Bonjour,

un grand merci à Jérôme, grâce à sa réactivité j'ai pu résoudre mon problème très rapidement (1h après le post).
En outre, je garde en réserve la technique de Papouclo qui pourra m'aider sur un fichier excel un peu plus complexe que je suis en train de développer.
@Chris, effectivement je passe sur plusieurs forum, je ne connais pas forcément la popularité de tel ou tel forum excel sur le net, donc je maximise mes chances

Merci à tous en tous les cas, continuez ainsi. C'est grâce à vous que l'on avance.

Bonne journée.