Discussion :

[dodo69]

Bonjour,

J'aimerai lorsque je clique sur un bouton dans un userform, ouvrir un classeur vierge, puis le nommer et sauvegarder sous la forme ( analyse du (date).xlsx)

J'ai ecris un code malheureusement, il ne l'enregistre pas à l'endroit souhaiter (le bureau pour commencer),

voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
Workbooks.Add.SaveAs ("fichier analyse.xlsx")
 
Workbooks("fichier analyse.xlsx").Activate
Feuil3.Cells(1, 1).Value = "ca marche?" 'non ca ne marche pas , ca écrit dans le mauvais classeur :s

Si quelqu'un pourrait m'eclaircir sur ce point, ça serait bien sympa

Cordialement
Dorian

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim wb As Workbook
Dim Chemin As String
 
Set wb = Workbooks.Add
Chemin = "C:\Documents and Settings\Administrateur\Bureau"
wb.Sheets("Feuil3").Cells(1, 1).Value = "ca marche?"
wb.SaveAs Chemin & "\fichier analyse.xlsx"
Set wb = Nothing

[dodo69]

Merci mercatog, tes réponses sont tout l temps pertinentes, j'apprécie vraiment beaucoup

Par contre dans le nom du fichier j'aimerai y introduire la date

"fichier analyse (date du jour).xlsx" je sais pas comment faire

Et j'ai deux questions pour mieux comprendre le fonctionnment du code :p

Je comprend pas l'utilisation du Set, on fixe quoi ?

Quand on utilise l'enregistreur de macro il marque : "ChDir"
C'est quoi la différence entre "ChDir" et "Dir"?

Merci d'avance

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wb.SaveAs Chemin & "\fichier analyse" & Format(Date, "ddmmmyyyy") & ".xlsx"

Set pour affecter un objet à une variable objet

ChDir (Change Directory) changer le répertoire

[dodo69]

Encore une fois merci
A bientot
Cordialement
Dorian

[MarcelG]

Bonjour Dodo69, Bonjour le Forum,

Notre grand ami mercatog n'étant pas là, je me permets.

1 - Pour Dir et ChDir, tu peux regarder l'aide en ligne sur VBE

DIR Renvoie une valeur de type String représentant le nom d'un fichier, d'un répertoire ou d'un dossier correspondant à une chaîne de recherche, à un attribut de fichier ou au nom de volume d'un lecteur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

CHDIR Change le répertoire ou le dossier courant.

2 - La méthode SET est obligatoire pour affecter une variable à un objet
(classeur, feuille, cellule)

Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set mafeuille = ActiveSheet

3 - Pour formaliser ton nom de classeur, tu peux utiliser une concaténation du type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
madate = Format(Date,"ddmmyy")
 
wb.SaveAs Chemin & "\fichier analyse" & madate & ".xlsx"

En espérant que ces indications te seront utiles.

[MarcelG]

Décidément, je suis destiné au télescopage.

Pardon à vous 2 et à bientôt.

[dodo69]

Bonjour,
En continuant ce code, me suis rendu compte d'un problème

Si le fichier en question est déjà ouvert, ma macro bug,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub ouvrir_fichier()
 
Dim wb As Workbook
Application.DisplayAlerts = False
 
Set wb = Workbooks.Add
    wb.SaveAs "C:\Data\fichier analyse " & Format(Date, "dd_mmm_yyyy") & ".xlsx"
Set wb = Workbooks("fichier analyse " & Format(Date, "dd_mmm_yyyy") & ".xlsx")
 
 wb.Activate
Sheets("Feuil2").Select
    ActiveWindow.SelectedSheets.Delete
    Sheets("Feuil3").Select
    ActiveWindow.SelectedSheets.Delete
    Sheets("Feuil1").Select
    Sheets("Feuil1").Name = "Rapport_Analyse"
 
Set wb = Nothing
Application.DisplayAlerts = True
 
End Sub

J'aimerai compléter ce code, par quelque chose qui dirai
Si le fichier est déjà ouvert, Exit Sub
Malheureusement je ne sais pas comment lui demander si un fichier est déjà ouvert
...

[MarcelG]

Bonjour,

S'il s'agit de tester ta session Excel, tu balaies les classeurs ouverts

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Public Sub essai()
Dim wk As Workbook
For Each wk In Workbooks
    If wk.Name = "monclasseur.xls" Then
        'ton code éventuel
        Exit For
        Exit Sub
    End If
Next wk
End Sub

S'il s'agit de savoir si tel classeur est ouvert par un utilisateur
Voici une fonction qui pourra t'aider

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function FichierEstOuvert(ByRef FichierTeste As Variant) As Boolean								
    Dim FICHIER As Long								
    On Error GoTo Erreur								
    FICHIER = FreeFile								
    Open FichierTeste For Input Lock Read As #FICHIER								
    Close #FICHIER								
    FichierEstOuvert = False								
    Exit Function								
Erreur:								
    FichierEstOuvert = True								
End Function

exemple : test si le fichier Excel "Astuces VBA" est ouvert

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
FichierTeste = "\\lechemin complet\Astuces VBA.xls"								
MsgBox FichierEstOuvert(FichierTeste)

Si le fichier "Astuces VBA" est ouvert alors la fonction "FichierEstOuvert" renvoie VRAI

[mercatog]

on vérifie d'abord si le fichier existe, ensuite s'il est ouvert dans la même instance d'Excel, alors on le ferme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub ouvrir_fichier()
Dim wb As Workbook
Dim Chemin As String, Fichier As String
 
Application.ScreenUpdating = False
Chemin = "C:\Data\"
Fichier = "fichier analyse " & Format(Date, "dd_mmm_yyyy") & ".xlsx"
'Si le fichier existe déjà
If Dir(Chemin & Fichier) <> "" Then
    On Error Resume Next
    Set wb = Workbooks(Fichier)
    On Error Resume Next
    'si le fichier est ouvert (dans la même instance excel), on le ferme
    If Not wb Is Nothing Then wb.Close False
End If
 
Set wb = Workbooks.Add(1) 'on crée un nouveau fichier avec une seule feuille
wb.Worksheets(1).Name = "Rapport_Analyse"
'Notre code pour travailler avec le fichier crée
Application.DisplayAlerts = False
wb.SaveAs Chemin & Fichier
Application.DisplayAlerts = True
Set wb = Nothing
End Sub

[Edit], Bonjour MarcelG

[dodo69]

Merci a tous les deux cette fois MarcelG t'as devancé mercatog

En tout cas, ça marche parfaitement, donc je vous remercie pour votre rapidité et pour votre efficacité

Merci beaucoup
A+

Cordialement
Dorian

[MarcelG]

Salut,

Je sais bien que tu ne le considères pas ainsi.
Mais mon idée n'était pas de devancer mercatog,que je respecte et avec qui je suis loin de me mesurer.

J'avais ce 2ème code sous la main, et il faut penser à tous les lecteurs et participants de ce forum.

Bien à vous deux.