Discussion :

[Pastore]

Bonjour à tous !

J'aurais d'un petit coup de main, et je vous en remercie par avance !
Voilà mon problème :

Je voudrais copier dans les 3 cellules suivant "cible", la valeur de cible. Ensuite, j'aimerais que la cible gagne 5 lignes.

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Macro2()
 
    cible = Cells(19, 1)
 
    Cells(Range("cible").Row + 1, 1).Select
    ActiveCell.FormulaR1C1 = "=R[-1]C"
    Cells(Range("cible").Row + 2, 1).Select
    ActiveCell.FormulaR1C1 = "=R[-2]C"
    Cells(Range("cible").Row + 3, 1).Select
    ActiveCell.FormulaR1C1 = "=R[-3]C"
    Cells(Range("cible").Row + 4, 1).Select
 
    cible = cible + 5
 
 
End Sub

Il y a surement un problème de syntaxe dans la sélection de la ligne de "cible" mais je ne vois pas où ...

Merci encore !!

[Jean-Philippe André]

salut,

tu n'as pas déclaré cible. Est-ce une valeur numérique ? Est-ce une cellule ou plage de cellules ? Est-ce une chaîne de caractères ?

Toujours faire des déclarations de variables pour la lisibilité du code

Sans cette info, on va te proposer moultes idées qui ne correspondront pas nécessairement à ton cas de figure, donc ca fait gagner du temps à tout le monde

Pour déplacer entre les cellules, voir la fonction .Offset(). La syntaxe est donné dans l'aide en ligne

[Pastore]

Merci pour ta réponse !
En fait, cible représente une cellule cible. En regardant les variables disponibles, je ne vois que des variables numériques, texte, date ... Du coup, je dois utiliser variant ?

[Didier Gonard]

Bonjour,

voir ici ?

http://silkyroad.developpez.com/VBA/LesVariables/#LII-K


Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier

[Pastore]

Hum, je ne vois toujours pas où déclarer une cellule ...
En fait, dois-je déclarer la cellule elle-même ou bien la valeur qu'il y aura dans la cellule ?
Mais en compilant, le message d'erreur qui s'affiche ne vient pas de là. "Range de l'objet global a échoué"

Merci pour les explications sur le fonctionnement du forum.

[gFZT82]

Bonjour,

Tu peux commencer avec ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
Sub Macro2()
Dim Ws As Worksheet
Dim Cible As Range
    Set Ws = ThisWorkbook.Worksheets("Feuil1") 'Nom de feuille à adapter
    'La cellule A19 est désignée comme cible
    Set Cible = Ws.Cells(19, 1)
    'On affecte une formule aux 3 cellules qui suivent la cible
    Cible.Offset(1, 0).FormulaR1C1 = "=R[-1]C"
    Cible.Offset(2, 0).FormulaR1C1 = "=R[-2]C"
    Cible.Offset(3, 0).FormulaR1C1 = "=R[-3]C"
    'On désigne la nouvelle cellule cible (décalage de 5 lignes)
    Set Cible = Cible.Offset(5, 0)
    'On active la feuille Ws
    Ws.Activate
    'On sélectionne la nouvelle cible
    Cible.Select
    Set Cible = Nothing
    Set Ws = Nothing
End Sub

Cordialement.