Discussion :

[possible924]

Bonjour à tous,
Dans une base d'une centaine de tables,
je souhaiterais mettre, par VBA, la propriété "Sous feuille de données non" sur "Aucune" dans toutes les tables de la base.
Hélas mes connaissances en VBA, ne sont pas suffisantes pour régler ce problème

Question subsidiaire :
Est t'il possible en VBA de mettre tous les champs de toutes les tables par l'onglet "Liste de choix", "contrôle de l'affichage" sur la valeur "Zone de texte"

Merci par avance pour votre aide
Pierre

[Didier L]

Bonsoir,

Voila déjà le code pour mettre la propriété "Sous feuille de donnée étendue" de toutes les tables à Non

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub MaManipulationDeTables()
Dim voMaTable As TableDef
On Error Resume Next
    For Each voMaTable In CurrentDb.TableDefs
        If Left(voMaTable.Name, 4) <> "MSys" Then
            voMaTable.Properties("SubdatasheetExpanded") = False
        End If
    Next
End Sub

Attention de ne pas manipuler les tables "System" d''ou le test sur "Msys"
Ensuite En début de code je me sert de la syntaxe :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

On Error Resume Next

Afin d'éviter le plantage générer par l'absence de la propriété qui n'est créée par Access que si la table a eu la propriété "Oui".
Par défaut cette propriété n'existe pas dans l'objet "Tabledef" !

Ensuite pour la seconde question ma réponse serait que c'est surement possible.
Il faut parcourir les propriétés de la collection "Fields".
Mais il faut trouver la bonne syntaxe, faire des boucles imbriquées et surtout faire attention au cas ou ces propriétés n'existeraient pas pour certains type de champs.
A tester donc d’abord sur une table, etc ...

[Didier L]

Et voila le second code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub MaManipulationDeChamps()
Dim voMaTable As TableDef
Dim I As Integer
On Error Resume Next
    For Each voMaTable In CurrentDb.TableDefs
        If Left(voMaTable.Name, 4) <> "MSys" Then
            For I = 0 To voMaTable.Fields.Count - 1
                voMaTable.Fields(I).Properties("DisplayControl").Value = 109
            Next
        End If
    Next
End Sub

[possible924]

ça marche très bien
Merci
Pierre

[Didier L]

Bonjour,

Super
Alors merci de penser au tag résolu