Discussion :

[Délie]

Bonjour,

je viens vers vous car je me trouve confronter à un problème un peu étrange...

Je dois additionner des gros volumes horaires tel que :
A1 :65535:00
A2 :897775:45
A3 :89631456:12
A4 :457681289:50
A5 :=A1+A2+A3+A4

Toutes mes cellules sont misent au format :[hh]:mm
Toutefois je n'arrive pas à taper les montants horaires dans les cellules, de fait à partir de 65536:00 Excel modifie les nombres et idem pour mon addition.
Que faire ? le calcul à la main est extrêmement fastidieux !
Merci de votre aide

[rjamin]

Bonjour,
Je crois qu'un moyen serait de décimaliser les nombres d'heures
656335:00 = 65535,00
897775:45 = 897775,75
89631456:12 = 89631456,20
457681289:50 = 457681289,833333
la somme en décimal donne 548.276.056,78333

soit en transformant 0,78333 en minute 0.78333*60 = 46,9999999 soit 47 min

donc le total serait 548.276.056:47

Attention qu'Excel ne traite pas les nombres de plus de 17 chiffres

[keygen08]

Sauf que 0.78 en min, cela fait 1H47
donc le vrai total serait de 548.276.057:47

[papouclo]

Bonjour,
Le résultat décimalisé 548.276.056,78333 étant un nombre d'heures, ce serait vraiment étonnant que 0.78 h fasse 1h 47
Robert Jamin a donné la méthode.
Pour ne pas avoir de problèmes de conversion, quelques formules pour transformer les écritures.
L'écriture 897775:45 en A1 étant considéré comme du texte, la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=CNUM(GAUCHE(A1;NBCAR(A1)-3))+CNUM(DROITE(A1;2))/60

renvoie l'heure décimale 897775,75 dans une autre cellule.
La somme 548276056,8 étant calculée et exprimée en heures décimales dans la cellule D1, la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=TEXTE(ENT(D1);"# ###")&":"&TEXTE(ARRONDI(MOD(D1;1)*60;0);"00")

renvoie la somme transcrite en texte dans le format [h]:mm soit 548 276 056:47.
Enfin , si l'on ne veut pas de réponses intermédiaires, en appelant durées la plage de durées à additionner, on peut s'en sortir en concentrant ces différentes formules en une seule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=TEXTE(ENT(SOMME(CNUM(GAUCHE(durées;NBCAR(A2:A5)-3))+CNUM(DROITE(durées;2))/60));"# ###")&":"& TEXTE(ARRONDI(MOD(SOMME(CNUM(GAUCHE(durées;NBCAR(durées)-3))+CNUM(DROITE(durées;2))/60);1)*60;0);"00")

à valider avec ctrl + maj + entrée.
Cordialement
Claude

[keygen08]

Autant pour moi
d'ailleurs, loin de vouloir insister, le vrai resultat est 548 866 856 H et 47 min

[Délie]

Merci beaucoup pour vos éléments de réponse c'est très intéressant !

j'ai testé la double formule : décimaliser les formats horaires puis les retranscrire en texte "h :mm" cela fonctionne très bien ! merci
Par contre la formule globale me donne une somme de 457 681 289:23 au lieu de 548 276 056:47 et cette réponse semble immuable même si je change les valeurs des cellules de la plage (A1:A4)=durées
je vous avoue ne pas comprendre le rôle des fonctions de cette dernière formule, c'est dommage...
j'aimerai bien que vous m'expliquiez plus en détail la syntaxe de cette formule, c'est très intéressant, j'aimerais en comprendre le sens.
De plus cette formule globale me semble plus intéressante à mettre en place dans le cadre de retraitement de données issues de fichiers CSV.

merci, cordialement

[papouclo]

Bonjour,
Toutes mes excuses pour le retard de ma réponse
Au temps pour moi !
Dans mes essais, la plage de "données - textes", nommée durées, était en A2:A5 et lorsque j'ai établi la formule globale , j'ai oublié un remplacement de NBCAR(A2:A5) par NBCAR(durées) ; cela ne posait pas de problème sur mon classeur et j'ai donc réécrit la formule dans mon post; malheureusement, elle ne pouvait renvoyer un résultat exact, recopiée dans un autre classeur où la plage durées est en A1:A4 ou n'importe où ailleurs qu'en A2:A5.
La formule globale correcte est la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=TEXTE(ENT(SOMME(CNUM(GAUCHE(durées;NBCAR(durées)-3))+CNUM(DROITE(durées;2))/60));"# ###")&":" & TEXTE(ARRONDI( MOD( SOMME( CNUM(GAUCHE(durées;NBCAR(durées)-3))+CNUM(DROITE(durées;2))/60);1)*60;0);"00")

à valider par ctrl + maj + entrée.
Cette formule est obtenue en imbriquant les deux formules "simples" données et bien sûr une formule de calcul de la somme. Un peu de couleur mettra peut-être en évidence cette imbrication :
{ = TEXTE(ENT( SOMME( CNUM(GAUCHE(durées;NBCAR(durées)-3))+CNUM(DROITE(durées;2))/60 ) );"# ###")&":"&TEXTE(ARRONDI(MOD( SOMME( CNUM(GAUCHE(durées; NBCAR(durées)-3))+CNUM(DROITE(durées;2))/60 ) ;1)*60;0);"00") }
Cordialement
Claude

[Délie]

merci beaucoup claude,

j'ai mis en pratique vos formules dont je commence à m'approprier la logique et cela fonctionne très bien et me fait gagner un temps précieux

cordialement,