Discussion :

[stephb084]

Bonjour a tous,

Le code suivant permet de remplir ma ComboBox1 avec les données de chaque ligne de la colonne B sans les doublons. Je voudrais rajouter les conditions suivantes :

Récupérer les données de la colonne B dans la ComboBox1 seulement si la colonne F contient une valeur et si la J n'en contient pas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
'déclaration des variables
Dim j As Integer, i As Integer, k As Integer
Dim temp As String
Dim cell As Range
 
'-------------------------------------COMBOBOX1--------------------------------------
'vide la combobox1
ComboBox1.Clear
j = 0
i = 0
k = 0
temp = 0
 
'vide la combobox1
ComboBox1.Clear
 
With Sheets("Borne")
    For j = 2 To .Columns(1).Find("*", , , , xlByColumns, xlPrevious).Row
'remplit la combobox
        ComboBox1 = .Range("B" & j)
'sans doublons......
    If ComboBox1.ListIndex = -1 Then ComboBox1.AddItem .Range("B" & j)
    Next j
End With
'trie la combobox
With ComboBox1
    For i = 0 To .ListCount - 1
      For k = 0 To .ListCount - 1
        If .List(i) < .List(k) Then
          temp = .List(i)
          .List(i) = .List(k)
          .List(k) = temp
        End If
      Next k
    Next i
    .ListIndex = -1
End With
 
End Sub

Bonne journée a tous

[Philippe Tulliez]

Bonjour,
Une simple procédure décisionnelle Select Case permet de facilement gérer ce dont tu parles.

[stephb084]

Ok, je ne connais pas cette procédure, pourrais-tu me donner un peu plus d'info stp ?

[Philippe Tulliez]

Bonjour,
Un petit coup d'oeil sur le chapitre 11-C. La structure Select Case du tutoriel Initiation au VBA Office

[stephb084]

Bonsoir,

Je ne trouve pas ou insérer le Select case. Je n'ai pas tout pigé sur cette procédure.

[joe.levrai]

Bonjour,

un petit IF/END IF encadrant la ligne 22 ne suffirait-il pas ?

si bidule "est différent de vide" et machin "égale le vide" alors ....

[Philippe Tulliez]

Bonjour,
Voici un exemple qui contrôle à chaque ligne de la plage de données (à partir de la deuxième) si la colonne 3 contient le mot "Excel" et que la valeur se trouvant en colonne 4 est plus grand que 3. Si c'est le cas, on rempli le ComboBox avec la valeur de la cellule de la colonne 2 sans doublon.
Le test est fait avec le Select Case mais on peut bien entendu utiliser également la procédure décisionnelle If...Then...Else comme l'a proposé Joe que je salue au passage.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Explicit
Dim rng As Range
Private Sub UserForm_Initialize()
 Dim Row As Integer, cb As ComboBox, ColNumber As Integer
 Set rng = ThisWorkbook.Worksheets("db").Range("A1").CurrentRegion
 Set cb = Me.ComboBox1
 ColNumber = 2 ' Parcourt les cellules de la première colonne
 With rng
  For Row = 2 To .Rows.Count
   Select Case True
     Case .Cells(Row, 3) = "Excel" And .Cells(Row, 4) > 3
     ' Ctrl si doublon
     cb.Value = .Cells(Row, ColNumber)
     If cb.ListIndex = -1 And Len(.Cells(Row, ColNumber)) Then cb.AddItem .Cells(Row, ColNumber)
   End Select
  Next Row
 End With
 cb.ListIndex = 0 ' Sélectionne le premier élément de la liste
End Sub

Solution avec If

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub UserForm_Initialize()
 Dim Row As Integer, cb As ComboBox, ColNumber As Integer
 Set rng = ThisWorkbook.Worksheets("db").Range("A1").CurrentRegion
 Set cb = Me.ComboBox1
 ColNumber = 2 ' Parcourt les cellules de la première colonne
 With rng
  For Row = 2 To .Rows.Count
   If .Cells(Row, 3) = "Excel" And .Cells(Row, 4) > 3 Then
     ' Ctrl si doublon
     cb.Value = .Cells(Row, ColNumber)
     If cb.ListIndex = -1 And Len(.Cells(Row, ColNumber)) Then cb.AddItem .Cells(Row, ColNumber)
   End If
  Next Row
 End With
 cb.ListIndex = 0 ' Sélectionne le premier élément de la liste
End Sub

[stephb084]

Bonjour Philippe,

Merci pour ton aide.

J'ai inséré le code dans mon projet. Plusieurs problèmes se sont présentés.
Le premier, un message d'erreur ("Instruction incorrect dans une procédure") a l’exécution de la procédure "Option explicit".
Après a voir mis "Option explicit" en commentaire pour tester la suite du code je retrouve le message ("Impossible de définir la propriété de ListIndex. Valeur de propriété non valide") au niveau de cb.ListIndex en rouge.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Sub UserForm_Initialize()

    Application.WindowState = xlMinimized 'Ferme le classeur
    Application.Visible = False 'Ferme le classeur

Clock = Format(Now, "dd.mm.yyyy")
 m_lasttime = Now '+ TimeValue("00:00:01")
 
Application.OnTime m_lasttime, "GetTime"

Clock1 = Format(Now, "hh:mm")
 m_lasttime = Now '+ TimeValue("00:00:01")
 
Application.OnTime m_lasttime, "GetTime"
   

'Option Explicit
Dim rng As Range
 
 Dim Row As Integer, cb As ComboBox, ColNumber As Integer
 Set rng = ThisWorkbook.Worksheets("Borne").Range("A1").CurrentRegion
 Set cb = Me.ComboBox1
 ColNumber = 2 ' Parcourt les cellules de la première colonne
 With rng
  For Row = 2 To .Rows.Count
   Select Case True
     Case .Cells(Row, 3) = "Excel" And .Cells(Row, 4) > 3
     ' Ctrl si doublon
     cb.Value = .Cells(Row, ColNumber)
     If cb.ListIndex = -1 And Len(.Cells(Row, ColNumber)) Then cb.AddItem .Cells(Row, ColNumber)
   End Select
  Next Row
 End With
 cb.ListIndex = 0 ' Sélectionne le premier élément de la liste
End Sub

[Philippe Tulliez]

Bonjour,
Alors Option Explicit est une instruction qui doit être placée en tête de module et qui oblige à déclarer toutes ses variables et bien évidemment que la ligne que tu indiques se mette en erreur du fait que tu as gardé les mêmes tests que moi donc il n'y a aucun élément dans ta liste.
Dans cette ligne de code qui est le test, tu n'as sûrement aucune cellule de la colonne 3 contenant "Excel" et peut-être aussi rien dans les cellules de la colonne 4 qui soit supérieur à 3

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Case .Cells(Row, 3) = "Excel" And .Cells(Row, 4) > 3

Il faut tout de même essayer de comprendre le code. Une structure décisionnelle telle que If Then Else ou Select Case c'est du VBA de base.

Utilise le deuxième code où le test avec If est sans doute plus simple à comprendre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

  If .Cells(Row, 3) = "Excel" And .Cells(Row, 4) > 3 Then

Cela signifie en français

Si la valeur de la cellule(N° de ligne de la boucle, colonne 3) est égale à "Excel" ET la valeur de la cellule(N° de ligne de la boucle, colonne 4) est supérieure à 3 Alors

Je te conseille la lecture du tutoriel que je t'ai référencé dans ma réponse d'hier à 19h02

[stephb084]

Philippe,

Je suis très intéresser par le vba, je travaille dessus régulièrement pour le comprendre.

J'ai modifié mon tableur pour y insérer "Excel" en 4 et un chiffre supérieur a 3 en 3 éme colonne pour mes tests avant de poster mon dernier message.
Mais je vais trouver une solution sans problème.

Merci encore de votre aide.

[joe.levrai]

Bonjour,

tu as tout ce qu'il faut dans ce sujet maintenant

1) quelle condition faire ?

si bidule "est différent de vide" et machin "égale le vide" alors ....

2) que sont "bidule" et "machin" ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If .Cells(Row, 3) = "Excel" And .Cells(Row, 4) > 3 Then

que n'arrives-tu pas à faire ?
il faut juste corréler ces deux quotes, en écrivant en langage VBA le premier quote
c'est ça ton souci ?

[Philippe Tulliez]

Bonjour,
Je ne sais pas si cela à un rapport avec ton encodage mais idéalement lorsque je teste une chaîne de caractères j'ajoute les fonctions Trim et LCase afin d'éviter les problèmes de casse et les caractères espacés dû à un "dérapage" de l'encodeur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

   If Trim(LCase(.Cells(Row, 3))) = "excel" And .Cells(Row, 4) > 3 Then

Voici le classeur qui a servi à cette discussion.

[joe.levrai]

Philippe,

Je suis très intéresser par le vba, je travaille dessus régulièrement pour le comprendre.

J'ai modifié mon tableur pour y insérer "Excel" en 4 et un chiffre supérieur a 3 en 3 éme colonne pour mes tests avant de poster mon dernier message.
Mais je vais trouver une solution sans problème.

Merci encore de votre aide.

Je lis correctement en disant que tu as mis Excel en colonne 4 et le chiffre en colonne 3 ?
Là où Philippe réalise l'inverse ?

Si la valeur de la cellule(N° de ligne de la boucle, colonne 3) est égale à "Excel" ET la valeur de la cellule(N° de ligne de la boucle, colonne 4) est supérieure à 3

[stephb084]

Bonjour a tous,

Joé, c'est vrai j'ai inversé les deux, faute d'inattention ! Désolé.

Philippe, j'ai bien compris le code que tu utilise. Je veux juste changer "Excel" par "cellule non vide" et ">3" par "cellule vide". C'est cette partie la que je n'arrive pas a écrire. J'ai trouvé en fouillant sur le forum et sur internet le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Not IsEmpty(LCase(.Cells(Row, 3))) And .Cells(Row, 4) = "" Then

Mais je n'arrive pas a l'adapter. La premiére partie, si je ne me suis pas trompé "si la colonne 3 de la ligne de la boucle n'est pas vide ..." par contre pour la deuxième partie je ne sais pas comment écrire "et la colonne 4 de la ligne de la boucle est vide" ?

[joe.levrai]

Bonjour,

une cellule vide a la particularité d'héberger une chaine de caractère vide ( = "")

c'est ce que je soulignais avec mon "si bidule 'est différent de vide' et machin 'égale le vide' alors ...."

tu connais bidule et machin, ce qui donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 If Bidule <> ""  ' = n'est pas vide
If Bidule = "" ' = est vide

attention si les cellules contiennent des formules qui renvoient une valeur vide toutefois

[stephb084]

Ok super !

Le code fonctionne parfaitement. J'ai exactement ceux que je cherchais.

Voici le final :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim rng As Range
 
 Dim Row As Integer, cb As ComboBox, ColNumber As Integer
 Set rng = ThisWorkbook.Worksheets("Borne").Range("A1").CurrentRegion
 Set cb = Me.ComboBox1
 ColNumber = 2 ' Parcourt les cellules de la première colonne
 With rng
  For Row = 2 To .Rows.Count
   Select Case True
     Case .Cells(Row, 6) <> "" And .Cells(Row, 8) = "" And .Cells(Row, 10) = ""
     ' Ctrl si doublon
     cb.Value = .Cells(Row, ColNumber)
     If cb.ListIndex = -1 And Len(.Cells(Row, ColNumber)) Then cb.AddItem .Cells(Row, ColNumber)
   End Select
  Next Row
 End With
End Sub

Encore merci a tous de nous faire partager vos compétences. J'apprend beaucoup ici.

A bientôt