Discussion :

[jibounet]

Bonjour,

Je dois dire avant de commencer que je n'ai aucune connaissance en VBA. Je vous explique mon problème :

Sur la première ligne de mon tableau Excel, il y a le titre des colonnes et chaque colonne (à partir de la deuxième ligne ne contient que des chiffres entiers entre 0 et 9). Ma première ligne commence ainsi :
"Absence-joie | Travail-peur | Fête-tristesse | Fête-joie | Absence-tristesse ..."
(où le | est représente un changement de colonne)

Si vous préférez, ligne1colone1 = "Absence-joie" ; ligne1colonne2 = "Travail-peur"... Un mot (comme "absence, travail, fête") est toujours associé par un trait d'union à trois émotions : "joie, peur, tristesse".

J'aimerais regrouper le colonnes de sorte à avoir, pour un même mot, les 3 émotions associées l'une à côté de l'autre. C'est-à-dire, réorganiser mes colonnes de sorte à avoir une première ligne qui ressemblerait à
"Absence-joie | Absence-peur | Absence-tristesse | Travail-joie ..."

Manuellement, ça revient à chercher le mot "absence" parmi mes tonnes de colonnes et à déplacer manuellement les colonnes qui contiennent ce mot.
J'aurais aimé automatiser ce travail de recherche-déplacement.

J'ai essayé avec le tri par ordre alphabétique, mais je n'y arrive pas.

Pourriez-vous m'aider, s'il vous plait ?

Merci !

[Theze]

Bonjour,

Pour faire un tri latéral (masquage des colonnes) il faut passer par VBA. Donc, voici une possibilité.
Tu lance la proc Test, une boite de message s'affiche, tu entre le mot cherché et ensuite, les colonnes seront déplacées vers la gauche. Fait un test sur une copie de ton classeur.
Pour aller dans le VBE, Alt+F11 puis tu clique sur "Insertion" -> "Module" et tu colle le code ci-dessous dans la partie droite, tu mets le curseur sur la proc "Test" et tu appuis sur F5 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
 
Sub Test()
 
    TriLatéral InputBox("Quel mot cherché ?", "Tri", "")
 
End Sub
 
Sub TriLatéral(Texte As String)
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Tbl() As Integer
    Dim Adr As String
    Dim I As Integer
    Dim Max As Integer
 
    'sur la feuille active
    With ActiveSheet
 
        Set Plage = .Range(.Cells(1, 1), .Cells(1, .Columns.Count).End(xlUp))
 
        Set Cel = Plage.Find(Texte, .Cells(1, .Columns.Count), xlValues, xlPart)
 
    End With
 
 
    'si trouvé,
    If Not Cel Is Nothing Then
 
        Adr = Cel.Address
 
        'boucle et stocke les n° de colonnes dans un tableau
        Do
            I = I + 1
            ReDim Preserve Tbl(1 To I)
 
            Tbl(I) = Cel.Column
 
            Set Cel = Plage.FindNext(Cel)
 
        Loop While Adr <> Cel.Address
 
        'récup du nombre de colonne correspondantes
        Max = UBound(Tbl)
 
        'insère le nombre de colonnes en A
        For I = 1 To Max
 
            Columns(1).Insert xlToRight
 
        Next I
 
        'déplace les colonnes concernées
        For I = 1 To UBound(Tbl)
 
            Columns(Tbl(I) + Max).Cut Columns(I)
            Columns(Tbl(I) + Max).Delete xlToLeft
            Max = Max - 1
 
        Next I
 
    Else
 
        MsgBox "Mot non trouvé !"
 
    End If
 
End Sub

Hervé.

[jibounet]

C'est génial, ça m'aide beaucoup ! Merci