Discussion :

[gregoireBA]

Bonjour,

Je cherche une solution depuis quelques semaines à ce problème. Je suis sûr qu'il y a un moyen simple de me faciliter la tâche, mais je n'y connais rien en VBA...

J'ai une liste (en colonne) d'éléments que je voudrais combiner, en faisant apparaître le résultat sur deux colonnes. Par exemple, disons que les éléments sont:

1
2
3
4
5

Je voudrais obtenir les combinaisons de deux chiffres suivantes:

1 2
1 3
1 4
1 5
2 3
2 4
2 5
3 4
3 5
4 5

Soit, pour chaque élément, une combinaison avec chacun des éléments situés en-dessous de lui. Évidemment dans cet exemple de 5 éléments, c'est simple, et je pourrais le faire "manuellement". Ça devient tout de suite beaucoup plus long et fastidieux quand il y a 200 ou 300 éléments dans la liste... Le copier-coller donne vite de l'arthrose...

Merci pour toute aide,

Grégoire

[P4board]

Bonjour,

En vba cela me parait assez simple ; je viens d'en écrire un très rapidement et est donc certainement très perfectible :

Colonne A les chiffres

Colonne B et C les combinaisons

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Private Sub CommandButton1_Click()
Dim i As Integer
Dim j As Integer
Dim k As Integer
i = 1
k = 1
While (ActiveSheet.Range("A" & i) <> "")
  j = i + 1
  While (ActiveSheet.Range("A" & j) <> "")
    ActiveSheet.Range("B" & k) = i
    ActiveSheet.Range("C" & k) = j
    j = j + 1
    k = k + 1
  Wend
  i = i + 1
Wend
End Sub

Pour le faire fonctionner, il suffit de créer un bouton (affichage->barre d'outils->boite à outils controle sur excel 2003) puis de faire un clic droit sur le bouton "Viualiser le code" puis de copier le code ci-dessus dans VB

[kiki29]

Salut, une recherche via http://www.google.fr/#sclient=psy&hl...w=1023&bih=724

[gregoireBA]

Salut P4board,

Tout d'abord, merci pour ton temps et ta solution. Quand je l'exécute, le résultat présente correctement les combinaisons dans les colonnes B et C, mais je crois que j'ai mal présenté mon exemple, car les numéros de la colonne initiale ne se suivent pas nécessairement. Par exemple:

(a1) 1
(a2) 3
(a3) 4
(a4) 5
(a5) 7

devrait donner

1 3
1 4
1 5
1 7
3 4
3 5
3 7
4 5
4 7
5 7

Hum, je suppose que ça complique un peu les choses...

[Qwazerty]

Salut
Qui dit beaucoup de valeur, dit temps de traitement, il est donc préférable d'utiliser un tableau et de bien garder en tête sur quel classeur et quelles feuilles on travaille. Si on ne défini pas ça dès le départ, si l'utilisateur change de document pendant le déroulement de la macro, ça peut vite devenir catastrophique.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
Option Base 0
Sub Combinaison()
Dim Wb As Workbook
Dim Ws_Source As Worksheet, Ws_Resultat As Worksheet
Dim Tab_ValeurBase As Variant
Dim Tab_Resultat() As Long
Dim NombreCombi As Long
Dim X As Long, Y As Long
Dim CursPos As Long
 
'Sur un traitement qui va prendre du temps,
'il est preférable de garder la référence du document en cours
Set Wb = ThisWorkbook
 
'Les feuilles
Set Ws_Source = Wb.Sheets("Feuil1") 'à adapter
Set Ws_Resultat = Wb.Sheets("Feuil2") 'à adapter
 
'On place les valeurs source dans une variable sous forme de tableau
With Ws_Source
    Tab_ValeurBase = .Range("A2", .Cells(.Rows.Count, "A").End(xlUp))
End With
 
'On calcule le nombre de combinaison
NombreCombi = UBound(Tab_ValeurBase) - 1
NombreCombi = (NombreCombi * (NombreCombi + 1)) / 2
 
'On dimenssionne le tableau qui va recevoir les solutions
ReDim Tab_Resultat(0 To NombreCombi - 1, 0 To 1)
 
'Ensuite on rempli
For X = 0 To UBound(Tab_ValeurBase) - 1
    For Y = X + 1 To UBound(Tab_ValeurBase) - 1
        Tab_Resultat(CursPos, 0) = Tab_ValeurBase(X + 1, 1)
        Tab_Resultat(CursPos, 1) = Tab_ValeurBase(Y + 1, 1)
        CursPos = CursPos + 1
    Next
Next
 
'On place dans la feuil resultat
Ws_Resultat.Cells.Clear
Ws_Resultat.Range("A2").Resize(UBound(Tab_Resultat) + 1, UBound(Tab_Resultat, 2) + 1) = Tab_Resultat
 
End Sub

Il faut adapter les lignes qui définissent Ws_Source et Résultat en mettant le feuilles ou tu souhaites avoir le résultat. Si c'est sur la même feuille, pense à modifier cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Ws_Resultat.Range("B2").Resize(UBound(Tab_Resultat) + 1, UBound(Tab_Resultat, 2) + 1) = Tab_Resultat

A2 devient B2 et représente la cellule en haut à gauche du tableau de résultat

++
Qwaz

[P4board]

Effectivement gregoireBA, j'ai été un peu vite dans mon écriture... 2 petites modifs et ç'est ok :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Dim i As Integer
Dim j As Integer
Dim k As Integer
i = 1
k = 1
While (ActiveSheet.Range("A" & i) <> "")
  j = i + 1
  While (ActiveSheet.Range("A" & j) <> "")
    ActiveSheet.Range("B" & k) = ActiveSheet.Range("A" & i)
    ActiveSheet.Range("C" & k) = ActiveSheet.Range("A" & j)
    j = j + 1
    k = k + 1
  Wend
  i = i + 1
Wend

Effectivement l'utilisation d'un tableau serait plus optimale... mais dans ce cas je ne suis pas sur du réel gain de temps.

[Qwazerty]

Salut
[Edit]
Boff, en effet dans le cas d'une 100ènes de valeur ça n'est pas si flagrant que ça... j'suis dessus...
Mais à 200/ 300 valeurs on commence à mieux voir.
Et d'ailleurs tu as un dépassement de capacité à cause de Integer
[/Edit]

Effectivement l'utilisation d'un tableau serait plus optimale... mais dans ce cas je ne suis pas sur du réel gain de temps.

Mets une 100ènes de valeurs, tu te rendras mieux compte.

ensuite tu rajouteras

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
k = 1
Application.screenupdating = False
While (ActiveSheet.Range("A" & i) <> "")

Tu sentiras déjà une net amélioration.

Et par la suite si tu as beaucoup plus de valeurs, au lieu d'avoir le temps de prendre une douche, tu finiras tout juste ton café

Et comme je l'explique dans mon message prècedent, imagine que durant le déroulement de ta macro, tu changes de classeur, a ton avis que va t il se passer?

Bonne continuation

++
Qwaz

[gregoireBA]

Tout simplement génial, merci à tous les deux. Et même en considérant le temps de calcul, c'est infiniment plus rapide que faire tout à la main! Vous venez de me sauver des heures de travail!

[P4board]

Effectivement je m'incline

Je voulais juste faire simple et compréhensible car il a dit qu'il n'y connaissait rien en vba...

avec mon vieux bouzin d'il y a 11 ans :
ma methode :
10s pour 50 lignes
35s pour 100 lignes
1'20 pour 150 lignes

Il ne faut donc pas aller trop loin...

ta methode :
2s pour 350 lignes

Gloups !