Discussion :

[jireu]

Bonjour à vous,

Tout nouveau sur ce forum et ne travaillant pas dans le domaine de la programmation (Architecte), Je viens quérir votre aide car je réalise un petit batch pour nettoyer des fichiers de sauvegarde et je rencontre une difficulté à différencier certain fichiers.

la forme de l’appellation des fichiers : "ABCD0.0.0.RVT" qui est le fichier principal et "ABCD0.0.0.0000.RVT" qui est le fichier de sauvegarde intermédiaire.
ABCD le nom du fichier
0.0.0 la date du fichier (qui n'est pas présente dans toute les nommages)
.0000 le numéro de sauvegarde intermédiaire
.rvt l'extension

je souhaite repérer et supprimer les fichiers de sauvegarde intermédiaires mais je n'arrive pas à les différencier des fichiers ayant juste une date.

pour l'instant mon batch se présente ainsi:

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
@echo off
set TOTAL=0
set NB=0
for /r  %%X in (*.0*.rvt) do (
	echo %%~nX
	set /a NB+=1
	set /a TOTAL+=%%~zX / 1000000
)
echo nombre de fichier de sauvegarde    : %NB%
echo Taille totale : %TOTAL% Mo
set /p choix=Voulez vous vraiment effacer ces fichiers(O/N) ? :
 
if /I "%choix%"=="O" (goto :oui)
if /I "%choix%"=="N" (goto :non)
 
:oui
 echo SUPRESSION DES FICHIERS
 del /s *.0*.rvt
:non
 goto :EOF

Étant assez léger en programmation, je ne vois pas comment réussir ...

merci d'avance pour vos retours

[cerede2000]

Bonjour à toi,
Afin d'être sur du format précis pourrais tu mettre quelques vrais non de fichiers ?
ABCD, est-ce que c'est toujours sur 4 ? Ou ça peut être plus ?
La date 0.0.0 j'imagine que c'est en fait genre 01.10.16 ?

Bref avec des vrais valeurs ça permettrai de faire un filtre regex plus précis

[jireu]

Bonjour,

c'est vrai que de vrais noms seront plus parlant

TARBES Phases 09.03.16.rvt
TARBES Phases 09.03.16.0012.rvt
NANCY APS.rvt
NANCY APS.0002.rvt
NANCY APS V2.rvt
etc...
donc pour répondre à tes interrogations,
la partie alphabétique n'est jamais de même taille,
le format de date est tel que tu le décris, mis à par qu'elle n'est pas présente dans tout les cas
le numéro de sauvegarde intermédiaire est toujours basé sur 4 chiffres.

Cordialement,

[cerede2000]

Ah en effet c'est mieux !
Alors je te propose ceci :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

dir /s/b | findstr /i /r "\.[0-9][0-9][0-9][0-9]\.rvt$"

Confirme moi que que ca te liste bien QUE les fichier intermédiaire que tu souhaites supprimer

L'idée est celle que tu à tenté au départ mais qui n'est pas faisable comme tu le pensait
On liste les fichier qui répondent au format *.0000.rvt

Du coup pour supprimer après :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

FOR /f "usebackq delims=" %i IN (`dir /s/b ^| findstr /i /r "\.[0-9][0-9][0-9][0-9]\.rvt$"`) DO DEL "%i"

Attention dans un fichier batch il faut doubler les %%:

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

FOR /f "usebackq delims=" %%i IN (`dir /s/b ^| findstr /i /r "\.[0-9][0-9][0-9][0-9]\.rvt$"`) DO DEL "%%i"

Je vais mettre ça de côté, on commente tout juste à bosser avec Revit dans ma boite (metallerie/serrurie) mais ça va finir par me servir

PS : Penser à quand les réponses te conviennent

[jireu]

je test ça et je reviens te dire ce qu'il en est

[jireu]

cette commande fonctionne donc très bien. merci à toi !

challenge supplémentaire : comment effectuer en plus une recherche des fichiers contenant la chaîne "obsolete". peut on rajouter cette recherche dans le même dir ou faut-il créer une commande supplémentaire.

cordialement,

[cerede2000]

Pffff les regex de FINDSTR étant super limité il faut en effet une autre recherche.

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

dir /s/b | findstr /i "obsolete"

[jireu]

et bien tout fonctionne superbement.
merci pour ce code

j'essai d'apprendre le fonctionnement de usebackq delims du coup

[cerede2000]

Pour les explication usebackq et delim : http://ss64.com/nt/for_cmd.html
En fait usebackq sert pour les chemin et nom de fichier qui aurait des espaces, cela permet de les placer entre quotes.
Et delim également, car par défaut le délimiteur est espace, donc on obtient qu'un seul morceau du nom et il faut alors utiliser plusieurs variables.