Discussion :

[bob456]

Bonjour,

Cela fait plusieurs jours que j'ai l'erreur suivante...
J'ai du mal à comprendre pourquoi, des fois cela fait l'erreur des fois nan...
Lorsque que j'ai crée le graphique j'ai

"La méthode 'SerieCollection' de l'objet '_Chart' a échoué erreur 1004"

Je suppose que c'est le fait que la macro n'arrive pas a choper le grpahique mais je ne vois pas comment faire mieux pour qu'elle le sélectionne...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub creation_diagramme(total_dd, total_dnd, total_di, total_deee, feuille_de_donnee As String)
    Worksheets(feuille_de_donnee).Activate
 
    Charts.Add
    ActiveChart.ChartType = xlPie
    ActiveChart.SeriesCollection(1).XValues = Array("DD", "DND", "DI", "DEEE")
    ActiveChart.SeriesCollection(1).Values = Array(total_dd, total_dnd, total_di, total_deee)
    ActiveChart.SeriesCollection(1).Name = "=""Répartition des déchets"""
    ActiveChart.SeriesCollection(1).Points(1).Interior.ColorIndex = dechet_dangereux
    ActiveChart.SeriesCollection(1).Points(2).Interior.ColorIndex = dechet_non_dangereux
    ActiveChart.SeriesCollection(1).Points(3).Interior.ColorIndex = dechet_inerte
    ActiveChart.SeriesCollection(1).Points(4).Interior.ColorIndex = dechet_electique
    ActiveChart.Location Where:=xlLocationAsNewSheet, Name:="Répartition des déchets"
    ActiveChart.Deselect
 
End Sub

Merci pour votre futur aide,


Edit : J'ai 0 SeriesCollection, je ne sais pas pourquoi..

[PMO2017]

Bonjour,

Peut être une piste avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub creation_diagramme(total_dd, total_dnd, total_di, total_deee, feuille_de_donnee As String)
    Worksheets(feuille_de_donnee).Activate
 
    Charts.Add
    ActiveChart.ChartType = xlPie
 
'--- il faut ajouter l'instruction suivante en adaptant le Range concerné ---
   ActiveChart.SeriesCollection.Add Source:=ActiveWorkbook.Worksheets(feuille_de_donnee).Range("B1:B10")
 
 
    ActiveChart.SeriesCollection(1).XValues = Array("DD", "DND", "DI", "DEEE")
    ActiveChart.SeriesCollection(1).Values = Array(total_dd, total_dnd, total_di, total_deee)
    ActiveChart.SeriesCollection(1).Name = "=""Répartition des déchets"""
    ActiveChart.SeriesCollection(1).Points(1).Interior.ColorIndex = dechet_dangereux
    ActiveChart.SeriesCollection(1).Points(2).Interior.ColorIndex = dechet_non_dangereux
    ActiveChart.SeriesCollection(1).Points(3).Interior.ColorIndex = dechet_inerte
    ActiveChart.SeriesCollection(1).Points(4).Interior.ColorIndex = dechet_electique
    ActiveChart.Location Where:=xlLocationAsNewSheet, Name:="Répartition des déchets"
    ActiveChart.Deselect
 
End Sub

[bob456]

Le problème c'est qu'il n'y a pas du tout besoins de données dans des cellules enfaite...
J'ai directement les résultats dans des variables.

Je vais essayer de mettre un range imaginaire.

Ce que je comprend pas c'est que la j'ai testé 15 fois aucune erreur et en refaisant la même chose ca vient de me le refaire plusieurs fois d'affilé...

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub Creation_Diagramme(ByVal Total_dd As Double, ByVal Total_dnd As Double, ByVal Total_di As Double, ByVal Total_deee As Double)
Const StrNom As String = "Répartition des déchets"
Dim Sr As Series
 
Application.ScreenUpdating = False
'Pour supprimer d'abord l'éventuelle feuille graphique
'---------------------------
On Error Resume Next
Application.DisplayAlerts = False
ThisWorkbook.Sheets(StrNom).Delete
Application.DisplayAlerts = True
On Error GoTo 0
'---------------------------
 
With ThisWorkbook.Charts.Add
    .Name = StrNom
    .ChartType = xlPie
 
    If .SeriesCollection.Count = 0 Then
        Set Sr = .SeriesCollection.NewSeries
    Else
        Set Sr = .SeriesCollection(1)
    End If
 
    With Sr
        .XValues = Array("DD", "DND", "DI", "DEEE")
        .Values = Array(Total_dd, Total_dnd, Total_di, Total_deee)
        .Name = StrNom
        .Points(1).Interior.ColorIndex = 9       'dechet_dangereux
        .Points(2).Interior.ColorIndex = 11      'dechet_non_dangereux
        .Points(3).Interior.ColorIndex = 26      'dechet_inerte
        .Points(4).Interior.ColorIndex = 37      'dechet_electique
    End With
End With
End Sub

[bob456]

Ça marche parfaitement pour le moment.

Le code est propre je savais pas que l'on pouvait faire "NewSeries".

merci