Discussion :

[robinicol]

Bonjour à tous,

Je débute un peu en VBA et j'ai un soucis de programmation.
Voilà, je souhaite que mon fichier soit enregistré automatiquement sous un autre nom (avec la date et l'heure) dès le premier enregistrement afin de conserver une copie du fichier d'origine. Par contre à partir du second enregistrement, je souhaite que le nouveau fichier écrase le fichier précédent sans le renommer.

Voilà le code que j'ai généré jusqu'à maintenant en utilisant une variable booléenne dont la valeur est initialisée à "True" dès l'ouverture du fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
'définition du nom du fichier
    Dim nom As String
    nom = "Tableau Industriel_MACRO" & "_" & Format(Date, "yyyy-mm-dd") & "_" & Format(Time, "hhmmss") & ".xls"
 
'vérification de la variable d'enregistrement
If var = True Then
'modification de la valeur de la variable d'enregistrement
    var = False
' Sauvegarde du fichier incluant la date et l'heure pour le premier enregistrement
    'sauvegarde dans le répertoire en cours sous un nouveau nom
    ActiveWorkbook.SaveAs ActiveWorkbook.Path & "\" & nom
 
    'message de validation de l'enregistrement
    rep = MsgBox("Votre fichier a été sauvegardé sous le nom : " & nom, vbYes + vbInformation, "Sauvegarde classeur")
 
Else
' Sauvegarde du fichier sans modification du nom dès le second enregistrement
ActiveWorkbook.Save
End If
End Sub

Mon soucis c'est que dès le premier enregistrement, après le message de confirmation, un message d'erreur apparaît et Excel ferme le fichier (en me proposant de récupérer mes données)...
Le message qui s'affiche avant la fermeture de mon fichier est disponible en pièce jointe.

Quelqu'un peut-il m'aider à résoudre mon problème...???

Merci d'avance.

[casefayere]

Bonsoir,
J'ai voulu tester ton code mais je travaille sur excel 2007 donc déjà un message me demande si je veux enregistrer avec les macros, c'est logique, quand tu précises dans ton titre "pour toute version", ce n'est pas exact, sur exc. 2007, cette ligne doit s'écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

nom = "Tableau Industriel_MACRO" & "_" & Format(Date, "yyyy-mm-dd") & "_" & Format(Time, "hhmmss") & ".xlsm"

a cette condition, je n'ai pas eu de problème, encore faut'il que l'ancien fichier fut en ".xlsm"

Bonne soirée

[pgz]

Bonsoir.

Je serais tenté de penser qu'il y a un problème qui vient de ce que tu demandes à sauvegarder dans une procédure évènementielle déclenchée par chaque sauvegarde. Je t'aurais bien proposé de modifier ta procédure ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
 
Application.EnableEvents = False
 
'définition du nom du fichier
Dim nom As String
nom = "Tableau Industriel_MACRO" & "_" & Format(Date, "yyyy-mm-dd") & "_" & Format(Time, "hhmmss") & ".xls"
 
'vérification de la variable d'enregistrement
If Var = True Then
    'modification de la valeur de la variable d'enregistrement
    Var = False
    ' Sauvegarde du fichier incluant la date et l'heure pour le premier enregistrement
    'sauvegarde dans le répertoire en cours sous un nouveau nom
    ActiveWorkbook.SaveAs ActiveWorkbook.Path & "\" & nom
 
    'message de validation de l'enregistrement
    MsgBox "Votre fichier a été sauvegardé sous le nom : " & nom, vbYes + vbInformation, "Sauvegarde classeur"
 
Else
    ' Sauvegarde du fichier sans modification du nom dès le second enregistrement
    ActiveWorkbook.Save
    MsgBox "enregistré sans changement de nom"
End If
 
Application.EnableEvents = True
Cancel = True
 
End Sub

Mais Casefayere dit qu'il n'y a pas de pb et, du coup, je ne sais pas.

Cordialement,

PGZ

[robinicol]

Bonjour,

Je viens de tester la solution de pgz et ça marche !!!

Pour répondre à Casefayere, après vérification, ma version Excel est de 2003, par conséquent la solution proposée ne marche pas dans mon cas. (Je me suis un peu précipité en renseignant l'intitulé...)

L'avantage c'est que vos propositions permettent de résoudre mon problème pour toutes les versions Excel!

En tous cas merci pour votre aide et la rapidité de vos réponses.

Bonne journée.
Cdlt.