Discussion :

[ElPibeOro]

Bonjour,

J'ai un fichier avec 2 feuilles :
- 1 feuille "opérations" qui regroupent toutes les opérations (1 opération = 1 ligne)
- 1 feuille "opérations terminées" où j'aimerai regrouper les opérations qui ont le statut "terminées" dans la feuille 1

J'ai donc une colonne "statut de l'opération" dans la Feuille1 et je voudrais que lorsque on tape "terminée" dans cette colonne, la ligne de l'opération aille directement dans la feuille2.

J'ai mi en place ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Opérationsterminées()
 
  Dim Lig     As Long
  Dim Col     As String
  Dim NbrLig  As Long
  Dim NumLig  As Long
 
  Sheets("Opérations terminées").Activate ' feuille de destination
 
  Col = "P"                 ' colonne de la donnée non vide à tester
  NumLig = 0
  With Sheets("Opérations")     ' feuille source
  NbrLig = .Cells(65536, Col).End(xlUp).Row
  For Lig = 1 To NbrLig
    If .Cells(Lig, Col).Value = "Terminée" Then
      .Cells(Lig, Col).EntireRow.Copy
      NumLig = NumLig + 1
      Cells(NumLig, 1).Select
      ActiveSheet.Paste
    End If
  Next
  End With
 
End Sub

Ce code fonctionne mais je suis obligé de lancer le programme pour que le changement de feuille s'effectue, et je voudrais qu'il se fasse automatiquement dés que je rempli la colonne "statut" par "terminée"..

Comment faire ?

[gFZT82]

Bonjour,

Tu peux obtenir le résultat attendu en plaçant le code suivant dans le module de la feuille "Opérations".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim WsSource As Worksheet
Dim WsCible As Worksheet
Dim LigneAjout As Long
Dim NumLig  As Long
    If Target.Column = 16 Then
        Set WsCible = Worksheets("Opérations terminées")
        Set WsSource = Worksheets("Opérations")
        With WsCible
            LigneAjout = .Range("P" & .Rows.Count).End(xlUp).Row + 1
            If Target.Value = "Terminée" Then
                Target.EntireRow.Copy Destination:=WsCible.Cells(LigneAjout, 1)
            End If
        End With
        Set WsCible = Nothing
        Set WsSource = Nothing
    End If
End Sub

Cordialement

[samuel50]

Bonjour

tu pourrais essayer en plaçant cette routine dans le code de la feuille "Opérations"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Columns(16)) Is Nothing And Target.Value = "Terminée" Then
  Target.EntireRow.Copy
  With Sheets("Opérations terminées")
    .Paste Destination:=.Cells(.Cells(Rows.Count, 1).End(xlUp).Row + 1, 1)
  End With
End If
End Sub

cordialement

oups : un peu tard

[ElPibeOro]

Merci à vous deux, ça fonctionne parfaitement, vous êtes magiques