Discussion :

[tixilee]

Bonjour.

Sur une meme feuille "AAA", je voudrais trouver une solution pour que
Pour chaque ligne (sauf ligne 1), avoir la valeur maximum entre la cellule de la colonne "East" et la colonne "Ouest"; le resultat etant cree dans une nouvelle colonne "Max" qui sera situee apres la derniere colonne remplie.

Dites-moi si je ne suis pas claire.

Merci.

[Alqualonde]

Bonjour Tixilee,

Voilà un code qui marche... si c'est bien la demande !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Macro1()
'
' Macro1 Macro
'
 
'
    numlignevide = Range("A2").End(xlDown).Row()
    numColVide = Range("A2").End(xlToRight).Column()
    For i = 2 To numlignevide
        Cells(i, numColVide + 1).FormulaR1C1 = "=MAX(RC[-2],RC[-1])"
    Next
End Sub

Edit : en supposant ici que la colonne Est et la colonne Ouest sont en colonnes A et B (à modifier selon besoins)

[papouclo]

Bonjour,
Voici un code possible

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub trouvermax()
'Déclaration des variables
Dim nlecol As Integer, derli As Integer
Dim col1 As Integer, col2 As Integer, i As Integer
 
'Sélection de la feuille AAA
    Sheets("AAA").Select
 
'Détermination de la colonne Max et de la dernière ligne
    nlecol = ActiveSheet.UsedRange.Columns.Count + 1
    derli = ActiveSheet.UsedRange.Rows.Count
    Cells(1, nlecol).Formula = "Max"
 
'Détermination des colonnes East et Ouest
    For i = 1 To nlecol - 1
        If Cells(1, i).Value = "East" Then
            col1 = i
        End If
        If Cells(1, i).Value = "Ouest" Then
            col2 = i
        End If
    Next i
 
' Détermination et écriture du maximum cherché sur chaque ligne
    For i = 2 To derli
        Cells(i, nlecol).Value = Application.WorksheetFunction.Max(Cells(i, col1).Value, Cells(i, col2).Value)
    Next i
 
End Sub

Cordialement
Claude

Edit : c'est Alqualonde qui a raison; lorsqu'on écrit la macro, on sait quelles sont les colonnes East et Ouest et c'est inutile d'écrire des lignes pour leur détermination.

[tixilee]

Merci, cela fonctionne parfaitement!