Discussion :

[ochini]

et donc tes dates sont en anglais ?


Je ne comprends pas pourquoi tu ne cherche plus la cellule sélectionné ?

Oui les dates sont en anglais

Non mais en fait c'est juste un exemple associé au fichier excel que j’ai mis en PJ. L'idée c'est toujours d'aller chercher la cellule sélectionnée. Mais c'était pour montrer que même en entrant la valeur directement dans la macro ça marchait pas (en tout cas pour les valeurs de jour inférieure à 10)

[SfJ5Rpw8]

ben je ce serais peu-être préférable de prendre la valeur à rechercher dans ta cellule ... au moins on serais sur que tu ne te trompe pas sur le format... de la chaîne...

[Theze]

Bonsoir,

En adaptant le code du post #13, ça fonctionne (recherche sur la valeur "Long" de la date) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Sub Macro()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim NumFormat As String
 
    With Worksheets("KAR02A")
 
        Set Plage = .Range(.Cells(6, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    With Plage
 
        NumFormat = Plage(1).NumberFormat 'récupère le format sur la première cellule de la plage
        .NumberFormat = "General"
        Set Cel = .Find(CLng(CDate("07-feb-15")), , xlValues, xlWhole)
        .NumberFormat = NumFormat
 
    End With
 
     If Not Cel Is Nothing Then
 
        MsgBox Cel.Address(0, 0)
        Cel.Select
 
     End If
 
End Sub

Sinon, il y a la bonne vieille moulinette :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
 
    'défini la recherche sur la colonne A de la feuille "Feuil1"
    With Worksheets("Feuil1")
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    For Each Cel In Plage
 
        If Cel.Text Like "07-feb-15" Then
 
            MsgBox Cel.Address(0, 0)
            Cel.Select
            Exit Sub
 
        End If
 
    Next Cel
 
 End Sub

Attention tout de même, mes tests sont fait sur un format de dates Français soit "07-févr-15" mais ça ne doir rien changer si c'est un format de date valide !

[ochini]

Merci Theze

Ca fonctionne nickel. Tu me sors une épine du pied

J’ai toujours pas bien compris pourquoi ca marchait pas avant. Mais en forçant le format en tout cas c'est bon