Discussion :

[ericdev67]

Bonjour,

J'ai un classeur, 2 feuilles.

Dans la "Feuil1", en A1, j'ai la valeur "Essai Eric".
Dans la "Feuil2", en A1, j'ai

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=Feuil1!A1

(je fais volontairement simple....)

Fonctionnement : en "Feuil1", j'ai un code qui me fait un ensemble de calculs, je compile ces calculs dans la "Feuil2". Chaque semaine, je dois refaire les calculs de la "Feuil1", mais je souhaite conserver un historique. Donc, il faut que j'insère une nouvelle feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

add.sheet

(exemple "Feuil3") , copie "Feuil2" et colle en "Feuil3".

Le souci est qu'en "Feuil3" A1, dans la cellule, j'ai

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=Feuil1!A1

,("normal" puisque je copie/colle), mais ce qui m'intéresse, c'est d'avoir la valeur "Essai Eric" en Feuil3 A1 , pas la formule, car, vous l'avez compris, lorsque je refais tourner mon code en "Feuil1", la "Feuil3" change et prend les valeurs de la "Feuil1", ....

Une idée ?

Merci,

A+

[rjamin]

Bonjour,

Au lieu de simplement coller prenez Collage Spéciale > Valeurs.
La version d'Excel utilisée aiderait à en donner un peu plus.

[pgz]

Bonjour.

Par code, après avoir copié la feuille, tu peux faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

oNewSheet.UsedRange.Formula = oNewSheet.Usedrange.Value

Cordialement,

PGZ

[ericdev67]

Merci rjamin, tu m'as appris une fonction "coller" que je ne connaissais pas...(pas trop fan des copier/coller, ha, Mac, quand tu nous tiens..)..et donc effectivement, j'ai essayé par l'assistant, donc, pour résoudre complètement mon problème, il faut faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub ajoutfeuille()
'
 
Dim sem As String
sem = InputBox("nom de feuille que vous souhaitez rajouter")
'
Sheets("Feuil1").Select
    Rows("1:46").Select
    Selection.Copy
 
Sheets.Add after:=Worksheets(Sheets.Count)
Worksheets(Sheets.Count).Name = sem
 
ActiveSheet.Select
 
 Range("A4").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

, et ça fonctionne : ajout d'une feuille avec le nom que l'on souhaite et copie des valeurs plutôt que les formules....tout baigne !!!!

PGZ, une fois de plus, je te remercie. Par contre, j'ai essayé de mettre ton code (qui fait plus VBAiste que l'assistant....et surtout qui m'apprend de nouveaux codes) et à chaque fois, ça plante...je faisais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub ajoutfeuille()
'
 
Dim sem As String
sem = InputBox("nom de feuille que vous souhaitez rajouter")
'
Sheets("Feuil1").Select
    Rows("1:46").Select
    Selection.Copy
 
Sheets.Add after:=Worksheets(Sheets.Count)
Worksheets(Sheets.Count).Name = sem
 
ActiveSheet.Select
oNewSheet.UsedRange.Formula = oNewSheet.Usedrange.Value

, c'est une histoire de mauvais positionnement ? (je ne pense pas car j'i essayé à différents endroits du code) ou il y a un truc/instruction qui manque ?

Merci,
A+

[Philippe Tulliez]

Bonsoir,
Pour réduire ton code, tu peux écrire ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Sub ajoutfeuille()
  Dim sem As String
  sem = InputBox("nom de feuille que vous souhaitez rajouter")
  Sheets.Add after:=Worksheets(Sheets.Count)
  Sheets("Feuil1").Rows("1:46").Copy
  With Worksheets(Sheets.Count)
  .Name = sem
  .Range("A1").PasteSpecial Paste:=xlPasteValues
  End With
End Sub

[pgz]

Bonsoir.

J'ai cru que tu copiais la feuille, pas seulement une plage. CEla donne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub ajoutfeuille()
Dim oNewSheet As Excel.Worksheet
Dim sem As String
 
sem = InputBox("nom de feuille que vous souhaitez rajouter")
 
ThisWorkbook.Worksheets("Feuil1").Copy , ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count)
Set oNewSheet = ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count)
oNewSheet.Name = sem
 
oNewSheet.UsedRange.Formula = oNewSheet.UsedRange.Value
 
Set oNewSheet = Nothing
End Sub

Cordialement,

PGZ

[ericdev67]

Merci PGZ,

Une fois de plus, merci pour ton explication simple et claire.

Je ne comprenais pas toujours certains codes de la FAQ, les choix de telles ou telles déclarations.....maintenant, je pense avoir compris et surtout l'intérêt !!! (de stabilité et de limitation d'erreur...)

Merci,

A+ pour de prochaines aventures