Discussion :

[ExcelLiod]

Bonjour à tous !

Je chercherai à faire une macro VBA qui me permettrait de pouvoir marquer des informations sur plusieurs fichiers présents dans un répertoire bien défini selon les informations et critères présents dans un fichier (voir fichier Macrodiligences.xlm ci-joint).

Je pense avoir déjà quelques indications pour réaliser cette macro, mais comme je suis vraiment débutant en vba c'est assez confus dans ma tête .

Alors premièrement pour que la macro trouve l'endroit où sont les fichiers à modifier je pensais utiliser un code dans ce style :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

chem = "Z:\SAUV2016\DILIG2016\

les fichiers à modifier se trouve dans la colonne "FICHIER DILIGENCE" présent colonne D du fichier [attachment=1]MacroDiligences.xlsm[/attachment]. Donc il faudrait que la macro ouvre ces fichiers un par un. Inscrive les données présents dans les colonnes A, B et E. Pour exemple de la colonne A le code je pensais à un truc du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
L = Sheets("Modele").Range("A65536").End(xlUp).Row 
Sheets("Modele").Range("A" & L + 1) = "L'information présent dans la colonne date"

Vous pouvez voir un exemple du 1er fichier à modifier dans l'exemple (fichier ronald.xls ci-joint).

Je voudrais juste que la macro ne fasse pas des modifs de fichier quand il y a une croix dans la colonne C "Clos"

Merci d'avance pour votre aide.

[Neutthsch]

Salut ExcelLiod,

Pour ce qui est de la manipulation des fichiers je te conseille ce tuto.
Lis ça tranquillement, fait des essais et reviens dans le coin si t'as toujours besoin d'aide.

ATTENTION : Je conseille la manipulation de fichier en mode bac à sable. Tu créés un dossier fictif avec des fichiers fictifs et tu ne travailles que sur cette destination pour t’entraîner. Tu ne changeras le chemin d’accès qu'une fois le code maîtrisé. on a vite fait d'altérer des données avec codes là

[joe.levrai]

Bonjour,

si le nom des fichiers est intégralement écrit dans une colonne de son fichier Excel, il ne me semble pas nécessaire de boucler sur la liste des fichier avec FSO ?

voici un exemple pas super optimisé, à bien sûr adapter :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Sub MesEcrits()
Dim CELL_SOURCE As Range
Dim WB_DEST As Workbook
Dim CELL_DEST As Range
Dim PLAGE_SOURCE As Range
Const CHEMIN_DOSSIER As String = "Z:\SAUV2016\DILIG2016\"
 
Application.ScreenUpdating = False
 
With ThisWorkbook.Worksheets("Feuil1")
    'filtre automatique pour ne prendre que les lignes sans X en colonne C
    With .Range("A1")
        .AutoFilter
        .AutoFilter 3, "<>X"
    End With
 
    'l'ensemble des lignes non clôturées
    Set PLAGE_SOURCE = .UsedRange.Columns(1).SpecialCells(xlCellTypeVisible)
End With
 
' boucle sur chaque ligne
For Each CELL_SOURCE In PLAGE_SOURCE.Cells
    If CELL_SOURCE.Row > 1 And CELL_SOURCE.Offset(0, 3).Value <> "" Then
        ' ouverture du fichier
        Set WB_DEST = Workbooks.Open(CHEMIN_DOSSIER & CELL_SOURCE.Offset(0, 3).Value)
 
        With WB_DEST.Worksheets("Modele")
            ' positionnement sur la première ligne vide en colonne A
            Set CELL_DEST = .Cells(.Rows.Count, 1).End(xlUp)(2)
        End With
 
        ' écriture des données
        With CELL_DEST
            .Value = CELL_SOURCE.Value
            .Offset(0, 1).Value = CELL_SOURCE.Offset(0, 1).Value
            .Offset(0, 2).Value = CELL_SOURCE.Offset(0, 4).Value
        End With
 
        ' si tu veux marquer un "X" sur la ligne que tu viens d'écrire
        CELL_SOURCE.Offset(0, 2).Value = "X"
 
        ' fermeture et sauvegarde du fichier
        WB_DEST.Close True
    End If
Next CELL_SOURCE
 
 
With ThisWorkbook
    ' retrait du filtre automatique
    .Worksheets("Feuil1").Range("A1").AutoFilter
    ' enregistrement
    .Save
End With
 
Application.ScreenUpdating = True
End Sub

il est IMPORTANT que le nom du fichier dans ta colonne D :

- soit bien écrit
- comporte l'extension (.xls ou .xlsx ou .xlsm etc...)

[ExcelLiod]

Bonjour,

si le nom des fichiers est intégralement écrit dans une colonne de son fichier Excel, il ne me semble pas nécessaire de boucler sur la liste des fichier avec FSO ?

voici un exemple pas super optimisé, à bien sûr adapter :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Sub MesEcrits()
Dim CELL_SOURCE As Range
Dim WB_DEST As Workbook
Dim CELL_DEST As Range
Dim PLAGE_SOURCE As Range
Const CHEMIN_DOSSIER As String = "Z:\SAUV2016\DILIG2016\"
 
Application.ScreenUpdating = False
 
With ThisWorkbook.Worksheets("Feuil1")
    'filtre automatique pour ne prendre que les lignes sans X en colonne C
    With .Range("A1")
        .AutoFilter
        .AutoFilter 3, "<>X"
    End With
 
    'l'ensemble des lignes non clôturées
    Set PLAGE_SOURCE = .UsedRange.Columns(1).SpecialCells(xlCellTypeVisible)
End With
 
' boucle sur chaque ligne
For Each CELL_SOURCE In PLAGE_SOURCE.Cells
    If CELL_SOURCE.Row > 1 And CELL_SOURCE.Offset(0, 3).Value <> "" Then
        ' ouverture du fichier
        Set WB_DEST = Workbooks.Open(CHEMIN_DOSSIER & CELL_SOURCE.Offset(0, 3).Value)
 
        With WB_DEST.Worksheets("Modele")
            ' positionnement sur la première ligne vide en colonne A
            Set CELL_DEST = .Cells(.Rows.Count, 1).End(xlUp)(2)
        End With
 
        ' écriture des données
        With CELL_DEST
            .Value = CELL_SOURCE.Value
            .Offset(0, 1).Value = CELL_SOURCE.Offset(0, 1).Value
            .Offset(0, 2).Value = CELL_SOURCE.Offset(0, 4).Value
        End With
 
        ' si tu veux marquer un "X" sur la ligne que tu viens d'écrire
        CELL_SOURCE.Offset(0, 2).Value = "X"
 
        ' fermeture et sauvegarde du fichier
        WB_DEST.Close True
    End If
Next CELL_SOURCE
 
 
With ThisWorkbook
    ' retrait du filtre automatique
    .Worksheets("Feuil1").Range("A1").AutoFilter
    ' enregistrement
    .Save
End With
 
Application.ScreenUpdating = True
End Sub

il est IMPORTANT que le nom du fichier dans ta colonne D :

- soit bien écrit
- comporte l'extension (.xls ou .xlsx ou .xlsm etc...)

Merci infiniment ! ça fonctionne nickel ta macro et j'ai beaucoup appris sur les codes que t'utilises un grand merci !!!!!