Publipostage vers word pour un seul enregistrement

**meritites** · 15/08/2015, 12h49

Bonjour,
j'ai actuellement une base de donnée utilisée pour envoyer des notifications de jugement (entre autre). Ces notifications doivent être envoyée au comparant, à son avocat et à tout un tas d'administration. Un document word avec publipostage a donc été créé avec les modèles pour chaque partie.
A l'heure actuelle, je peux ouvrir ce document word via access avec le publipostage. Voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
' Voici pour la déclaration du code :
Dim wdapp As Word.Application
Dim stword As String
Dim stsql As String
stsql = [Forms]![vu jugement sas]![Texte154] 'contient la clé affaire
stword = Me.Texte4
' Démarrer Word
Set wdapp = CreateObject("Word.application")
With wdapp
       .Visible = True
 .Documents.Open stword
       .ActiveDocument.MailMerge.OpenDataSource _
            Name:=CurrentProject.FullName, _
            LinkToSource:=True, _
            Connection:="Table Jugement", _
            SQLStatement:="SELECT * FROM [Jugement] WHERE [CLE_AFFAIRE]=stsql"
 
           ' Diriger le publipostage vers un nouveau document
     .ActiveDocument.MailMerge.Execute
End With
 
' Fermer et libérer les objets
Set wdapp = Nothing

Je rencontre cependant 3 problèmes:

-le premier est que, bien que la table soit spécifiée dans le code, je dois tout de même la sélectionnée dans word;
-le deuxième, ça ne marche que si la base est sous forme mdb sinon il ne trouve pas du tout la base de donnée

-Enfin, il ne sélectionne absolument pas l'enregistrement en cours. J'ai droit à toute la table! J'ai pensé à créer une table temporaire mais c'est lourd et j'ai peur que ça ne soit pas très gérable.

Auriez-vous une idée pour palier à ces problèmes? Merci d'avance

**Zealynn** · 19/08/2015, 14h09

Bonjour,
J'ai le même souci que toi. J'ai essayé d'adapter le super tutoriel fait par Olivier Lebeau mais je pense que je manque d'expérience.

Je ne souhaite pas mettre le code dans Module mais dans le VB d'un bouton à cliquer puis lui indiquer quels champs de l'enregistrement en cours parser avec word et tout droit dans des signets définis.

Ce publipostage me semble logique mais j'éprouve énormément de difficultés mais ça me passionne.

Si je trouve une piste je tiendrais au courant.

Cordialement.

**T4keo** · 20/08/2015, 12h06

Bonjour,

Personnellement j'ai réussi à le faire, j'ai tout d'abord créé un document word relié a ma table grâce au publipostage, j'y ai inséré les champs au endroit ou je le souhaitais et ensuite, dans Access, j'ai créé un module contenant la fonction de publipostage word ci-dessous et j'appel cette fonction que j'ai placé sur un bouton.

Cette fonction ouvre le document word de publipostage (CheminDocument) et va executer la requete sql (SQL) ceci ouvre un autre document Word contenant juste l'enregistrement avec le bon publipostage.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
 
' ---
' PUBLIPOSTAGE AVEC WORD 2007
' ---
' Le résultat de la fusion reste affiché à l'écran.
'
' CheminDocument = Chemin du document Word à ouvrir
' SQL = Instruction SQL que l'on veut
Function Publipostage(CheminDocument As String, sql As String)
On Error GoTo errorPubli
    Dim wdApp As Object
    Dim wdDoc As Object
 
    ' Démarrer Word
    Set wdApp = CreateObject("Word.Application")
    With wdApp
        ' Rendre Word visible pour faciliter la mise au point
        .Visible = True
        ' Ouvrir le document de publipostage
        .Documents.Open CheminDocument
 
        ' Paramétrer le publipostage
        With .ActiveDocument.MailMerge
            .OpenDataSource Name:=CurrentProject.FullName, SQLStatement:=sql, ReadOnly:=True
 
            ' Diriger le publipostage vers un nouveau document plutôt que vers l'imprimante, le fax ou le mail
            .Destination = wdSendToNewDocument
 
            ' Lancer la fusion
            .Execute
        End With
    End With
 
    ' Fermer et libérer les objets
    Set wdApp = Nothing
 
    'Fermer Le document de Publipostage Word
    'Récupère l'objet Word correspondant au document
    Set wdDoc = GetObject(CheminDocument)
    'On ferme le document sans enregistrer les changements
    wdDoc.Close wdDoNotSaveChanges
    'Libérer les objets
    Set wdDoc = Nothing
Exit Function
errorPubli:
    MsgBox "Une erreur est survenu !" & vbCrLf & _
        "Erreur : " & Err.Number & " - Erreur sur le publipostage" & _
        vbCrLf & Err.Description
 
        wdApp.Close wdDoNotSaveChanges
        wdDoc.Close wdDoNotSaveChanges
        Set wdApp = Nothing
        Set wdDoc = Nothing
    Exit Function
End Function

Enfin je remarque aussi que ta requête SQL est mauvaise, tu utilise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SQLStatement:="SELECT * FROM [Jugement] WHERE [CLE_AFFAIRE]=stsql"

Alors qu'il faudrait l'écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SQLStatement:="SELECT * FROM [Jugement] WHERE [CLE_AFFAIRE]='" & stsql & "';"

car tu essaye d'utiliser une variable déclaré plus haut a ce que je vois mais ta requete tu lui dit de chercher spécifiquement "stsql" et non le contenu de la variable, je pense que ceci peux résoudre ton problème aussi.

**meritites** · 20/08/2015, 17h58

Merci de ta réponse mais absolument rien ne marche. Le problème viens je pense du fait que word ne trouve pas la table même si je la note dans le code.
Si j'ouvre le document à part, no problem. si je l'ouvre à partir d'access, il me met une liste de toutes mes tables et me demande d'en choisir une.

J'ai beau tourner le probleme dans tous les sens, je ne comprends pas.