Discussion :

[Simplifi]

Bonjour à tous,
pour des raisons de rapidité, j'ouvre un recordset avec un texte SQL et je teste le nombre d'enregistrements (recordcount) si = 0, je passe à la suite
sinon, je voudrai ouvrir un formulaire basé sur ce recordset.
je sais faire ça en attribuant le texte SQL à la propriété recordsource. mais il me semble que cette requête doit être re-moulinée à ce moment là
Y a t il une solution pour affecter directement le recordset déjà constitué à la source du formulaire?
merci

[paidge]

Bonjour,
j'aurais tendance à penser à qqe chose comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Dim strSQL As String
Dim rst As DAO.Recordset
 
strSQL = "SELECT * FROM MaTable;"
Set rst = CurrentDb.OpenRecordset(strSQL)
rst.MoveLast
 
If rst.RecordCount = 0 Then
    ......
Else
    DoCmd.OpenForm "MonFormulaire", acNormal, , , acFormEdit, acWindowNormal
    With Forms("MonFormulaire")
        .RecordSource = strSQL
        .Requery
    End With
End If

[Simplifi]

Merci pour la rapidité!!
c'est bien la méthode que j'utilise pour le moment
mais j'ai l'impression que Access résout des fois le SQL, une pour alimenter le recordset, une pour alimenter le formulaire.
Et comme chaque formulaire possède son recordset, qu'on peut d'ailleurs récupérer (Rs = forms!mon_form.recordset), je cherche à faire le contraire (forms!mon_form.recordset = Rs)
là, j'ai une erreur: 3251 Opération non autorisée pour ce type d'objet

je cherche donc la bonne solution

PS: ces requêtes (à l'origine du SQL) sont des recherches d'erreurs et il y en a une trentaine pour le moment ce qui fait que ma première méthode de requêtes-ajouts dans une table et formulaire sur cette table est bien lente!!

[mumen]

Y a t il une solution pour affecter directement le recordset déjà constitué à la source du formulaire?

Je n'y crois pas, d'ailleurs "Opération non autorisée pour ce type d'objet".

Quand tu dis

pour des raisons de rapidité, j'ouvre un recordset avec un texte SQL et je teste le nombre d'enregistrements (recordcount) si = 0, je passe à la suite

Tu fais un MoveLast pour tester le RecordCount ? Parce que si oui, tester le EOF suffirait à te dire si tu as au moins un enregistrement sans aller jusqu'au bout du RecordSet.

[mumen]

Maintenant, si ton ouverture de requête est vraiment longue par rapport aux sorties attendues (des erreurs, ça doit être rare), au point que la multiplier par deux est gênant, alors fais une table temporaire avec le résultat et ouvre le formulaire dessus.

[LedZeppII]

Bonjour,

Je crois que c'est à ça que tu pensais :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Compare Database
Option Explicit
 
' Recordset global
Dim rsFm As DAO.Recordset
 
 
Private Sub Form_Load()
Dim sSql As String
' Ouvrir le recordset global
sSql = "SELECT * FROM Clients"
Set rsFm = Application.CurrentDb.OpenRecordset(sSql, dbOpenDynaset)
' En faire la source du formulaire
Set Me.Recordset = rsFm
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
' Déconnecter le formulaire du recordset
Set Me.Recordset = Nothing
' Libérer/fermer le recordset global
Set rsFm = Nothing
End Sub

Ce que j'ai fait :
- J'ai créé un formulaire basé sur la table Clients.
- J'ai supprimé la source du formulaire (mise à blanc de la propriété Données>Source qui contenait «Clients»)
- J'ai ajouté le code ci-dessus.

A+

[Simplifi]

Merci à tous!
effectivement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

       Forms!Résidus.Form.Recordset = Rs

donne une erreur mais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

       Set Forms!Résidus.Form.Recordset = Rs

fonctionne
l'erreur était dans le détail

[Simplifi]

Juste pour ceux que la programmation complète intéresserait:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Function Filtre_à_Résidus(Devis As Long) As Integer
Dim  Rs As DAO.Recordset
Dim Txt_Sql As String
 
'DoCmd.SetWarnings False
'DoCmd.RunSQL "DELETE * FROM Résidus;" ' plus besoin de table
'DoCmd.OpenQuery "Résidus_export_certif_devis_1" 'précédente méthode avec requêtes ajout
    Txt_Sql = "SELECT [N° de proposition] as N°devis, 'Opérations' as Formulaire, 'Ref' as Champ, Ref as Valeur_problématique, 'N°prop' as Clef, ""Libellé de l'opération"" as Commentaire"
    Txt_Sql = Txt_Sql & " FROM (Devis_détail INNER JOIN Devis_détail_plus ON (Devis_détail.[N° de proposition] = Devis_détail_plus.N°prop) AND (Devis_détail.[N° de proposition] = Devis_détail_plus.N°prop)) LEFT JOIN Acc_cert ON Devis_détail_plus.Ref = Acc_cert.CODE"
    Txt_Sql = Txt_Sql & " WHERE n_dev_1=" & Devis & " AND CODE Is Null AND Typ='ops';"
    Set Rs = CurrentDb.OpenRecordset(Txt_Sql)
    If Rs.RecordCount > 0 Then
        DoCmd.OpenForm "Résidus"
        Set Forms!Résidus.Form.Recordset = Rs
        Filtre_à_Résidus = 0
        Exit Function
    Else
        Filtre_à_Résidus = 1
    End If
End If

et pour inspirer ....

[mumen]

Set Me.Recordset = rsFm

J'admire. Et cela laisse à présager d'autres possibilités.

Il s'est passé des choses depuis Access 97 !

[paidge]

En effet Je suis avec Access 97 au boulot et quand je me suis penché sur le problème, je ne trouvais pas de propriété .Recordset pour les objets Forms....A part le .RecordsetClone qui est en lecture seule, il n'y a rien...D'où ma proposition :p Mais qd j'aurai l'occasion de travailler sur une version plus récente d'Access, je sens que je m'en servirai

[ouali_0033]

Bonjour,
SVP, j'ai une question à vous posez.
est-il possible d'affecter un recordset à un champ d'un sous formulaire dans access comme cette façon:
voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
 
'Requête SQL table
    SQL = "SELECT tachesdeSuiviedeProjet.tache FROM tachesdeSuiviedeProjet"
    SQL = SQL & "  WHERE (((tachesdeSuiviedeProjet.TypeProjet)="
    SQL = SQL & Typeprojet
    SQL = SQL & "));"
 
Set rstTaches = CurrentDb.OpenRecordset(SQL, dbOpenForwardOnly)
 
 
 
 Set Me![FichedeSuiviedeProjet]![taches].Recordset = rstTaches!tache

merci

[tee_grandbois]

bonsoir,

est-il possible d'affecter un recordset à un champ d'un sous formulaire dans access comme cette façon:

un recordset est un jeu d'enregistrements, c'est à dire une ou plusieurs lignes contenant chacune une ou plusieurs colonnes: comment penses-tu affecter un champ avec cela ?
c'est comme essayer de faire entrer une feuille excel dans une seule case ...

[ouali_0033]

Bonjour,

tous d'abord, je vous remercie d'avoir répondu à ma question
je vous explique mon besoin:

j'aimerais afficher le résultat d'une requête SQL (plusieurs enregistrement ) dans un sous formulaire lier à une table pour que je puisse par la suite continuer à remplir les autres champs

Exemple:
j'ai une table projet qui a pour colonnes : id, titre, typeProjet, dateMES,...............
une table fichedesuivie qui a pour colonnes: id, idprojet, typeProjet, tâches.......
une autre table listedestache aui a pour colonnes: id, typeProjet, listetaches (association entre les deux tables se fait par le type de projet )
en effet pour chaque type de projet, j'ai une liste des tâches bien précise donc ce que je veut faire c'est que une fois que je choisie le type de projet dans le formulaire projet, le champ listetaches de sous formulaire de la table fichedeSuivie se met à jour avec la liste des tâches associé au type de projet


merci beaucoup