Discussion :

[Little___Buddha]

Bonjour à tous,
Je suis actuellement sur Access 2007 et je bloque.
Je cherche à stocker dans une table un certains nombre de variable d’environnement.

J’ai trouvé un code VBA que j’ai collé dans un module qui me donne un début de piste :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Function VariablesEnvironnement()
Dim varEnv As Variant, intI As Integer
Dim strMessage As String, v As Variant
 
' Liste des variables d'environnement
varEnv = Array("ALLUSERSPROFILE", "APPDATA", _
  "COMPUTERNAME", "HOMEDRIVE", "HOMEPATH", _
  "LOGONSERVER", "NUMBER_OF_PROCESSORS", "OS", _
  "PATH", "PATHEXT", "PROCESSOR_ARCHITECTURE", _
  "PROCESSOR_IDENTIFIER", "PROCESSOR_LEVEL", _
  "PROCESSOR_REVISION", "PROMPT", _
  "SYSTEMDRIVE", "SYSTEMROOT", "TEMP", "TMP", _
  "USERDOMAIN", "USERNAME", "USERPROFILE")
 
' Lecture de toutes les valeurs
strMessage = ""
For Each v In varEnv
  strMessage = strMessage & v & " = " & Environ(v) & vbCrLf
Next
 
' Affichage final
MsgBox strMessage
End Function

Les résultats affichés sont corrects, mais ce n’est que de l’affichage.

Comment créer une requête ou comment modifier le code ci-dessus pour stocker ces données dans une table ?

En vous remerciant par avance

[marot_r]

Si tu as besoin d'autant de variables je t'invite à les stocker dans une table dont la structure est :

• NumeroSequentiel (pas indispensable mais pratique pour retrouver dans quel ordre les données ont été entrées)
• NomVariable (Champ Texte 255c, clef primaire)
• ValeurVariale (Champ Mémo)

Après il est très facile de récupérer une valeur avec la fonction environ("NomVariable") et de parcourrir ta liste de variable en parcourant la table.

A+

[Stef999]

Pour compléter le message précédent ...

Dans la table des variables qu'on va nommer Var
Créer 3 champs :
IdVar : Numéro Automatique
NomVar : Texte 255
ValeurVar : Memo

et ceci dans le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Function VariablesEnvironnement()
Dim varEnv As Variant, intI As Integer
Dim strMessage As String, v As Variant
 
' Liste des variables d'environnement
varEnv = Array("ALLUSERSPROFILE", "APPDATA", _
  "COMPUTERNAME", "HOMEDRIVE", "HOMEPATH", _
  "LOGONSERVER", "NUMBER_OF_PROCESSORS", "OS", _
  "PATH", "PATHEXT", "PROCESSOR_ARCHITECTURE", _
  "PROCESSOR_IDENTIFIER", "PROCESSOR_LEVEL", _
  "PROCESSOR_REVISION", "PROMPT", _
  "SYSTEMDRIVE", "SYSTEMROOT", "TEMP", "TMP", _
  "USERDOMAIN", "USERNAME", "USERPROFILE")
 
'Déclaration des variables DAO 
 Dim dbBase As DAO.Database
 Dim rst As DAO.Recordset
 
'Instancie la base courrante
Set dbBase = CurrentDb
'charge la table dans le Recordset rst
Set rst = dbBase.OpenRecordset("Var", dbOpenDynaset)
 
'Boucle sur le tableau
For Each v In varEnv
        rst.AddNew      'Ajoute un enregistrements
        rst!NomVar = v  'v dans champ NomVar
        rst!ValeurVar = Environ(v) 'environ(v) dans champ ValeurVar
        rst.Update
Next v
 
Set rst = Nothing
Set dbBase = Nothing
 
End Function

Normalement ca marche

Cordialement

[Little___Buddha]

ça fonctionne nickel avec cette modification du code !

merci à vous pour cette réponse rapide et surtout très pertinente !!!