Discussion :

[Rat-Thon]

Bonjour a tous,

Je bosse sur un projet pour le boulot concernant un tableau excel et comme je suis débutant, je me demande si je n'ai pas les yeux plus gros que le ventre

Je bute sur une fonction et malgré mes recherches, je ne trouve pas ce que je veux, donc je viens demander un coup de main.

J'ai un classeur avec une feuille par mois + une feuille récapitulative (donc 13 feuilles)
Toutes les feuilles "mois" sont identique dans leur structure.
Il s'agit d'un tableau pour des visites sur différents sites avec des visites mensuelles et annuelles.
Sur chaque feuille, (dans la colonne P, via une liste) on peux choisir le type de visite et (dans la colonne Q), la date de la visite.

Je voudrai donc que dans la 13eme feuille (Recap Annuelle) il me copie automatiquement les dates issues de "Q" si P = "Annuelle", sachant qu'il ne peux avoir qu'une annuelle par site par an.

J'ai essayer avec la fonction SI mais je suis limité a 7 "SI", donc je cherche une alternative. J'ai essayé en découpant le formule sur 2 cellules, mais le résultat final est affiché en nombre et non en date (malgré la mise en forme)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(Janvier!P3="Annuelle";Janvier!Q3;SI(Février!P3="Annuelle";Février!Q3;SI(Mars!P3="Annuelle";Mars!Q3;SI(Avril!P3="Annuelle";Avril!Q3;SI(Mai!P3="Annuelle";Mai!Q3;SI(Juin!P3="Annuelle";Juin!Q3;""))))))

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=E3 & SI(Juillet!P3="Annuelle";Juillet!Q3;SI(Aout!P3="Annuelle";Aout!Q3;SI(Septembre!P3="Annuelle";Septembre!Q3;SI(Octobre!P3="Annuelle";Octobre!Q3;SI(Novembre!P3="Annuelle";Novembre!Q3;SI(Décembre!P3="Annuelle";Décembre!Q3;""))))))

Merci d'avance.

[Daniel.C]

Bonjour,

Une façon de contourner la limitation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=N(janvier!P3="Annuelle")*janvier!Q3+N(Février!P3="Annuelle")*Février!Q3

à compléter pour les 12 mois.

[Rat-Thon]

En plus d’être rapide, ça marche

Merci bcp

Par contre, comme le tableau sera rempli au fur et a mesure, lorsqu'il n'y a pas d'annuelle, il me met : "00/01/00". Y a t'il possibilité de ne rien mettre si pas de valeur ou genre si pas de valeur, case vide fond rouge et si valeur, valeur sur fond vert.

[Daniel.C]

Le plus simple est de changer le format de cellule et de mettre un format de nombre personnalisé : "jj/mm/aaaa;;"
Une autre approche est d'ajouter un "SI" à ta formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(formule=0;"";formule)

C'est à dire que la date s'affiche seulement si le nombre (qui représente la date) est supérieur à 0, sinon on n'affiche rien. Pour la coloration, mets une deux mises en forme conditionnelles, une pour le vert avec la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=A1>0

(remplace A1 par la cellule contenant la formule.)
et une pour le rouge avec la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=A1=0

A vrai dire, si tu colories la cellule en rouge, tu n'as besoin que de la première mise en forme conditionnelle. Si tu n'est pas familiarisé avec les mises en forme conditionnelles, dis-le.

[Rat-Thon]

Allez, pour le plaisir des yeux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(N(Janvier!P3="Annuelle")*Janvier!Q3+N(Février!P3="Annuelle")*Février!Q3+N(Mars!P3="Annuelle")*Mars!Q3+N(Avril!P3="Annuelle")*Avril!Q3+N(Mai!P3="Annuelle")*Mai!Q3+N(Juin!P3="Annuelle")*Juin!Q3+N(Juillet!P3="Annuelle")*Juillet!Q3+N(Aout!P3="Annuelle")*Aout!Q3+N(Septembre!P3="Annuelle")*Septembre!Q3+N(Octobre!P3="Annuelle")*Octobre!Q3+N(Novembre!P3="Annuelle")*Novembre!Q3+N(Décembre!P3="Annuelle")*Décembre!Q3=0;"Pas Fait";N(Janvier!P3="Annuelle")*Janvier!Q3+N(Février!P3="Annuelle")*Février!Q3+N(Mars!P3="Annuelle")*Mars!Q3+N(Avril!P3="Annuelle")*Avril!Q3+N(Mai!P3="Annuelle")*Mai!Q3+N(Juin!P3="Annuelle")*Juin!Q3+N(Juillet!P3="Annuelle")*Juillet!Q3+N(Aout!P3="Annuelle")*Aout!Q3+N(Septembre!P3="Annuelle")*Septembre!Q3+N(Octobre!P3="Annuelle")*Octobre!Q3+N(Novembre!P3="Annuelle")*Novembre!Q3+N(Décembre!P3="Annuelle")*Décembre!Q3)

+ 2 mises en forme conditionnelle
(merci le copier/coller)

Un grand merci a toi Daniel

(note pour plus tard, demander un stage excel.)