Discussion :

[ericdev67]

Bonjour

J'ai différents dossiers (nommés par "nom des personnes"), dans lequel se trouve des photos, des documents, etc...
J'ai un tableau Excel avec des noms (colonne A), prénoms (colonne B). En colonne C, j'aimerai mettre un lien hypertexte ou déclencheur pour que lorsque je clique dessus, la liste des fichiers présents dans le dossier s'affiche et que je puisse sélectionner son ouverture.

Exemple : Dossier "Eric", dans le C, contient Photo1 (jpeg), photo2 (jpeg), fichier "essais" (fichier word), fichier "tab" (excel)
Je clique sur le "déclencheur" de la colonne C, et une listebox ou un Userform s'affiche et liste les fichiers. Je sélectionne photo2 et l'image s'ouvre....

J'ai regardé dans la FAQ : http://faqvbnet.developpez.com/?page=form_lb qui semblerait faire cette opération, mais je l'ai mis dans un classeur, en Thisworkbook, mais rien ne se passe.....Je pense que c'est normal car il n'y a pas le chemin, mais je ne vois pas comment je peux utiliser ce code....

Une petite aide ?

Merci,

A+

[Theze]

Bonjour,

Teste ce qui suit et adapte. A mettre dans le module de la feuille, ajouter sur la feuille un bouton ActiveX ainsi qu'une ListBox ActiveX. Pour tester, il te faut adapter la constant Lecteur (ici D:\) et sélectionner la cellule contenant le nom du dossier que tu souhaite ouvrir puis tu clique sur le bouton, la ListBox devrait se remplir des noms des fichiers contenus dans le dossier ensuite, 1 clic dans la Listbox sur un nom devrait ouvrir le fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
 
Private Declare Function OuvrirProg _
                Lib "shell32.dll" _
                Alias "ShellExecuteA" ( _
                ByVal hwnd As Long, _
                ByVal lpszOp As String, _
                ByVal lpszFile As String, _
                ByVal lpszParams As String, _
                ByVal lpszDir As String, _
                ByVal FsShowCmd As Long) As Long
 
Dim Nom As String
Const Lecteur As String = "D:\"
 
Private Sub CommandButton1_Click()
 
    Dim Tbl() As String
    Dim I As Integer
 
    'ici, le nom du dossier est dans la cellule active, à adapter...
    Nom = ActiveCell
 
    'le lecteur est D, à adapter...
    Tbl = Fichiers(Lecteur & Nom)
 
    'en colonne "A" de la feuille active si pas vide
    If Not (Not Tbl) Then
 
        ListBox1.Clear
 
        For I = 1 To UBound(Tbl)
 
            ListBox1.AddItem Tbl(I)
 
        Next I
 
    End If
 
End Sub
 
Private Sub ListBox1_Click()
 
    Dim Retour As Long
    Dim Fichier As String
 
    Fichier = Lecteur & Nom & "\" & ListBox1.Text
 
    'au cas où "Nom" soit égal à ""
    Fichier = Replace(Fichier, "\\", "\")
 
    If InStr(ListBox1.Text, ".xls") Or InStr(ListBox1.Text, ".csv") Then
 
        Workbooks.Open (Fichier)
 
    Else
 
        Retour = OuvrirProg(0, "open", Fichier, vbNullString, vbNullString, 3)
 
    End If
 
End Sub
 
Function Fichiers(Chemin As String) As String()
 
    Dim TableauFichiers() As String
    Dim Fichier As String
    Dim I As Integer
 
    'complète le chemin le cas échéant
    If Right(Chemin, 1) <> "\" Then Chemin = Chemin & "\"
 
    'boucle dans le dossier jusqu'à la fin des fichiers et rempli le tableau
    Fichier = Dir(Chemin)
 
    Do While (Len(Fichier) > 0)
 
        I = I + 1
 
        ReDim Preserve TableauFichiers(1 To I)
 
        TableauFichiers(I) = Fichier
 
        Fichier = Dir()
 
    Loop
 
    Fichiers = TableauFichiers()
 
End Function

Hervé.

[ericdev67]

Merci Theze,

J'ai bien compris la manip, et ton code et je te remercie. Par contre, je ne suis pas très à l'aise avec les Userform et Listbox...et le code plante au premier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ListBox1

et je pense qu'il doit manquer un truc dans ma ListBox1, mais je ne vois pas où....

Si tu pouvais me donner un petit coup de main...merci (je mets l'exemple en PJ)

Une autre question : est-on obligé de passer par un CommandButton ? En effet, j'ai 1000 lignes, donc, d'après ce que j'ai compris de ton code : on sélectionne en colonne A, le nom, on clique sur le CommandButton et la ListBox (enfin quand elle est bien configurée...) apparait. Je pensais mettre une croix, en colonne C, qui indiquerait si il existe un dossier (en mettant une "X" par exemple) et lorsque je clique dessus, cela génère la ListBox .....

Merci pour ton aide,

A+

[SfJ5Rpw8]

Bonjour,

et ton code il plante quoi ?

J'ai bien compris la manip, et ton code et je te remercie. Par contre, je ne suis pas très à l'aise avec les Userform et Listbox...et le code plante au premier

[ericdev67]

Merci bbil,

j'ai le message :

Erreur de Compilation : Membre de méthode ou de données introuvable

et le code s'arrête au premier ListBox1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ListBox1.AddItem Tbl(I)

(J'ai mis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

  ListBox1.Clear

en

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

  ' ListBox1.Clear

, c'est pour cela que je parle du "premier" ListBox1


(Par contre, je n'ai pas compris pourquoi tu m'as enlevé ma PJ : je pense que c'est ma ListBox1 qui est mal déclarée, j'ai fait "insérer un Userform", j'ai mis une ListBox, renommé ListBox1, idem dans la partie "caption", et cela ne fonctionne pas....donc, je ne comprends pas où ça coince....d'où ma PJ...)


Merci,

A+

[SfJ5Rpw8]

Le code est bien placé dans un userfom , sur lequel se trouve une listbox nommée listbox1 ?