Discussion :

[Runsh63]

Bonjour,

J'exporte des données mensuellement qui me servent de base pour un suivi d'indices. L'export en csv depuis le site se trouve sur l'onglet "SYN-140201" du fichier en PJ. Les données les plus récentes se trouvent sur les premières lignes. Mon but final est que sur l'onglet "Base", je remette ces données dans l'ordre chronologique. Pas de problème comme je l'ai indiqué sur ma formule en B1 de l'onglet "Base".
Mon souci, c'est que le mois prochain, l'indicateur de janvier 2013 se trouvera en ligne 17, et ma formule sera fausse, sauf si je viens changer manuellement C16 par C17, ce qui est contraignant (j'ai une trantaine d'indices à suivre). Mon problème, c'est que je ne sais pas faire la formule me permettant de rappatrier l'adresse de la cellule correspondant à l'indice de janvier 2013.
Bien entendu, DECALER(RECHERCHEV(... ne fonctionne pas. J'ai cherché sur le forum et suis tombé sur ce post:

http://www.developpez.net/forums/d56...ev-rechercheh/

Le problème est que je ne maîtrise pas du tout les formules INDEX et EQUIV, du coup je n'arrive pas à faire la formule me permettant d'obtenir le résultat escompté.
L'un(e) de vous pourrait-il m'aider SVP ?

J'aimerai ne pas passer par une macro, est-ce possible?

Merci d'avance à vous tous, passez une excellente journée !

[papouclo]

Bonjour,
La fonction ADRESSE permet d'apporter une solution.
La formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= ADRESSE(EQUIV(Base!$A$1;'SYN-140201'!$A:$A;0);3;;;"SYN-140201")

renvoie le texte "SYN-140201!$C$16" dans l'état actuel du fichier mais si l'on insère une ligne supplémentaire en début de feuille SYN-140201, cette même formule renverra le texte "SYN-140201!$C$17".
Il faudra en plus utiliser la fonction INDIRECT pour obtenir à partir de ce texte la référence de cellule utilisée dans la formule avec la fonction DECALER, d'où la formule en B1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=SI(OU(ESTTEXTE(DECALER(INDIRECT(ADRESSE(EQUIV(Base!$A$1;'SYN-140201'!$A:$A;0);3;;;"SYN-140201"));-LIGNE(A1)+1;0));
ESTVIDE(DECALER(INDIRECT(ADRESSE(EQUIV(Base!$A$1;'SYN-140201'!$A:$A;0);3;;;"SYN-140201"));-LIGNE(A1)+1;0));
ESTERREUR(DECALER(INDIRECT(ADRESSE(EQUIV(Base!$A$1;'SYN-140201'!$A:$A;0);3;;;"SYN-140201"));-LIGNE(A1)+1;0)));"";
DECALER(INDIRECT(ADRESSE(EQUIV(Base!$A$1;'SYN-140201'!$A:$A;0);3;;;"SYN-140201"));-LIGNE(A1)+1;0))

Comme cette formule devient assez indigeste, un moyen est de définir dans le Gestionnaire de noms par exemple le nom debut comme faisant reference à :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= ADRESSE(EQUIV(Base!$A$1;'SYN-140201'!$A:$A;0);3;;;"SYN-140201")

Il suffit d'écrire ensuite en B1 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
=SI(OU(ESTTEXTE(DECALER(INDIRECT(debut);-LIGNE(A1)+1;0));ESTVIDE(DECALER(INDIRECT(debut);-LIGNE(A1)+1;0));ESTERREUR(DECALER(INDIRECT(debut);-LIGNE(A1)+1;0)));"";
DECALER(INDIRECT(debut);-LIGNE(A1)+1;0))

puis de la recopier vers le bas.
Cordialement
Claude

[Invité]

Salut,

En principe, une simple rechercheV suffit.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
= RECHERCHEV($A1;'SYN-140201'!$A:$C;3;FAUX)
=SIERREUR(RECHERCHEV($A1;'SYN-140201'!$A:$C;3;FAUX); "" )

[papouclo]

Re,
Je me suis attaché à garder la formule initiale, ce qui semblait être ton désir ( " remplacer C16 par C17") mais la proposition de Nouveau2 me semble bien plus pertinente.
Cordialement
Claude

[Invité]

Salut Papouclo,

Grillé.