Discussion :

[ulpu6422]

Bonjour,

Je suis débutant en VBA sous Excel 2007.
Je cherche à écrire une macro qui me permet de
1 - Rechercher la première cellule dans la colonne A de la Feuil2 de mon classeur ayant une valeur identique à la cellule A1 de la Feuil1.
2 - Se positionner sur la cellule trouvée et effacer le contenu
3 - Se positionner sur la Feuil1

Merci d'avance pour votre aide.

[Docmarti]

Bonjour,

Bienvenu sur VBA Excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub tt()
Set f1 = ThisWorkbook.Worksheets("Feuil1")
 valeur = f1.Cells(1, 1).Value
 
Set f2 = ThisWorkbook.Worksheets("Feuil2")
 
 derniereligne = f2.Range("A" & Rows.Count).End(xlUp).Row
 
 For I = 1 To derniereligne
  If f2.Cells(I, 1).Value = valeur Then
   f2.Activate 'Facultatif
   f2.Cells(I, 1).Select  'Facultatif
   f2.Cells(I, 1).Value = ""
   f1.Activate  'Facultatif
   Exit For
  End If
 Next
End Sub

[Theze]

Bonjour,

Une autre piste :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
 
    With Worksheets("Feuil2")
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    'recherche la valeur
    Set Cel = Plage.Find(Worksheets("Feuil1").Range("A1").Value, , xlValues, xlWhole)
 
    'si trouvée, efface
    If Not Cel Is Nothing Then
 
        Cel.Value = ""
 
    End If
 
End Sub

Hervé.

[ulpu6422]

Merci pour ton aide. J'ai gagné du temps.

Cordialement

[Invité]

bonjour,
test ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Sub test()
Dim L As Long
L = SerchXls(Sheets("Feuil2").Range("A:A"), Sheets("Feuil2").Range("A1"), Sheets("Feuil1").Range("A1"), True)
If L <> 0 Then MsgBox "Trouvé en ligne : " & L
End Sub
 
Function SerchXls(Myrange As Range, MyCellule As Range, strRecherche, EntierCell As Boolean) As Long '
On Error Resume Next
Dim CellEntrier As Integer
If EntierCell = True Then CellEntrier = xlWhole Else CellEntrier = xlPart
SerchXls = 0
   SerchXls = Myrange.Cells.Find(what:=strRecherche, After:=MyCellule, LookIn:=xlFormulas, LookAt _
        :=CellEntrier, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
        False, SearchFormat:=EntierCell).Row
  If SerchXls <= MyCellule.Row Then SerchXls = 0
End Function

[keygen08]

Bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub chercher_a1()
Dim r As Range
Set r = Sheets("Feuil2").Columns(1).Find(Sheets("Feuil1").Range("a1"), , xlValues, xlWhole)
If Not r Is Nothing Then Sheets("Feuil2").Cells(r.Row, 1).ClearContents
End Sub

[Docmarti]

rdurupt

Mieux vaut mettre SearchFormat:=False.

[Invité]

Et oui!
Je voulai frimer en montrant a qq1 du forum que l'enregisteur de macro donnait une trame et qu'en la retouchant!
Pourvue qu'il ne tombe pas sur ce poste!

rdurupt

Le paramètre SearchFormat s'utilise en conjonction avec la propriété FindFormat. Mieux vaut mettre SearchFormat:=False.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub UseFindFormat()
 
 ' Establish search criteria.
 With Application.FindFormat.Font
 .Name = "Arial"
 .FontStyle = "Regular"
 .Size = 10
 End With
 
 ' Notify user.
 With Application.FindFormat.Font
 MsgBox .Name & "-" & .FontStyle & "-" & .Size & _
 " font is what the search criteria is set to."
 End With
 
End Sub

[Menhir]

2 - Se positionner sur la cellule trouvée et effacer le contenu
3 - Se positionner sur la Feuil1

Comme on peut le voir dans les codes proposer, il n'est pas nécessaire de se positionner sur une cellule pour en effacer le contenu.

Comme tu le vois, il y a de nombreuses méthode pour parvenir à ce résultat
Je te propose ma version en une seule ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Feuil2").Column("A").Find(Worksheets("Feuil1").Cells(1,1)).ClearContents

A placer bien sûr dans une structure Sub / End Sub.

[keygen08]

Oui menhir, plus courte
mais efface 10 quand on cherche 1 si les chiffre sont dans le desordre
et puis columnS("a") me semble plus justeque column("a")

Mais bon, je dis ça juste parce que c'est pas moi qu'est la plus courte

[ulpu6422]

Comme on peut le voir dans les codes proposer, il n'est pas nécessaire de se positionner sur une cellule pour en effacer le contenu.

Comme tu le vois, il y a de nombreuses méthode pour parvenir à ce résultat
Je te propose ma version en une seule ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Feuil2").Column("A").Find(Worksheets("Feuil1").Cells(1,1)).ClearContents

A placer bien sûr dans une structure Sub / End Sub.

merci pour ta réponse, mais lorsque la commande est lancée à partir d'un click sur une checkbox et j'ai le message d'erreur "propriété ou méthode non gérée par cet objet".

[Menhir]

merci pour ta réponse, mais lorsque la commande est lancée à partir d'un click sur une checkbox et j'ai le message d'erreur "propriété ou méthode non gérée par cet objet".

Le correctif a été proposé par keygen08 (merci à lui ) juste après mon message.