Discussion :

[apt]

Bonsoir à tous,

J'aimerais trouver le jour "J" dans une colonne B qui contient les journées du mois sous forme de "dd/mm/yyyy".

Mais voila ma recherche n'aboutie à rien !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub CommandButton1_Click()
    Dim Plage As Range, Trouve As Range
    Dim D() As String, fDay As String
    With Sheets("Feuil2")
        .Select
        D = Split(Format(Now(), "dd/mm/yyyy"), "/")
        fDay = D(0)
        Set Plage = .Range(.[B2], _
                           .[B65536].End(xlUp))
        MsgBox "PLAGE = " & Plage.Address & vbCrLf & _
               "Cherche le jour : " & fDay
        Set Trouve = Plage.Find(What:=fDay, LookIn:=xlValues, LookAt:=xlPart)
        If Not Trouve Is Nothing Then
            MsgBox "trouve = " & Trouve.Address
            Trouve.Offset(0, 1).Value = Sheets(1).Range("G23").Value
            Trouve.Offset(0, 1).NumberFormat = "#,##0.00 "
        End If
    End With
End Sub

Merci d'avance.

[AlainTech]

Bonjour,

Pourquoi faire simple quand on peut faire compliqué?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub CommandButton1_Click()
    Dim Plage As Range, Trouve As Range
 
    With Sheets("Feuil2")
        .Select
        Set Plage = .Range(.[B2], _
                           .[B65536].End(xlUp))
        MsgBox "PLAGE = " & Plage.Address & vbCrLf & _
               "Cherche le jour : " & Date
        Set Trouve = Plage.Find(What:=Date, LookIn:=xlValues, LookAt:=xlWhole)
        If Not Trouve Is Nothing Then
            MsgBox "trouve = " & Trouve.Address
            Trouve.Offset(0, 1).Value = Sheets(1).Range("G23").Value
            Trouve.Offset(0, 1).NumberFormat = "#,##0.00 "
        End If
    End With
End Sub

D'autant qu'avec ton code, si tu cherches le jour 3, tu vas obtenir le premier jour du mois de mars.

[apt]

Bonsoir Alain,

Merci pour ton code.

Il marche très bien.

et mes excuses pour la réponse tardive