Discussion :

[philippe6]

Bonjour,

j'ai un classeur excel d'une vingtaine de feuilles, la première feuille est une présentation du classeur avec une vingtaine de boutons associés aux feuilles avec le thème de la feuille comme nom sur le bouton, le bouton permet d'atteindre la feuille , puis arrivé sur la feuille, j'ai un bouton pour revenir à la "page de présentation".

Je me demande si une listBox ne serait pas mieux que les boutons sur la page de présentation, une listeBox contenant le nom des feuilles (ceux qui sont sur les onglets).
Il y a un truc qui me semble mieux : ça devrait prendre moins de place.
Il y a un truc qui ne va pas du tout : je ne sais pas le faire !!!
Pire : je ne sais même pas si la listbox est le plus indiqué dans ce cas.

Pourriez vous me mettre sur la voie ?

Merci,

Philippe

[Daniel.C]

Bonjour,

Même si trouves, après coup, que ce n'est pas mieux, tu auras au moins appris à le faire. Est-ce que tu sais dessiner une listbox sur ta feuille ?

[philippe6]

Bonjour,

merci de ta réponse.

Oui, le sais dessiner la listebox à partir de la boite à outil de vba (cependant je confond peur-être avec une checkbox !).
Mais ensuite je ne sais pas affecter de code aux items de la listbox comme par exemple pour un bouton.

[Daniel.C]

Quelle est ta version d'Excel ? Est-ce que tu as utilisé la boîte à outils "Formulaire" ou la boîte à outils "contrôles ActiveX" ? Quand tu mets le curseur sans cliquer sur l'icône, tu vois s'afficher le type du contrôle dans une bulle.

[philippe6]

J'ai excel 2002, mais je suis je le reçois d'un serveur dans un intranet et la boite à outil (des contrôles) est toute petite, une douzaine , tu peux faire apparaitre une liste de contrôles supplémentaires où il y a bien une listebox la liste est présentée comme une feuille de menu dans un restau, mais juste le nom du contrôle. Mais qu'importe je crois qu'i me faut une listbox (déroulante).

Désolé, mais je préfère te prévenir, je m'absente une heure
Philippe

[Daniel.C]

Pas de problème, chacun intervient sur le forum quand il est disponible. Le mieux serait que tu mettes une listbox sur un classeur vierge, que tu l'enregistres et que tu le mettes ici comme pièce jointe.

[philippe6]

Merci de ta patience, voici donc cette listbox

[Daniel.C]

Euh... Elle est sur quelle feuille ?
J'ai trouvé.

[philippe6]

J'ai crée un un userform et je l'ai placé dessus

je n'ai lu que la première ligne de ta réponse

[Daniel.C]

Tu peux mettre directement la listbox sur la feuille, comme je l'ai fait ou passer par un userform comme tu l'as fait. Si tu le mets sur un userform, il faut ajouter un bouton pour le faire apparaître. Si la listbox est sur la feuille, dans le module de la feuille, mets la macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_Activate()
    Me.ListBox1.ListIndex = -1
End Sub

qui efface la sélection précédente.

Egalement, la listbox sur la feuille sera remplie à l'ouverture du classeur. Dans le module "ThisWorkbook" tu mets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Workbook_Open()
    Dim sh As Worksheet
    Sheets("Accueil").ListBox1.Clear
    For Each sh In Sheets
        If sh.Name <> "Accueil" Then
            Sheets("Accueil").ListBox1.AddItem sh.Name
        End If
    Next sh
End Sub

Mets également dans le module de la feuille "CommandButton1 étant le nom du bouton) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub CommandButton1_Click()
    UserForm1.Show
End Sub

qui affiche le userform, et :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub ListBox1_Click()
    Application.Goto Sheets(Me.ListBox1.Value).[A1]
End Sub

qui débranche au clic sur la feuille choisie (listbox sur la feuille).

Dans le module de l'userform, mets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub ListBox2_Click()
    Me.Hide
    Application.Goto Sheets(Me.ListBox2.Value).[A1]
End Sub

qui fait le débranchement sur la feuille choisie et :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub UserForm_Activate()
    Dim sh As Worksheet
    Me.ListBox2.Clear
    For Each sh In Sheets
        If sh.Name <> "Accueil" Then
            Me.ListBox2.AddItem sh.Name
        End If
    Next sh
End Sub

qui remplit la listbox de l'userform.

Ca doit te paraître un peu compliqué, mais il y a deux solutions indépendantes donc tu peux éliminer celle qui est inutile. N'hésite pas à poser toutes les questions qui te viendront à l'esprit. Tout est repris dans le classeur joint.

[philippe6]

Ta réponse est tip-top, merci !
Il faut absolument que je récupère une méthode d'initiation, il ya trop de truc bien à faire !

Philippe