Discussion :

[goldfinger13]

Bonjour à tous

je cherche à trier les valeurs de mes deux Combobox en ordre croissant sans pour autant toucher à l'ordre de la BASE.

et bien évidemment je tourne en rond donc je vous sollicite
merci d'avance pour votre aide

[jfontaine]

Bonjour,

Ci dessous un bout de code a adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
'Activer la référence "Microsoft Scripting Runtime"
 
Dim Dic As New Scripting.Dictionary
Dim i As Integer
 
Dim sh As Worksheet
Dim shTemp As Worksheet
 
Set sh = Sheets("Feuil1")
 
'Enregistrement des données dans le dictionnaire avec suppression des doublons
For i = 1 To sh.Range("A" & Rows.Count).End(xlUp).Row
    If Not Dic.Exists(sh.Range("A" & i).Value) Then
        Dic.Add sh.Range("A" & i).Value, sh.Range("A" & i).Value
    End If
Next i
 
'Création feuille tampon
Set shTemp = ThisWorkbook.Worksheets.Add
 
'Copie le dictionnaire sur la feuille
shTemp.Range("A1").Resize(Dic.Count, 1) = Application.WorksheetFunction.Transpose(Dic.Keys)
 
'Tri les données
shTemp.Range("A1").Sort key1:=shTemp.Range("A1"), order1:=xlAscending
 
'Alimente la combobox
Me.ComboBox1.Clear
For i = 1 To shTemp.Range("A" & Rows.Count).End(xlUp).Row
    Me.ComboBox1.AddItem shTemp.Range("A" & i).Value
Next i
 
Application.DisplayAlerts = False
shTemp.Delete
Application.DisplayAlerts = True

[goldfinger13]

merci pour ton aide problème résolu