Discussion :

[booggy]

Bonjour,
Je fais appel à votre expertise car j'ai un petit soucis avec Open Office. Je m'explique:
L'entreprise dans laquelle je travaille utilise Excel notamment pour générer des étiquettes temporaires (de production).
L'opérateur scanne une série de codes barres pour renseigner plusieurs champs (A2:M2) dans la feuille de saisie (nom de la feuille = Datos). Lorsqu'il a terminé, il valide sa saisie en cliquant sur un bouton à la fin de la ligne, et là, une macro s'exécute (toute simple). Elle permet d'imprimer l'étiquette avec les informations renseignées, d'effacer le contenu des informations saisies au préalable et de repositionner le curseur sur le champs A2 pour recommencer une nouvelle saisie. La feuille qui contient le format de l'étiquette est masquée (nom de la feuille = Etiqueta).

Pour des raisons de coût, ma société a décidé de migrer vers Open Office. En conséquence, il m'est nécessaire de refaire (assez rapidement) la macro sous Calc. Mais là...comme je débute, je ne sais pas trop comment m'y prendre.

Voici le code initial, si quelqu'un peut me proposer un équivalent pour Calc se serait vraiment super:

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Imprimir()
'
' Imprimir Macro
'
Sheets("Etiqueta").Visible = True
Sheets("Etiqueta").Activate
ActiveSheet.PrintOut
Sheets("Etiqueta").Visible = False
      Sheets("Datos").Select
    Range("A2:M2").Select
    Selection.ClearContents
    Range("A2").Select
End Sub

Merci d'avance pour votre aide précieuse.

[rvtoulon]

Bonjour,
sans être un grand spécialiste n'hésite pas à parcourir la FAQ d'open office tu trouveras des réponses a tes questions.
j'ai essayé de faire le code qui te concerne, étant moi même un débutant sous open office . Il n'y a que la partie du code pour imprimer la feuille dont je ne suis pas sur, le reste c'est OK. voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Sub Macro_test
dim oDoc as object, osh1 as object, osh2 as object
dim oCC as object,maplage as object,ocel as object
dim document   as object, dispatcher as object
 
oDoc = thiscomponent
oCC = oDoc.currentcontroller
 
'Affiche la feuille masquée nommée "Etiqueta"
osh1 = oDoc.getsheets.getbyname("Etiqueta")
osh1.IsVisible = True
 
'rend le feuille Etiqueta active
oCC.activesheet = osh1
 
rem - 'IMPRIME LA FEUILLE ACTIVE ----------------------------------------
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")
dispatcher.executeDispatch(document, ".uno:PrintDefault", "", 0, Array())
rem ----------------------------------------------------------------------
 
'masque le feuille Etiqueta
osh1.IsVisible = False
 
'active la feuille Datos
osh2 = oDoc.getsheets.getbyname ("Datos")
oCC.activesheet = osh2
 
'vide le contenu de A2:M2
maplage = osh2.getcellrangebyname ("A2:M2")
maplage.clearContents(com.sun.star.sheet.CellFlags.VALUE +_
  com.sun.star.sheet.CellFlags.DATETIME +com.sun.star.sheet.CellFlags.STRING +_
  com.sun.star.sheet.CellFlags.ANNOTATION +com.sun.star.sheet.CellFlags.FORMULA)
 
'sélectionne A2
ocel = osh2.getcellrangebyname("A2")
oCC.select (ocel)
End Sub

tiens moi au courant.