Discussion :

[Sebphyto]

Bonsoir à tous,

Je viens vers vous car la je bugge.....

J'ai un Array du type:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

tablo = Array("Mâles", "Hongres", "Femelles", "juments")

et un split du type:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
chaine = "Pour juments de 7, 8 et 9 ans (V, U et T), n'ayant pas gagné 263.000 €"
splitchaine = Split(chaine, " ")

Je souhaite en fonction de l'Array trouver dans le split, un des 4 arguments de l'Array, mais en vain, il me renvoit "Trouvé" à chaque fois....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Essai()
tablo = Array("Mâles", "Hongres", "Femelles", "juments")
chaine = "Pour juments de 7, 8 et 9 ans (V, U et T), n'ayant pas gagné 263.000 €"
splitchaine = Split(chaine, " ")
 
For a = LBound(tablo) To UBound(tablo)
    For s = 0 To UBound(splitchaine)
        On Error Resume Next
        If IsError(Application.Match(splitchaine(s), tablo(a), 0)) Then
        'If IsError(Application.Match(tablo(a), splitchaine(s), 0)) Then
            MsgBox "trouvé"
        Else
            MsgBox "non trouvé"
        End If
        On Error GoTo 0
    Next
Next
End Sub

J'ai également essayé de la façon "Scripting.dictionary" que est une manière élégante et relativement rapide...Il y a un truc que je n'ai pas du comprendre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
'On recherche dans chaine, la présence de mots dans tablo.
Sub recherche()
tablo = Array("Mâles", "Hongres", "Femelles", "juments")
chaine = "Pour juments de 7, 8 et 9 ans (V, U et T), n'ayant pas gagné 263.000 €"
splitchaine = Split(chaine, " ")
   Application.ScreenUpdating = False
   Set d = CreateObject("Scripting.Dictionary")
   For Each C In tablo
   d.Add C.Value, C.Value
 
   Next C
  For j = LBound(splitchaine) To UBound(splitchaine)
            If d.Exists(splitchaine(j)) Then MsgBox splitchaine(j)
        Next j
 End Sub

je sollicite votre aide pour me dépatouiller avec ces 2 solutions afin que je comprenne mon erreur dans les 2 sub

Merci d'avance
seb

[joe.levrai]

Bonjour,

3 pour le prix de 2 qu'en dis-tu ?

1) Match

Ta fonction match doit comporter :

- 1 string à rechercher : chaque valeur de tablo
- 1 MATRICE de recherche : le split COMPLET de ta chaine
- le type de recherche : 0 pour correspondance exacte

en modifiant simplement les parties que j'ai mis en majuscule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub EssaiMatch()
tablo = Array("Mâles", "Hongres", "Femelles", "juments")
chaine = "Pour juments de 7, 8 et 9 ans (V, U et T), n'ayant pas gagné 263.000 €"
splitchaine = Split(chaine, " ")
    For a = LBound(tablo) To UBound(tablo)
        ' ON FAIT LA RECHERCHE DANS LE splitchaine COMPLET
        If Not IsError(Application.Match(tablo(a), splitchaine, 0)) Then
            MsgBox "trouvé " & tablo(a)
        Else
            MsgBox "non trouvé " & tablo(a)
        End If
    Next
End Sub

Tu pourras donc virer le cas "Else", j'ai inversé ton test avec le "Not"


2) Dictionary

Si tu veux vraiment pas déclarer tes variables, garde toujours en tête que VBA va typer à ta place.
En l’occurrence, C est déjà un string, tu n'a donc pas de propriété "Value", fais directement référence à C quand tu l'ajoute au dictionnaire

par ailleurs, tu ne prévois pas le cas où l'élément existe déjà, ce qui te jouera des tours tôt ou tard.
Tu as deux solutions :

- On error resume Next / faire l'ajout / on error goto 0
- test avec un If : if d.Exists("élément) Then .... ajout

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub EssaiDictionary()
tablo = Array("Mâles", "Hongres", "Femelles", "juments")
chaine = "Pour juments de 7, 8 et 9 ans (V, U et T), n'ayant pas gagné 263.000 €"
splitchaine = Split(chaine, " ")
 
    Set d = CreateObject("Scripting.Dictionary")
    For Each C In tablo
         ' TOUJOURS TESTER L'EXISTENCE DE LA CLE QU ON AJOUTE
         If Not d.exists(C) Then d.Add C, C
                                     ' ON FAIT REFERENCE A "C" QUI EST DEJA UN STRING
    Next C
 
    For j = LBound(splitchaine) To UBound(splitchaine)
        If d.exists(splitchaine(j)) Then MsgBox splitchaine(j)
    Next j
End Sub

3) Bonus : fonction Instr

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub EssaiInstr()
tablo = Array("Mâles", "Hongres", "Femelles", "juments")
chaine = "Pour juments de 7, 8 et 9 ans (V, U et T), n'ayant pas gagné 263.000 €"
    For a = LBound(tablo) To UBound(tablo)
        ' instr = 0 veut dire que la sous-chaine n'existe pas dans la chaine principale
        If InStr(1, chaine, tablo(a)) > 0 Then
            MsgBox "trouvé " & tablo(a)
            Exit For
        End If
    Next a
End Sub

Fait tes courses parmi les choix !

Ps : si tu veux trouver la position de l'élément testé, t'as tous les outils dans ces exemples ... petit exercice pratique pour toi !
Si tu coinces, reviens avec ton exemple qui fonctionne pas

[Sebphyto]

Salut Joe,

Alors là chapeau bas, c que du bonheur et je n'en demandai pas tant...

En plus c très clair, en faite j'en étais pas si loin....

Merci beaucoup
Sébastien