Discussion :

[stradic4000]

Bonjour à tous,

Je cherche à créer un commentaire pour chaque cellule de la colonne A.
Le commentaire contient le texte de chaque cellule.

En fouillant à droite à gauche dans le forum, je suis parvenu à faire ce petit code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Private Sub Worksheet_Activate()
 With Range("A1")
   If .Comment Is Nothing Then Range("A1").AddComment
   .Comment.Text Text:=Sheets("Feuil1").[A1].Value
   .Comment.Shape.TextFrame.Characters.Font.Size = 12
.Comment.Shape.ScaleWidth 2.5, msoFalse, msoScaleFromTopLeft
 .Comment.Shape.ScaleHeight 1, msoFalse, msoScaleFromTopLeft
  End With
End Sub

Je souhaiterais appliquer cette macro à toutes les cellules non vides de ma colonne A. Il n'y a pas de cellule vide dans la colonne.

Je suis bloqué là.
Merci de votre aide.

[Thautheme]

Bonsoir Stradic, bonsoir le forum,

Ça ne t'ai pas venu à l'idée de faire une boucle ?!... Essaie comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Worksheet_Activate()
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim PL As Range 'déclare la variable PL (PLage)
Dim CEL As Range 'déclare la variable CEL (CELlule)
 
DL = Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne 1 (=A)
Set PL = Range("A1:A" & DL) 'définit la palge PL
For Each CEL In PL 'boucle sur toutes les cellules CEL de la plage PL
    On Error Resume Next 'gestion des erreurs (en cas d'erreur passe à la ligne suivante)
    CEL.Comment.Delete 'supprime le commentaire (génère une erreur su il n'y a pas de commentaire)
    If Err <> 0 Then Err.Clear 'si une erreur a été générée, supprime l'erreur
    On Error GoTo 0 'annule la gestion des erreurs
    CEL.AddComment 'ajoute un commentaire
    CEL.Comment.Text Text:=CEL.Text 'texte du commentaire
    CEL.Comment.Shape.TextFrame.Characters.Font.Size = 12 'polise du commentaire
    CEL.Comment.Shape.ScaleWidth 2.5, msoFalse, msoScaleFromTopLeft 'taille du commantaire (largeur)
    CEL.Comment.Shape.ScaleHeight 1, msoFalse, msoScaleFromTopLeft 'taille du commantaire (hauteur)
Next CEL 'prochaine cellule de la boucle
End Sub

[stradic4000]

Merci beaucoup, c'est exactement ça.
Je n'ai aucune connaissance en VBA, mais il va falloir que je m'y mette sérieusement...