Discussion :

[BAYRAL]

Bonjour tout le monde,

J'ai un fichier excel volumineux et je dois faire plusieurs choses dessus :
1 Je dois faire une colonne qui a une formule de calcul (pour ca c'est OK je gères).
2 En fonction du réslutat de la colonne je dois répartir les données dans des onglets différents. Exemple

RESULTAT COLONNE : NOUVEL ASSURE, je dois créer un onglet NOUVEL ASSURE et y déplacer la ligne contenant ce résultat.
IDEM pour un résultat de type ASSURE RADIE
IDEM pour un résultat de type MODIF ASSURE, etc...
Ce doit être fait en macro automatique.

Quelqu'un à t'il une idée ???
Merci par avance

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Dispatch()
Dim Sh As Worksheet
Dim LastLig As Long, NewLig As Long, i As Long
Dim NomFeuil As String
 
Application.ScreenUpdating = False
With Sheets("Feuil1")   'à adapter
   LastLig = .Cells(.Rows.Count, "F").End(xlUp).Row   'on désire créer les feuilles à partir de la colonne F à adapter
   For i = 2 To LastLig
      NomFeuil = CStr(.Range("F" & i).Value)
      If NomFeuil <> "" Then
         On Error Resume Next
         Set Sh = Sheets(NomFeuil)
         On Error GoTo 0
         If Sh Is Nothing Then
            Set Sh = Worksheets.Add(after:=Worksheets(Worksheets.Count))
            Sh.Name = NomFeuil
            .Rows(1).Copy Sh.Range("A1")
         End If
         NewLig = Sh.Cells(Sh.Rows.Count, "F").End(xlUp).Row + 1
         .Rows(i).Copy Sh.Range("A" & NewLig)
         Set Sh = Nothing
      End If
   Next i
   .Activate
End With
End Sub