Discussion :

[MrBiduleX]

Bonjour à tous,

Nouvelles difficultés avec l’utilisation d’une boucle FOR.
Le code suivant va analyser des répertoires sous [D:\Exemple] du type [Test_AAAA_MM_JJJJ_XXX ] où AAAA_MM_JJJJ sont des dates et XXX sont des nombres. Je voudrais connaître le nombre le plus grand [NumMax].

La première version fonctionne mais la boucle n’est pas bien utilisée car elle peut me fournir que la dernière information.

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
@ECHO OFF
 
SETLOCAL EnableDelayedExpansion
 
SET OldTarget="D:\Exemple\Test_"
SET /a Longueur=17
 
SET /a Num=0
SET /a NumMax=0
SET /a Longueur=%Longueur%+10
 
FOR /d %%G IN ("%OldTarget%*") DO SET NomRep=%%~G
SET /a Num=!NomRep:~%Longueur%,3!
IF %Num% GTR %NumMax% SET /a NumMax=%Num%
 
ECHO %NumMax%
 
PAUSE

La deuxième version ne fonctionne pas mais elle devrait me permettre, une fois le problème trouvé, d’obtenir la bonne information. Après quelques tests, la variable [NomRep] ne semble pas prendre le nom du répertoire.
Elle fournit une info. avec [ECHO !NomRep!] mais rien dans le [SET /a Num=!NomRep:~%Longueur%,3!].

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
@ECHO OFF
 
SETLOCAL EnableDelayedExpansion
 
SET OldTarget="D:\Exemple\Test_"
SET /a Longueur=17
 
SET /a Num=0
SET /a NumMax=0
SET /a Longueur=%Longueur%+10
 
FOR /d %%G IN ("%OldTarget%*") DO (
	SET NomRep=%%~G
	SET /a Num=!NomRep:~%Longueur%,3!
	IF %Num% GTR %NumMax% SET /a NumMax=%Num%
)
 
ECHO %NumMax%
 
PAUSE

Auriez-vous une idée ?

Merci pour votre aide.

[sachadee]

Tu peux récuperer les 3 derniers élément du répertoire simplement de cette manière

!NomRep:~-3!

ça t'évite les comptages inutils.


Donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
setlocal enabledelayedexpansion

set "$tmp=0"

FOR /d %%G IN ("%OldTarget%*") DO (
   SET "NomRep=%%~G"
   SET /a Num=!NomRep:~-3!
   IF !Num! GTR !$tmp! SET /a $Tmp=!Num!
)

echo le plus grand ==^> [!$Tmp!]

[MrBiduleX]

Cela fonctionne... sauf pour :
- "010" qui donne 8,
- un nombre composé d'un ou plusieurs "8" qui le message "Nombre non valide. Les constantes numériques...".

Étonnant ?!

[sachadee]

Effectivement je n'avais pas pensé à ça (Il compte en Octal)

Voici le code corrigé :

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
@echo off
setlocal enabledelayedexpansion
 
set "$tmp=0"
 
FOR /d %%G IN ("%OldTarget%*") DO (
   SET "NomRep=%%~G"
   SET "Num=!NomRep:~-3!"
   SET /a Num=10000!Num! %% 10000
   IF !Num! GTR !$tmp! SET /a $Tmp=!Num!
)
 
echo le plus grand ==^> [!$Tmp!]

[MrBiduleX]

Merci ça marche.