Discussion :

[krimoleroi]

Bonsoir,

J'ai un souci ; je travaille sur excel 2003.

Je suis dans un fichier excel "macro.xls" où il y a un bouton.
Ce bouton lance la macro suivante qui fonctionne de façon étrange :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Set oXL = New Excel.Application
Set oBook = oXL.Workbooks.Open("d:\Documents and Settings\KRIMO\test.xls")    
Set oSheet = oXL.ActiveWorkbook.Sheets("Table")
'   Set oSheet = oBook.Worksheets("Table")      
'    oXL.Visible = False
'    oSheet.Activate
'   oSheet.Select
 
    Range("E17") = Application.WorksheetFunction.CountA(oSheet.Range("C:C")) 
    Range("E22") = Application.WorksheetFunction.CountIf(Range("C:C"), "Site")

La fonction CountA fait le travaille correctement de recherche dans le fichier ouvert "test.xls".
Par contre la fonction CountIF travaille sur le fichier à partir duquel j'appelle la macro via le bouton macro.xls. ET c'est pas le but

J'aurai voulu que countIF joue sur le fichier "test.xls" feuille "Table" comme countA !
D'où provient le problème svp


J'ai essayé plein de bricolage mais sans succès (mis en commentaires code ci-dessus)


Merci d'avance et bon week-end

[mapeh]

Bonsoir,

Pourquoi ouvrir une nouvelle instance d'Excel????

Tu peux ouvrir un autre fichier dans l'instance en cours.

Il suffit de déterminer à l'avance le fichier en cours, et s'y référencer pour tes calculs.

Bon courage

[Didier Gonard]

Bonjour,

La fonction CountA fait le travaille correctement de recherche dans le fichier ouvert "test.xls".
Par contre la fonction CountIF travaille sur le fichier à partir duquel j'appelle la macro via le bouton macro.xls. ET c'est pas le but

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Range("E17") = Application.WorksheetFunction.CountA(oSheet.Range("C:C")) 
    Range("E22") = Application.WorksheetFunction.CountIf(Range("C:C"), "Site")

Vois les tutos sur le VBA pour comprendre ce qui se passe dans les codes que tu récupères

Programmer efficacement avec Excel en VBA http://bidou.developpez.com/tutoriels/ExcelVBA/

CountIf n'a rien à y voir, dans un cas tu invoques l'objet feuille Table via oSheet, dans l'autre tu invoques Range("C:C") direct donc implicitement tu t'adresses à la feuille active de l'instance d'Excel qui porte le code

Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier

[Theze]

Bonjour,

Il n'y a rien d'étrange au fonctionnement du code que tu nous présente. Bien évidemment, comme le dit si bien mapeh, il ne te sert à rien de créer une seconde instance d'Excel, une instance pouvant gérer plusieurs classeurs, tu peux l'ouvrir dans la même que le classeur appelant.
Le compilateur a été conçu pour interpréter les Range comme faisant parti du parent actif où se déroule les macros donc,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("E17") = Application.WorksheetFunction.CountA(oSheet.Range("C:C"))

Range("E17") est considéré comme faisant parti de la feuille active du classeur où se déroule la macro mais par contre, comme il y a précision sur la feuille où appliquer la fonction CountA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.WorksheetFunction.CountA(oSheet.Range("C:C"))

le résultat est celui que tu attends.
Dans le cas de la fonction CountIf, tu ne précise pas que tu souhaite travailler sur la feuille "Table" et donc, logiquement le compilateur en déduit que tu veux travailler sur la colonne "C" de la feuille active du classeur où se déroule cette macro.
Quand on travaille sur plusieurs classeurs, il est fortement conseillé d'utiliser des variables pour y faire référence ou de préciser de façon explicite sur quel objet ou souhaite travailler :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Dim oBook As Workbook
Dim ClasseurActif As Workbook
Dim oSheet As Worksheet
Dim FeuilleActive As Worksheet
 
Set oBook = Workbooks.Open("d:\Documents and Settings\KRIMO\test.xls")
Set ClasseurActif = ThisWorkbook
 
Set oSheet = oBook.Sheets("Table")
Set FeuilleActive = ClasseurActif.ActiveSheet
 
'NOTE : Range("E17") fait référence à la feuille active du classeur où se déroule cette macro
 
'ici, CountA fait bien référence à la feuille "Table" du classeur "Test"
Range("E17") = Application.WorksheetFunction.CountA(oSheet.Range("C:C"))
'il est mieux de faire référence à l'objet parent :
FeuilleActive.Range("E17") = Application.WorksheetFunction.CountA(oSheet.Range("C:C"))
 
'mais par contre, ici, CountIf fait référence à la colonne C de la feuille active
'du classeur où se déroule cette macro, ce comportement est tout à fait normal
'puisque que c'est de cette façon que le compilateur a été conçu !
FeuilleActive.Range("E22") = Application.WorksheetFunction.CountIf(Range("C:C"), "Site")
 
'dans le cas contraire, il te faut aussi faire référence à la feuille "Table" du classeur "Test"
FeuilleActive.Range("E22") = Application.WorksheetFunction.CountIf(oSheet.Range("C:C"), "Site")

Hervé.

Re,

Désolé Didier, je n'ai pas rafraîchi avant de poster.

Hervé.

[Didier Gonard]

@ Hervé.

[krimoleroi]

Bonjour,
....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FeuilleActive.Range("E22") = Application.WorksheetFunction.CountIf(oSheet.Range("C:C"), "Site")

...
Hervé.

J'avais senti d'où venait le problème mais je ne savais pas comment le résoudre.
J'avais essayé justement d'écrire ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("E22") = Application.WorksheetFunction.CountIf(oSheet.Range("C:C"), "Site")

Et ça n'avait rien donné.

J'ai maintenant recopié ton code et ça marche nickel.
Maintenant je comprend mieux le concept.

Merci infiniment pour le temps que tu m'as consacré.
Et merci également aux autres intervenants.