Discussion :

[maxval18]

Bonsoir,

J'ai USF pour inscrire des adhérents qui fonctionne très bien, mais j'aimerais lui faire une petite modification
J'ai 100 TextBox et 100 Combobox et j'ai un "combobox2" pour afficher le nombre de textbox désiré sur l'USF qui fonctionne très bien. mais j'aimerais lui faire une petite modification au niveau des combobox:

Voila si je rentre dans la "combobox2" le nombre de 10 textbox visible sur l'USF j'aimerais avoir le même nombre de combobox visible ?

Je joint mon fichier se qui apporteras un peut plus de clarté

Merci d'avance pour votre aide.

Cordialement
Max

[mercatog]

Dans le module de ton usf

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
Option Explicit
 
Private Sub UserForm_Initialize()
Dim Ctrl As Control
Dim i As Byte
 
Me.Height = 116                                  ' Hauteur de l'USF a l'ouverture
 
For i = 1 To 100
    Me.ComboBox2.AddItem i
Next i
 
For Each Ctrl In Me.Controls
    If TypeName(Ctrl) = "ComboBox" Then
        If Ctrl.Name <> "ComboBox2" Then Ctrl.List = Array("Nord", "Sud", "Est", "Ouest")
    End If
Next Ctrl
 
Cacher
End Sub
 
'Nombre de joueurs  concour
Private Sub ComboBox2_Change()
Dim Nb As Byte, i As Byte
 
Cacher
If Me.ComboBox2.ListIndex > -1 Then
    Nb = Val(Me.ComboBox2.Value)
 
    For i = 1 To Nb
        Me.Controls("TextBox" & i).Visible = True
        Me.Controls("ComboBox" & i + 2).Visible = True
    Next i
    Me.Height = 116 + 16 * ((Nb - 1.1) \ 4)
Else
    Me.Height = 116
End If
Me.Repaint
End Sub
 
Private Sub Cacher()
Dim Ctrl As Control
 
For Each Ctrl In Me.Controls
    If TypeName(Ctrl) = "ComboBox" Then
        If Ctrl.Name <> "ComboBox2" Then Ctrl.Visible = False
    ElseIf TypeName(Ctrl) = "TextBox" Then
        Ctrl.Visible = False
    End If
Next Ctrl
End Sub
 
' Bouton Valider joueur concour
Private Sub CommandButton2_Click()
Dim LastLig As Long
Dim i As Byte
 
With Worksheets("Inscriptions")
    LastLig = .Cells(.Rows.Count, "C").End(xlUp).Row
    For i = 1 To 100
        If Me.Controls("TextBox" & i) <> "" Then .Range("C" & LastLig + i).Value = Me.Controls("TextBox" & i)
    Next i
End With
Unload Me
End Sub

[maxval18]

Bonsoir mercatog,

Un seul mot génial

Je te remercie beaucoup et te souhaite une bonne soirée

Cordialement

Max

[mercatog]

Remplace le 16 par 17 en ligne 34 du code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Me.Height = 116 + 17 * ((Nb - 1.1) \ 4)

[maxval18]

Re,

Juste une petite modif quel est le code pour envoyer les infos des combobox vers la colonne "B"

Merci beaucoup....

@+

Max

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub CommandButton2_Click()
Dim LastLig As Long
Dim i As Byte
 
With Worksheets("Inscriptions")
    LastLig = .Cells(.Rows.Count, "C").End(xlUp).Row
    For i = 1 To 100
        If Me.Controls("TextBox" & i) <> "" Then
            .Range("C" & LastLig + i).Value = Me.Controls("TextBox" & i)
            .Range("B" & LastLig + i) = Me.Controls("ComboBox" & i + 2)
        End If
    Next i
End With
Unload Me
End Sub

Faire 100 TextBox pour saisir 100 joueurs, je trouve que c'est loin d'être une bonne idée

[maxval18]

Re,

Tous d'abord je tiens a te remercier beaucoup.

Après comment toi tu aurais fait a ma place?

Faire 100 TextBox pour saisir 100 joueurs, je trouve que c'est loin d'être une bonne idée
__________________

Sa m'intéresserais......

@+

Max