Discussion :

[kedmard]

Bonjour à tous,

Mon problème fait suite à la discussion :http://www.developpez.net/forums/d12...meme-classeur/

Je m'explique, j'ai une macro qui copie les cellules d'un tableau (à 3 champs Numsecu, Nom, Club) contenu dans une feuille nommée Source pour les coller dans une autre nommée Copie selon le critère de ressemblance du champ "Numsecu" c-à-d que lorsque la valeur du champ "Numsecu"
est la même dans chaque onglet alors toute la ligne correspondante est copiée dans Source puis collée dans Copie.

Tout cela ma macro arrive à le faire sans problème, ce que je souhaite c'est de laisser vide les champs Nom et Club (dans la feuille Copie) quand Numsecu n'est pas le même dans chaque onglet.


Pour mon exemple ci-joint, je veux qu'une fois ma macro exécuter, que les champs Nom et Club de Robinho et Ronaldo (de la feuille Copie) soient vides .




Voici la code qui me fait la copie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub sc()
Dim endlig As Long
Dim i As Long
Dim recherche As Range
Dim c As Range
 
With Sheets("Copie")
endlig = .Cells(5, 5).End(xlDown).Row
 
    For i = 6 To endlig
 
        Set recherche = .Cells(i, 5)
        With Worksheets("Source").Range("D11:D14")
            Set c = .Find(recherche, LookIn:=xlValues)
            If Not c Is Nothing Then
                recherche.Offset(0, 1) = c.Offset(0, 1)
                recherche.Offset(0, 2) = c.Offset(0, 2)
            End If
        End With
    Next i
End With
 
End Sub

Merci d'avance pour votre si précieuse



Ci-joint mon fichier.

[brownthefou]

Bonjour,

j'ai un peu survolé ton message je n'ai pas vraiment le temps, mais il te serait possible de faire une macro comparaison qui ferait (après remplissage de toutes les cellules par ta première fonction) :

• Comparer cellule (X1) de Feuil1 à la cellule (X2) de Feuil2
• Si différent, vider la cellule

Il y a possibilité de stocker les cellules dans des strings du coup du a juste une comparaison à faire entre 2 strings.

Je ne sais pas si j'ai pu t'aider beaucoup ...

Bon courage

Cordialement

[gFZT82]

Bonjour,

Si j’ai bien compris, pour réaliser le traitement tel que tu le décris, il suffit d’effacer les données Nom-Club de la feuille "Copie" puis de copier les données Nom-Club de la feuille "Source" si le même Numsécu est trouvé dans la feuille "Copie".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
Sub sc()
Dim WsSource As Worksheet
Dim WsCopie As Worksheet
Dim DerLigSource As Long, DerLigCopie As Long
Dim PlageSource As Range, PlageCopie As Range, Cel As Range
Dim Recherche As Range, c As Range
    Set WsSource = Worksheets("Source")
    Set WsCopie = Worksheets("Copie")
    DerLigSource = WsSource.Range("D" & WsSource.Rows.Count).End(xlUp).Row
    DerLigCopie = WsCopie.Range("E" & WsCopie.Rows.Count).End(xlUp).Row
    Set PlageSource = WsSource.Range("D11:D" & DerLigSource)
    Set PlageCopie = WsCopie.Range("E6:E" & DerLigCopie)
    'Effacement des données dans la feuille "Copie"
    PlageCopie.Offset(0, 1).Resize(, 2).ClearContents
    For Each Cel In PlageSource
        Set c = PlageCopie.Find(Cel, LookIn:=xlValues)
        If Not c Is Nothing Then
            c.Offset(0, 1) = Cel.Offset(0, 1)
            c.Offset(0, 2) = Cel.Offset(0, 2)
        End If
    Next
    Set c = Nothing
    Set PlageSource = Nothing
    Set PlageCopie = Nothing
    Set WsSource = Nothing
    Set WsCopie = Nothing
End Sub

Cordialement.

[kedmard]

Bonjour gFZT82,

Je te remercie vraiment pour ton aide ton code resoud mon problème ,

Merci à toi également brownthefou .

Je vais enfin avancée.

Bon weekend A vous.

Cordialement,

Kedmard.

Salut gFZT82,

Il y a juste ceci que je n'arrive pas à interpreter:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
PlageCopie.Offset(0, 1).Resize(, 2).ClearContents
    For Each Cel In PlageSource
        Set c = PlageCopie.Find(Cel, LookIn:=xlValues)
        If Not c Is Nothing Then
            c.Offset(0, 1) = Cel.Offset(0, 1)
            c.Offset(0, 2) = Cel.Offset(0, 2)
        End If
    Next

pourrais-tu me donner une explication? Merci.

[gFZT82]

PlageSource correspond à la plage des données Numsécu de la feuille "Source".
PlageCopie correspond à la plage des données Numsécu de la feuille "Copie".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

PlageCopie.Offset(0, 1).Resize(, 2).ClearContents

Effacement des 2 colonnes à droite de la plage des données Numsécu.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
For Each Cel In PlageSource
          Set c = PlageCopie.Find(Cel, LookIn:=xlValues)
          If Not c Is Nothing Then
                    c.Offset(0, 1) = Cel.Offset(0, 1)
                    c.Offset(0, 2) = Cel.Offset(0, 2)
          End If
Next

Pour chaque cellule de la plage source,
cherche la même valeur dans la plage cible
Si cette équivalence est trouvée, alors
copie le nom
copie le club

Cordialement.

[kedmard]

Salut gFZT82,

désolé pour cette réponse tardive, grand merci ton aide m'a été très précieuse .

Cordialement,


kedmard.