Discussion :

[wabo67]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

xlApp.Workbooks.Open "U:\XX\XX\bdd.xls"

Le programme va chercher le fichier sur le réseau.
Par contre lorsque le fichier est ouvert sur un autre PC, le programme l'ouvre et ouvre la boite "enregistrer sous".
Il n'y a pas un code qui permet d'ouvrir une fenetre d'erreur, lorsque le fichier est deja ouvert?

Merci de votre aide

[Godzestla]

Bonjour,

essaie ceci mais sans garantie:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Sub test
    If Not CheckExcelFileOpen("U:\XX\XX\bdd.xls") Then
       'code si le fichier n'est pas ouvert
    End If
 
End sub
 
 
Function CheckExcelFileOpen(fichier As String) As Boolean
    Dim x As Integer
 
    On Error Resume Next
    x = FreeFile()
 
    Open fichier For Input Lock Write As #x
    Close x
 
    If Err.Number = 0 Then CheckExcelFileOpen = False
    If Err.Number = 70 Then CheckExcelFileOpen = True
 
    On Error GoTo 0
End Function

[Didier Gonard]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub Testeur()
Dim wbkAtester As Workbook
Dim strChemin As String
Dim strNom As String
'********************* rajouter pour si macro dans cible : Application.EnableEvents = False / True
strNom = "Fichier a tester.xls"
On Error Resume Next
Set wbkAtester = Workbooks(strNom) 'Si le classeur n'est pas ouvertdans cette instance, on affecte à la variable Objet un objet qui n'existe pas dans l'Application. Le on Error Resume next passe à la lignee suivante, wbkAtester est donc resté à Nothing.
On Error GoTo 0
If wbkAtester Is Nothing Then
    MsgBox "Ce Classeur n'est pas ouvert dans cette instance d'Excel"
Else
    MsgBox "Déjà Ouvert dans cette instance d'Excel!"
    Set wbkAtester = Nothing
    Exit Sub
End If
 
strChemin = "E:\+ Cliparts\"
'strChemin = "\\Toto-PC\Users\Public\Documents\"
Set wbkAtester = Workbooks.Open(strChemin & strNom)
    If wbkAtester.ReadOnly Then
        MsgBox "Déjà Ouvert sur un autre poste ou dans une autre instance"
        wbkAtester.Close
    Else
        MsgBox "Ce Classeur n'est pas ouvert sur un autre poste ou dans une autre instance !"
        wbkAtester.Close 'ligne à activer ou non selon le test voulu classeur reste ouvert ou non
    End If
End Sub

cordialement,

Didier

[wabo67]

Merci marche parfaitement..