Discussion :

[maroonx]

Bonjour tout le monde,

J'ai déjà vu plusieurs sujets sur la question mais je n'arrive à faire ce que je veux.
Selectionner les cellules de la colonne 1 qui contiennent la chaine de caractère "AAA" si l'une des cellules de la ligne corresponde contient la valeur "1".

Pour l'instant j'en suis là mais ça nne fonctionne pas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub ITK()
Dim DAT, PLANT As Range
Dim d, p As Range
 
derlig = Sheets("Feuil1").Cells(Rows.Count, "A").End(xlUp).Row
 
Set DAT = Range(Cells(2, 1), Cells(derlig, 1))
Set PLANT = Range(Cells(2, 2), Cells(derlig, 13))
 
For Each d In DAT
    For Each p In PLANT
 
If d.Value Like "*ANT*" And p.Value = "1" Then
 
d.Select
 
End If
 
    Next
Next
 
End Sub

Merci beaucoup à la personne qui pourra m'aider!!!

[unparia]

Bonjour
Déjà :

si l'une des cellules de la ligne corresponde contient la valeur "1"

tu peux donc utiliser Worksheetfunction.countif pour voir si cette condition est vérifiée, non ?

[parmi]

Bonjour,

Si j'ai bien compris, tu pourrais te mettre une formule RechercheV (ou NB.SI) dans une colonne vide à droite pour rechercher la valeur 1 dans la ligne.
Il te suffira à faire un filtre sur AAA dans la colonne A et sur 1 dans cette colonne.

Edit: je n'avais pas vu ta réponse unparia... On se rejoint tout de même dans l'idée...

[Pierre Fauconnier]

Salut.

VBA pour Excel => D'abord penser à Excel... Observe le tableau suivant qui montre que l'on peut s'en sortir par une formule... (La colonne O n'est là que pour illustrer la construction de la formule)



Dès lors, on peut utiliser Evaluate en VBA...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Colorer()
  Dim xCell As Range
 
  For Each xCell In Range(Range("a2"), Range("a1048576").End(xlUp))
    If Evaluate("and(iferror(search(""ANT""," & xCell.Address & "),false),countif(" & xCell.Offset(0, 1).Resize(1, 12).Address & ",1)>0)") = True Then xCell.Interior.Color = vbRed
  Next xCell
End Sub

Tu peux aussi utiliser ceci, qui utilise ton LIKE et dont la philosophie est la même que pour l'exemple ci-dessus, mais sans Evaluate, en utilisant la fonction Countifs de Application (ou Application.WorksheetFunction) et qui demande peut-être moins de traitement...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub AuteSolution()
  Dim xCell As Range
  Dim Result As Range
  For Each xCell In Range(Range("a2"), Range("a1048576").End(xlUp))
    If xCell.Value Like "*ANT*" And Application.CountIfs(xCell.Offset(0, 1).Resize(1, 12), 1) > 0 Then xCell.Interior.Color = vbRed
  Next xCell
End Sub

Cela étant, tu veux les colorer ou les sélectionner?

Si tu veux les sélectionner, tu peux utiliser

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Selectioner()
  Dim xCell As Range
  Dim Result As Range
  For Each xCell In Range(Range("a2"), Range("a1048576").End(xlUp))
    If Evaluate("and(iferror(search(""ANT""," & xCell.Address & "),false),countif(" & xCell.Offset(0, 1).Resize(1, 12).Address & ",1)>0)") = True Then
      If Result Is Nothing Then
        Set Result = xCell
      Else
        Set Result = Union(Result, xCell)
      End If
    End If
  Next xCell
  If Not Result Is Nothing Then Result.Select
End Sub

Sans VBA...

Si tu dois colorer les cellules, tu pourrais aussi, sans VBA, utiliser une Mise en Forme Conditionnelle formulée en utilisant la formule en O2 dans une MFC formulée sur A2:A12 (dans l'illustration ci-dessus).

Tu vois qu'il y a plusieurs solutions en fonction du résultat final que tu souhaites obtenir...

[maroonx]

Bonjour,

Vraiment merci pour vos réponses!!

@Parmi En fait c'est une partie de ce que je souhaite faire et comme je sais que la suite ne peux pas se faire avec excel donc je me suis dis que c'est mieux de faire comme ça...

@unparia J'ai essayé avec la fonction Worksheetfuntion.countif mais ça me donne le même résultat!

@Pierre Fauconnier Le code marche! mais je suis entrain de l'analyser car je ne l'ai pas encore bien compris!

Ce que je cherche à faire est un peu plus compliqué! Donc je regarde si avec vos réponses j'arrive à m'en sortir! Avant de valider la discussion...

Merci encore!!

[maroonx]

Re-bonjour,

Merci pour la solution avec "like" car je n'ai pas encore bien compris la fonction "evaluate" et je trouve peu de chose sur internet (utilisé comme ça) pour le moment.

Si c'est possible je me permets d'exposer la deuxième et dernière partie de mon problème, j'ai mis une image car c'est un peu compliqué à expliquer:

En fait sur l'image la ligne 2 réponds aux deux conditions ("ANT" + "1"), alors je dois chercher la condition suivante : présence de "TAR" dans la colonne1.
Comme la deuxième cellule répond à cette condition: alors entrer "1" dans la cellule .offset(0, 3) à partir du numéro de colonne de la cellule contenant "1" à la ligne2.

C'est un exemple sur deux lignes mais je dois le faire pour un grand tableau et pour différentes conditions. Les conditions sont liées: ici j'applique à "TAR" la formule si "ANT"+"1" est vérifié.
Est-ce que c'est possible de savoir si le code que tu m'as donné est un bon début, et avoir quelques indications pour la suites?

En tout cas merci encore!