Discussion :

[Marc31]

Bonjour,

Je souhaite une bonne année à tot le monde.
J'ai trouver un code qui ne marche pas sur internet qui transforme un document word en pdf.
J'aimerais avoir une correction sur ce code et savoir s'il serait possible de faire plusieurs word en même temps?
Merci et bonne journée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub test()
 
    Dim wdApp As Object
    Set wdApp = CreateObject("word.application")
 
    wdApp.Documents.Open ("C:\Users\Nouveau1.doc")
 
 
    wdApp.ActivePrinter = "PDFCreator"
 
    Dim FileNamePDF As String
    FileNamePDF = "C:\Users\\nouveau1.pdf"
 
    wdApp.DisplayAlerts = wdAlertsNone
    wdApp.PrintOut OutputFileName:=FileNamePDF, PrintToFile:=False
 
    wdApp.ActiveDocument.Close
    wdApp.Quit
    Set wdApp = Nothing
End Sub

[Invité]

bbil m'avait donné une solution, il a retiré le lien qu'il m'avait donné, contact le, je ne peux pas te donner la solution sans sont accord.

[Invité]

Code Modul de class ExportPDF :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
Option Explicit
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'============================================================================================='
' ajouter la référence PDFCreator.exe au projet
'============================================================================================='
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private mvarNomFichier As String
Private mvarNomDir As String
Private mvarChemDocComplet As String
'
' IMPORTANT : le composant est déclaré avec ses évènements
Private WithEvents PDFCreator1 As PDFCreator.clsPDFCreator '/ composant principal
Private pErr As clsPDFCreatorError '/ classe de gestion d'erreur
Private opt As clsPDFCreatorOptions '/ classe de paramétrage
 
Private noStart As Boolean '/ variable de contrôle
 
Private ImprimanteParDefaut As String '/variable imprimante par défaut
 
Public Property Let ChemDocComplet(ByVal vData As String)
    '/ Propriété : chemin absolu du fichier à exporter (ex : C:\Temp\monword.doc)
    mvarChemDocComplet = vData
End Property
 
Public Property Get ChemDocComplet() As String
    ChemDocComplet = mvarChemDocComplet
End Property
 
Public Property Let NomDir(ByVal vData As String)
    '/ Propriété : chemin absolu du répertoire de sortie (ex : C:\Temp\)
    mvarNomDir = vData
End Property
 
Public Property Get NomDir() As String
    NomDir = mvarNomDir
End Property
 
Public Property Let NomFichier(ByVal vData As String)
    '/ Propriété : nom du fichier de sortie sans extension (ex : monarchive)
    mvarNomFichier = vData
End Property
 
Public Property Get NomFichier() As String
    NomFichier = mvarNomFichier
End Property
 
Private Sub Class_Initialize()
    '
    ' Instanciation des objets
    Set PDFCreator1 = New clsPDFCreator
    Set pErr = New clsPDFCreatorError
    '
    noStart = True
    '
    With PDFCreator1
        .cVisible = True
        If .cStart("/NoProcessingAtStartup") = False Then
           If .cStart("/NoProcessingAtStartup", True) = False Then
               Exit Sub
           End If
           ' L'imprimante est occupée
           .cVisible = True
        End If
        '
        ' Instanciation de l'objet clsPDFCreatorOptions avec les options par défaut
        Set opt = .cOptions
        .cClearCache
        '/ A l'installation, PDFCreator mémorise l'imprimante système par défaut,
        '/ on la mémorise dans une variable
        ImprimanteParDefaut = .cDefaultPrinter
        ' on indique que l'imprimante a démarré
        noStart = False
    End With
    '
End Sub
 
Public Sub ConversionPDF()
    '
    ' On affecte les options de sortie qui nous intéressent à l'objet clsPDFCreatorOptions
    With opt
        '/ Répertoire de sortie
        .AutosaveDirectory = Trim$(NomDir)
        '/ Fichier de sortie
        .AutosaveFilename = Trim$(NomFichier)
        .UseAutosave = 1
        .UseAutosaveDirectory = 1
        '/ format de sortie (0 = PDF)
        .AutosaveFormat = 0
    End With
    '
    '/ on affecte ensuite les nouvelles options au composant principal clsPDFCreator
    Set PDFCreator1.cOptions = opt
    '/ On définit l'imprimante virtuelle comme imprimante par défaut
    PDFCreator1.cDefaultPrinter = "PDFCreator"
    '/ Impression du document Word (ou autre)
    PDFCreator1.cPrintFile Trim$(ChemDocComplet)
    '/ On affecte la propriété cPrinterStop à False pour contrôle ultérieur
    PDFCreator1.cPrinterStop = False
    '
    ' Tant que la propriété de cPrinterStop est à False, on laisse le temps au composant
    ' de terminer l'export PDF
    While PDFCreator1.cPrinterStop = False
        DoEvents
    Wend
    '
End Sub
 
Private Sub PDFCreator1_eReady() ' === ÉVÈNEMENT ==='
 
    '!!!! IMPORTANT!!!! c'est en interceptant l'évènement _eReady qu'on sait que l'impression PDF
    ' est terminé et l'imprimante libérée : cela permet de sortir de la boucle ci-dessus
    PDFCreator1.cPrinterStop = True
    '
End Sub
 
Private Sub PDFCreator1_eError() ' === ÉVÈNEMENT ==='
    Set pErr = PDFCreator1.cError
    MsgBox "Error[" & pErr.Number & "]: " & pErr.Description
    ' en cas d'erreur, on restaure l'imprimante par défaut du système via la classe principale
    PDFCreator1.cDefaultPrinter = ImprimanteParDefaut
    '
End Sub
 
Private Sub Class_Terminate()
    '
    '/ restauration de l'imprimante par défaut
    PDFCreator1.cDefaultPrinter = ImprimanteParDefaut
    '
    If noStart = False Then
        DoEvents
        PDFCreator1.cClose
    End If
    '
    DoEvents
    '
    Set PDFCreator1 = Nothing
    Set pErr = Nothing
    Set opt = Nothing
    '
End Sub

à ajouter dans ton module

Code Conversion Wd PDF :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub PdfCr(NomDir As String, NomFichier As String)
Dim clExp As ExportPDF
    Set clExp = New ExportPDF
    '
    clExp.NomDir = NomDir
    clExp.NomFichier = NomFichier
    clExp.ChemDocComplet = NomDir & Replace(NomFichier, ".pdf", ".doc")
    '
    clExp.ConversionPDF
    '
    Set clExp = Nothing
 
End Sub

[Didier Gonard]

Bonjour,

Ton tag précise que tu es sous Excel 2010, si tu es sous office 2010, Word sais enregistrer directement en pdf, (et ouvrir des .doc anciens aussi) donc pas besoin de réinventer la poudre.

Tu ouvres un fichier an Word 2010, tu déclenches l'enregistreur de macros, tu fais enregistrer sous / choix = pdf tu valides et tu as les bases du code dont tu as besoin.

Tu ne donnes pas trop de précisions sinon...

Selon le contexte, tu peux faire ton VBA sous Word direct ce qui est plus efficient que de passer par Excel, mais sinon piloter Word via Excel est très aisé.
à titre indicatif le code basique qui copie une plage Excel dans Word :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub InsererPlageDansWord()
Dim AppWord As Word.Application 'on crée une variable Application Word
Dim objDocWord As Word.Document 'on crée une variable document Word
 
Set AppWord = New Word.Application ' on crée une instance de Word
AppWord.Visible = True 'par défaut, la nouvelle application n'est pas visible
'on ouvre le fichier Word voulu
Set objDocWord = AppWord.Documents.Open(ThisWorkbook.Path & "\" & "Exo.doc", ReadOnly:=False)
 ActiveWorkbook.Worksheets(1).Range("A1:D30").Copy 'on copie une plage Excel
objDocWord.Range.PasteSpecial ' on la colle dans Word
Application.CutCopyMode = False 'on désactive le mode copy
'  objDocWord.Application.ActiveDocument.Save 'évventuellement, du coup pas besoin du savechanges:=False ci-dessous
AppWord.Application.Quit savechanges:=False
Set objDocWord = Nothing
Set AppWord = Nothing
 
End Sub

Pour ce qui est de l'appliquer à plusieurs, il suffit de boucler.

cordialement,

Didier

[Invité]

oui c'était mon cas mais le fichier généré était volumineux c'est pour cela que j'avais posé cette question.

http://www.developpez.net/forums/d13...f/#post7250128

[Marc31]

Merci pour le code et je vais essayé de faire plus précis dans mes propos.
En fait j'ai plusieurs fichiers word que j'aimerais mettre en pdf sans avoir à faire fichier --> enregistrer sous pour chaques fichiers

[Invité]

voilà le code que j'utilisais et qui me convenais pas pour des problème de taille.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
ObjWord.ActiveDocument.ExportAsFixedFormat OutputFileName:= _
        PathSavePdf & SavePdf, ExportFormat:=17, _
        OpenAfterExport:=False, OptimizeFor:=0, Range:= _
        0, From:=1, To:=1, Item:=0, _
        IncludeDocProps:=False, KeepIRM:=True, CreateBookmarks:= _
        0, DocStructureTags:=False, BitmapMissingFonts:= _
        True, UseISO19005_1:=False

[SfJ5Rpw8]

bbil m'avait donné une solution, il a retiré le lien qu'il m'avait donné, contact le, je ne peux pas te donner la solution sans sont accord.

Je pense pas avoir retiré de lien ...

mais dans la précédente discussion il semble erroné le lien est :

http://www.developpez.net/forums/d21...ex-pdfcreator/

[Marc31]

Bonjour,

J'ai testé le code et il me crée bien un document pdf mais des que je veux l'ouvrir, il me marque que adobe reader n'a pas pu ouvrir le fichier parce qu'il n'est pas pris en charge....ça vient de quoi??

Merci et bonne journée

Ah non j'ai dit une bêtise, je n'arrive pas à faire fonctionner le code....

En fait c'est bon mais par contre j'aimerais savoir si je veux convertir plusieurs words en pdf, c'est possible ou pas?

[Invité]

je t'es fait un exemple, en pièce jointe, dézip la totalité du répertoire sur ton disque dur.

attention: ajouter la référence PDFCreator.exe au projet

Ah non j'ai dit une bétise, je n'arrive pas à faire fonctionner le code....

[Marc31]

Et oui j'avais oublié d'ajouter pdf creator au projet, erreur de debutant....

[Marc-L]

Bonjour.

J'ai trouver un code qui ne marche pas sur internet qui transforme un document word en pdf.

Normal, comme d'hab' !

Mais pourquoi diable poser la question dans un forum dédié à Excel au lieu de celui pour Word directement ?‼