Discussion :

[siamis]

Bonjour
J'ai un tableau de livraison avec des dates de livraison. je voudrais trouver une formule pour faire apparaître à dans la cellule à coté de la date: livraison 1 si c'est la date la plus ancienne, livraison 2 si c'est la deuxième date la plus ancienne, livraison 3 si c'est la troisième date la plus ancienne, et au moins jusqu'à la dixième livraison
J'ai essayé avec:
=MIN($P$1:$P$350) plus ancienne date
=PETITE.VALEUR($P$1:$P$350;2) deuxième plus ancienne date
=PETITE.VALEUR($P$1:$P$350;3) troisième plus ancienne date

Cela ne fonctionne pas car les dates dans la colonne n'apparaissaient pas forcément par ordre chronologique et il y des lignes avec des cellules vides pour les lignes ou je ne connais pas encore la date de livraison
Qui peut m'aider ?
Je ne connais pas trop excel
merci

[mdo100]

Bonjour siamis,

Un début de piste, car je n'ais pas tout compris.
A suivre.

[Menhir]

Mets en Q1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=Rang(P1;P$1:P$350)

Sélectionne Q1 > Clic droit > Format de cellule > Onglet Nombre > Catégorie = Personnalisée > dans le champ Type, mettre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

"Livraison "Standard

Recopie Q1 en Q2:Q350.

[excfl]

Bonjour le forum,

L2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(PETITE.VALEUR($D$2:$D$11;COLONNE()-11);"")

A tirer vers la droite.

Format : Date

[papouclo]

Bonjour à tous,
Le problème est qu'il y a des doublons dans la plage de dates D2: D11.
excfl je ne sais pas si, pour ta copie d'écran, tu as tiré vers la droite ta formule qui fonctionne correctement bien sûr en L2, mais chez moi, ta formule a redonné 01/03/16 pour les livraisons 2 et 3 ce qui est logique pour Excel, les trois plus petites valeurs étant la date 01/03/16.

Autre proposition après avoir laissé en L2 la formule donnée par siamis = MIN (D2: D11)
écrire en M2 la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(COLONNES($L$2:M2)<=SOMME(SI($D$2:$D$11<>"";1/NB.SI($D$2:$D$11;$D$2:$D$11)));MIN(SI(($D$2:$D$11>L2);$D$2:$D$11));"")

à valider par Ctrl + Maj + Entrée et à recopier vers la droite jusqu'en U2.
Un test, ici COLONNES($L$2:M2)<=SOMME(SI($D$2:$D$11<>"";1/NB.SI($D$2:$D$11;$D$2:$D$11)) (et la structure en SI) est nécessaire car, après la dernière date, la formule de calcul renvoie non pas un signal d'erreur mais la valeur 0 donc la date 01/01/1900.
Remarque : Si la fonction MIN.SI est définie (versions récentes d'Excel), on peut aussi écrire en M2 la formule toujours matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(COLONNES($L$2:M2)<=SOMME(SI($D$2:$D$11<>"";1/NB.SI($D$2:$D$11;$D$2:$D$11)));MIN.SI($D$2:$D$11;$D$2:$D$11;">"&L2);"")

Pour la colonne E, écrire alors en E2 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX($L$1:$U$1;EQUIV(D2;$L$2:$U$2;0));"")

et la recopier vers le bas jusqu'en E11.

Cordialement
Claude

[siamis]

Bonjour et merci pour votre aide,

Lorsque je saisis les formules comme vous le demandez aucun résultat ne s'affiche dans les cellules.
Pourriez-vous mettre le tableau en pièce jointe avec vos formules saisies ?

Merci

[papouclo]

Bonjour,
Voir le classeur joint
Cordialement
Claude