Explication de code "Ajout de bouton"

**BEBER1212** · 11/05/2010, 21h25

Bonjour,

J'ai trouvé ce code dans les FAQ de ce site. Je voudrais savoir si quelqu'un pouvait m'expliquer en partie ce code. Je décroche aux paramètres pour a création de la macro : lamacro = ...
Est ce que ça renvoie vers une macro définie ailleurs ?

Merci.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
Sub AjoutCommandButton_Feuille()
    Dim Ws As Worksheet
    Dim Obj As OLEObject
    Dim laMacro As String
    Dim x As Integer
 
    'Ajout feuille
    Set Ws = Sheets.Add
 
    'Ajout CommandButton dans la feuille
    Set Obj = Ws.OLEObjects.Add("Forms.CommandButton.1")
    With Obj
        .Left = 50 'position horizontale
        .Top = 50 'position verticale
        .Width = 140 'largeur
        .Height = 30 'hauteur
        .Object.BackColor = RGB(235, 235, 200) 'Couleur de fond
        .Object.Caption = "Supprimer données feuille"
    End With
 
    'Paramètres pour la création de la macro:
    '(suppression contenu cellules)
    laMacro = "Sub CommandButton1_Click()" & vbCrLf
    laMacro = laMacro & "Cells.Clear" & vbCrLf
    laMacro = laMacro & "End Sub"
 
    With ThisWorkbook.VBProject.VBComponents(ActiveSheet.Name).CodeModule
        x = .CountOfLines + 1
        .InsertLines x, laMacro
    End With
End Sub

**Pierre Fauconnier** · 11/05/2010, 22h23

Bonsoir

Toute la macro Sub AjoutCommandButton_Feuille() sert à ajouter un bouton sur une feuille et à lui affecter une macro qui n'existe pas, et qui doit par conséquent être construite.

si on devait affecter le code du bouton à la main, on insérerait le code suivant dans le module de la feuille active

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub CommandButton1_Click()
Cells.Clear
End Sub

C'est cette action que la macro Sub AjoutCommandButton_Feuille() prend en charge à partir de la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    laMacro = "Sub CommandButton1_Click()" & vbCrLf

La variable LaMacro reçoit la chaine de caractère qui compose le code de la macro événementielle qui sera déclenchée sur le clic du nouveau bouton.

Lorsque la variable LaMacro contient le code complet, on insère ce code dans le module de la feuille active.

Pour que cela fonctionne, il faut que la confiance soit accordée au code VBA (voir la sécurité des macros selon la version d'Excel utilisée)

Ok?

**BEBER1212** · 11/05/2010, 22h42

Merci pour ces explications, qui me mènent à d'autres questions

Envoyé par Pierre Fauconnier

C'est cette action que la macro Sub AjoutCommandButton_Feuille() prend en charge à partir de la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    laMacro = "Sub CommandButton1_Click()" & vbCrLf

La variable LaMacro reçoit la chaine de caractère qui compose le code de la macro événementielle qui sera déclenchée sur le clic du nouveau bouton.

Donc si je veux ouvrir un onglet caché, je devrais remplacer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
  laMacro = "Sub CommandButton1_Click()" & vbCrLf
    laMacro = laMacro & "Cells.Clear" & vbCrLf
    laMacro = laMacro & "End Sub"

par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
  laMacro = "Sub CommandButton1_Click()" & vbCrLf
    laMacro = laMacro & "Sheets("Modification").Visible=1" & vbCrLf
    laMacro = laMacro & "Sheets("Modification").Activate" & vbCrLf
    laMacro = laMacro & "End Sub"

???

Lorsque la variable LaMacro contient le code complet, on insère ce code dans le module de la feuille active.

Est ce que c'est réalisé avec le dernier With ?

Merci

**Pierre Fauconnier** · 12/05/2010, 19h42

Envoyé par BEBER1212

...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
  laMacro = "Sub CommandButton1_Click()" & vbCrLf
    laMacro = laMacro & "Sheets("Modification").Visible=1" & vbCrLf
    laMacro = laMacro & "Sheets("Modification").Activate" & vbCrLf
    laMacro = laMacro & "End Sub"

???

Lorsque les guillemets font partie de la chaine en tant que caractères, il faut les doubler

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

laMacro = laMacro & "Sheets(""Modification"").Visible=1" & vbCrLf

Envoyé par BEBER1212

...
Est ce que c'est réalisé avec le dernier With ?

Merci

Oui

**BEBER1212** · 12/05/2010, 20h34

Merci pour votre réponse.

Je me suis en effet rendu compte qu'il fallait doubler les guillemets.
Par contre le code se met dans la page "modification" au lieu de la page dans laquelle le bouton se crée. Je ne comprends pas pourquoi. Mon code ci-dessous, avez vous une explication ?

Merci.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Private Sub Chercher_Click()
Dim laMacro As String
Dim x As Integer
 
 
Application.ScreenUpdating = False
On Error Resume Next
 
' Affiche l'onglet correspondant au nom de l'invité
Sheets(Range("B19").Value).Visible = 1
 
' Message d'erreur si pas d'invité avec ce nom
If Err <> 0 Then
   MsgBox "Pas d'invité avec ce nom dans la liste. Faites une autre recherche. Attention à l'orthographe et aux accents.", , "Message Erreur"
 
' Si pas d'erreur afficher l'onglet
Else: Sheets(Range("B19").Value).Activate
 
' Dans l'onglet de l'invité
With ActiveSheet
' Création d'un bouton
.OLEObjects.Add(ClassType:="Forms.CommandButton.1", Link:=False _
, DisplayAsIcon:=False, Left:=183.75, Top:=119.25, Width:=169.5, _
Height:=79.5).Select
' Changer le nom d bouton
.OLEObjects("CommandButton1").Object.Caption = "Modifier"
End With
 
' Avec le clic du bouton
laMacro = "Sub CommandButton1_Click()" & vbCrLf
' Rendre visible la Feuil9
laMacro = laMacro & "Feuil9.Visible=1" & vbCrLf
' Activer la Feuil9
laMacro = laMacro & "Feuil9.Activate" & vbCrLf
laMacro = laMacro & "End Sub"
 
' ???
With ThisWorkbook.VBProject.VBE.CodePanes(1).CodeModule
x = .CountOfLines + 1
.InsertLines x, laMacro
End With
 
Application.ScreenUpdating = True
End If
End Sub

**Pierre Fauconnier** · 12/05/2010, 20h41

Je n'ai pas testé, mais je dirais qu'il faut remplacer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With ThisWorkbook.VBProject.VBE.CodePanes(1).CodeModule

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With ThisWorkbook.VBProject.VBComponents(ActiveSheet.Name).CodeModule

**BEBER1212** · 13/05/2010, 00h19

Merci pour cette modif, mais j'ai toujours le même problème : le code se met dans l'onglet "modification" alors que c'est l'onglet que je souhaite ouvrir avec le bouton.
Ça ne fonctionne donc pas...

Pour info, mon fichier est dispo ici, si vous avez le temps de regarder :

http://www.cijoint.fr/cjlink.php?fil...cijjhwOJtZ.xls

Merci

**mercatog** · 13/05/2010, 00h43

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With ThisWorkbook.VBProject.VBComponents(ActiveSheet.CodeName).CodeModule

CodeName à la place de Name

Edit: Je me suis permis d'ouvrir ton fichier, il est temps d'avertir que la démarche et la conception adoptées sont fastidieuses.
une bonne réflexion s'impose.
C'est un simple point de vue

**BEBER1212** · 13/05/2010, 00h53

Wouhou !!! Merci Pierre et Mercatog. Ça fonctionne.

Je confirme vos statuts de Responsable Excel et de Membre Expert

Merci beaucoup.

Pour les intéressés, voici mon code en entier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
    Private Sub Chercher_Click()
    Dim laMacro As String
    Dim x As Integer
    On Error Resume Next
 
    Sheets(Range("B19").Value).Visible = 1
    Application.ScreenUpdating = False
    If Err <> 0 Then
       MsgBox "Pas d'invité avec ce nom dans la liste. Faites une autre recherche. Attention à l'orthographe et aux accents.", , "Message Erreur"
 
    Else: Sheets(Range("B19").Value).Activate
    With ActiveSheet
    .OLEObjects.Add(ClassType:="Forms.CommandButton.1", Link:=False _
            , DisplayAsIcon:=False, Left:=183.75, Top:=119.25, Width:=169.5, _
            Height:=79.5).Select
    .OLEObjects("CommandButton1").Object.Caption = "Modifier"
 
    End With
 
 
    laMacro = "Sub CommandButton1_Click()" & vbCrLf
    laMacro = laMacro & "Sheets(""Modification"").Visible=1" & vbCrLf
    laMacro = laMacro & "Sheets(""Modification"").Activate" & vbCrLf
    laMacro = laMacro & "End Sub"
 
 
With ThisWorkbook.VBProject.VBComponents(ActiveSheet.CodeName).CodeModule
        x = .CountOfLines + 1
        .InsertLines x, laMacro
    End With
 
 
    Application.ScreenUpdating = True
    End If
    End Sub

Encore merci.

**mercatog** · 13/05/2010, 00h58

Si tu re recherche la même personne, il va te créer une autre bouton avec une même macro en double sur la même feuille.
il y aura ambiguïté!

**BEBER1212** · 13/05/2010, 01h00

@ mercatog :

Effectivement la démarche et la conception sont fastidieuses, mais je débute, donc je fais avec les moyens du bord...

Pour l'instant je voulais juste que tout fonctionne pour pouvoir utiliser mon fichier. Je verrai par la suite pour améliorer ça, mais je n'ai pour l'instant pas les connaissances suffisantes pour le faire.
La plupart de ces lignes, je les ai prises sur le net. Je ne suis donc pas le seul. Ouf

En tous cas merci encore !!!

Envoyé par mercatog

Si tu re recherche la même personne, il va te créer une autre bouton avec une même macro en double sur la même feuille.
il y aura ambiguïté!

Oui j'ai vu ça, mais sur ma feuille de modification, j'ai un bouton valider, auquel je demanderai de supprimer le premier bouton (en tous cas j'essaierai

).

Je suis preneur de toutes bonne idée (ou mauvaise d'ailleurs) qui me fera avancer, pour ce problème, mais aussi comme tu le disais, pour une meilleure conception.

Merci.

**mercatog** · 13/05/2010, 01h10

Bon courage,
n'oublies pas d'utiliser au mieux la FAQ et les tutos de ce magnifique forum.
bonne nuit

Edit, une piste http://excel.developpez.com/faq/inde...BA#DeleteMacro

**BEBER1212** · 13/05/2010, 01h22

OK, merci.

Pour mon info, peux tu m'expliquer en gros, en "français"

le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
With ThisWorkbook.VBProject.VBComponents(ActiveSheet.CodeName).CodeModule
        x = .CountOfLines + 1
        .InsertLines x, laMacro
    End With

Merci.

**mercatog** · 13/05/2010, 11h18

un peu de lecture http://silkyroad.developpez.com/VBA/...cEditor/#LII-B

Explication de code "Ajout de bouton"

Macros et VBA Excel

Discussions similaires

Partager

Partager