Discussion :

[tiralarc03]

Bonjour,
j'ai un code VBA comme ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub UserForm_Initialize()
ListBox1.ColumnCount = 5
ListBox1.ColumnWidths = "50;50;50;50;50"
ListBox1.List = Sheets("Analytique").Range("A1:E41").Value
End Sub

J'ai vu sur le net que je pouvais des separateurs avec ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub UserForm_Initialize()
Dim i As Byte, j As Byte
 
ListBox1.ColumnCount = 7
ListBox1.ColumnWidths = "50;15;50;15;50;15;50"
 
For i = 1 To 20
    ListBox1.AddItem "Ligne" & i
 
    For j = 2 To 7 Step 2
    ListBox1.List(ListBox1.ListCount - 1, j) = i & j
    Next j
 
    For j = 1 To 6 Step 2
    ListBox1.List(ListBox1.ListCount - 1, j) = Chr(124)
    Next j
Next i
End Sub

Mais pouvez-vous m'aider a l'adapter a mon code

Merci d'avance pour votre aide

[Qwazerty]

Salut

Il serait peut-être plus simple (et propre) d'utiliser le composant ListView, il est je pense d'origine bien que non déclaré par défaut dans VBE.
Pour l'ajouter à la liste des composant:


Dans la liste tu cherches Microsoft ListView.

Il doit y avoir pas mal de tutoriel à sont sujet, je te laisse regarder. Tu trouveras notement des info sur sa propriété "View" configuré en "3-lvwReport", qui permet de faire un affichage comme dans ton explorateur de fichier windows en version Détaillé.


Sinon, voila le code que tu cherches

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub UserForm_Initialize()
Dim i As Byte, j As Byte
Dim ListRange As Range
 
Set ListRange = ThisWorkbook.Sheets("Analytique").Range("A1:E41")
ListBox1.columnCount = 9 '(numéroté de 0 à 8)
ListBox1.ColumnWidths = "50;15;50;15;50;15;50;15;50"
 
For i = 1 To 41
    ListBox1.AddItem "Ligne" & i ' création de la ligne et renseignement de la 1ère colonne (0)
 
    'Place les séparateurs dans les colonnes impaires
    For j = 1 To 7 Step 2
    ListBox1.List(ListBox1.ListCount - 1, j) = Chr(124)
    Next j
 
    'Ajoute les donnée dans les colonnes paire de la nouvelle ligne
    For j = 2 To 8 Step 2
    ListBox1.List(ListBox1.ListCount - 1, j) = ListRange.Cells(i, j / 2).Value
    Next j
 
Next i
End Sub

++
Qwaz

[Docmarti]

Bonjour.

Sinon, si tu tiens au Listbox, fais une copie du champ source de données sur une autre feuille, insère-z-y des colonnes où tu mets ton séparateur et utilise cette feuille comme source de données.

[tiralarc03]

Bonjour.

Sinon, si tu tiens au Listbox, fais une copie du champ source de données sur une autre feuille, insère-z-y des colonnes où tu mets ton séparateur et utilise cette feuille comme source de données.

Bonsoir,
au final j'ai pris cette solution.
Un grand merci pour vos contribution..

[tiralarc03]

Bonsoir j'avais déjà regardé la fonction Listview mais je n'arrive pas l'adapter à mon tableau

j'ai 5 colonnes
une ligne de titre en première ligne
et après j'ai 40 lignes a reproduire dans la Listview

J'ai ce code prit sur le net qui marche sans modification mais lorsque je l'adapte à mon fichier j'ai un problème:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub UserForm_Initialize()
' création du listview
Dim rg As Range
Dim n As Integer, i As Integer

Set rg = [A1]   'ligne avec les titres
n = 5   'nb de colonnes de données

With Me.ListView1
'ajout des titres de colonnes
For i = 1 To n
.ColumnHeaders.Add , , rg.Offset(0, i - 1)
Next i

'ajout des éléments de la 1re colonne
Set rg = [A2]   '1re ligne avec les données
Do Until IsEmpty(rg)
.ListItems.Add , , rg
'ajout des éléments des autres colonnes
For i = 1 To n
.ListItems(rg.Row - 3).ListSubItems.Add , , rg.Offset(0, i)
Next i
Set rg = rg.Offset(1, 0)    'prochaine ligne
Loop

.FullRowSelect = True   'permet de choisir une ligne complète
.MultiSelect = True     'permet de sélectionner plusieurs lignes
.View = lvwReport       'format d'affichage des données
End With
End Sub

J'ai modifié les lignes en vert pour mon application sans problème mais en modifiant la ligne du code en rouge j'ai une erreur "erreur d’exécution 35600 index hors limites"

Que faut-il faire?

[Qwazerty]

Salut

(J'avais édité mon 1er message avec un code qui rempli un listBox.

Sinon pour le listView

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub UserForm_Click()
Dim iRow As Integer
Dim TheCell As Range
 
'On pointe la feuille contenant les données
With ThisWorkbook.Sheets("Analytique")
    'On place les entêtes
    For Each TheCell In .Range("A1", .Cells(1, .Columns.Count).End(xlToLeft))
        ListView1.ColumnHeaders.Add , , TheCell.Value
    Next
    'On place les données (ici, la colonne A ne doit jamais avoir de vide (sinon prendre une autre colonne)
    For iRow = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row
        'On ajoute une ligne
        ListView1.ListItems.Add , , .Cells(iRow, "A").Value
        'On y place les données
        'On boucle sur les cellule de la ligne iRow
        For Each TheCell In .Range(.Cells(iRow, "B"), .Cells(iRow, .Columns.Count).End(xlToLeft))
            ListView1.ListItems(iRow - 1).ListSubItems.Add , , TheCell.Value
        Next
    Next
End With
 
End Sub

Le ListView doit être configuré en View Report.
Le code est polyvalent, le nombre de ligne et de colonne de ton tableau source peuvent varier. Tu auras peut-être un message d'erreur si le tableau source est vide par contre, à tester.

++
Qwaz