Discussion :

[BasicZX81]

Bonsoir à tous,
j'aimerais lire un fichier XML généré par une application tierce. Savez vous comment lire ce type de fichier ? Si possible en utilisant la deserialization mais la structure ne ressemble pas un un objet serializé à moins que je me trompe (ou à défaut avec une autre méthode si cela n'est pas possible).
Au final il faudra que je stocke les infos dans une liste d'objets "commercial" qui posséderont 2 propriétés "start" et "end".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
<?xml version="1.0" encoding="utf-8" ?>
<root>
  <commercial start="0.000000" end="38.320000" />
  <commercial start="203.960000" end="441.400000" />
  <commercial start="3216.760000" end="3567.400000" />
  <commercial start="6258.240000" end="6605.320000" />
  <commercial start="9157.960000" end="9427.560000" />
 </root>

Merci beaucoup pour votre aide.

[wallace1]

Bonsoir BasicZX81,

Il existe d'autres façons de faire pour ce devoir mais voilà une solution parmi tant d'autres :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
 
'Il s'agit d'un document xml donc j'utilise la classe XmlDocument pour parser le fichier
        Dim xdoc As New XmlDocument()
'Chargement de ton fichier sauvegardé en dur mais tu peux utiliser la routine LoadXml pour charger le texte directement !
        xdoc.Load("C:\test.xml")
 
'Instanciation d'une liste d'objets de la classe commercial créée préalablement
        Dim ObjList As New List(Of Commercial)
'On parcours chaque noeuds pour trouver ceux qui contiennent le nom "Commercial"
        For Each it As XmlNode In xdoc.GetElementsByTagName("commercial")
'Déclaration de la classe commercial qui possède 2 propriétés (Start et End)
            Dim ObjComm As New Commercial()
' On parcours tout les attributs des noeuds
            For Each att As XmlAttribute In it.Attributes
'Le nom de l'attribut est "start" alors on récupère sa valeur et on l'affecte à la propriété "End" de la classe "Commercial"
                If att.Name = "start" Then
                    ObjComm.pstart = ("Start : " & att.Value)
                End If
'Le nom de l'attribut est "end" alors on récupère sa valeur et on l'affecte à la propriété "Start" de la classe "Commercial"
                If att.Name = "end" Then
                    ObjComm.pend = ("End : " & att.Value)
                End If
            Next
'Ajout de l'objet commercial à la liste
            ObjList.Add(ObjComm)
        Next
 
 
'On test que tout fonctionne en parcourant la liste d'objets
        For Each it In ObjList
            MsgBox(it.pstart & "---" & it.pend)
        Next
 
 
'La classe Commercial
    Friend Class Commercial
 
        Private _pstart As String
        Public Property pstart() As String
            Get
                Return _pstart
            End Get
            Set(ByVal value As String)
                _pstart = value
            End Set
        End Property
 
        Private _pend As String
        Public Property pend() As String
            Get
                Return _pend
            End Get
            Set(ByVal value As String)
                _pend = value
            End Set
        End Property
 
    End Class

A+

[tomlev]

Si possible en utilisant la deserialization mais la structure ne ressemble pas un un objet serializé à moins que je me trompe

A quoi est supposé ressembler un objet sérialisé d'après toi ? Tout dépend de comment il a été sérialisé

Tu peux déclarer une classe comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
<XmlType("commercial")>
Public Class Commercial
    <XmlAttribute("start")>
    Property PeriodStart As Decimal
    <XmlAttribute("end")>
    Property PeriodEnd As Decimal
End Class

(note : j'ai renommé start et end en PeriodStart et PeriodEnd, parce que End est un mot réservé en VB)

Pour désérialiser, tu peux faire comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Dim xs As New XmlSerializer(GetType(List(Of Commercial)), New XmlRootAttribute("root"))
Dim commerciaux As List(Of Commercial)
Using stream = File.OpenRead(fileName)
    commerciaux = CType(xs.Deserialize(stream), List(Of Commercial))
End Using

[BasicZX81]

Merci beaucoup Tomlev, ca fonctionne exactement comme je voulais.
@wallace1, merci beaucoup aussi, je garde ton code dans les cas ou je ne pourrais pas deserializer.