Discussion :

[janakka-horus]

Bonjour voila mon problème.

J'ai un tableau de TVA qui se génère automatiquement par mois depuis le logiciel de comptabilité. Mon soucis c'est que ces données se mettent à zero à chaque fois que l'on change de période. Or je voudrais garder une trace des soldes générés mensuellement en copiant automatiquement les soldes dans un tableau en fonction du mois de travail.

Par exemple dans le fichier ci joint

La cellule P9 indique 2016/5 (mois de MAI 2016)

Je souhaite que les infos contenu dans la colonne Solde à partir de la cellule Q16 soient recopiées dans la colonne du Moi de Mai (à partir cellule V16).

Je précise que toutes ces données sont générées mensuellement à partir de formules depuis le logiciel de comptabilité. Je ne souhaite garder une trace de ces données en fonction du mois sans utiliser la fonction copier valeur à partir de la souris.

J’espère avoir été le plus clair possible. Et merci pour votre aide car je ne connais rien en VBA.

MERCI

si je me suis mal exprimé merci de me le faire savoir

[thebenoit59]

Bonjour Janakka.

Je te retourne ton fichier.
La procédure est la suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit
 
'Forumeur : janakka-horus
'Auteur : TheBenoit59
'Lien : http://www.developpez.net/forums/d1587443/logiciels/microsoft-office/excel/macros-vba-excel/recopier-valeurs-fonction-mois/
 
Sub Report_Mensuel()
Dim Annees As String, Mois As Integer, i As Integer
    With Feuil1
        'On enregistre l'année de P9 ainsi que le numéro de mois
        Annees = Format(.[p9], "yyyy"): Mois = Format(.[p9], "mm")
            'On boucle les colonnes depuis la colonne R (18ème colonne), jusqu'à la dernière existante en ligne 13
            For i = 18 To .Range("r13").End(xlToRight).Column
                'Si la valeur contenue en colonne i et ligne 13 concaténé avec celle ligne 14
                'correspond à la valeur concaténée de Mois & Annees
                If .Cells(13, i).Value & .Cells(14, i).Value = Mois & Annees Then
                    'Alors on copie la colonne solde à partir de la ligne 16, à la dernière
                    .Range(.Cells(16, "q"), .Cells(.[q65000].End(xlUp).Row, "q")).Copy .Cells(16, i)
                    'Et on quitte la boucle
                    Exit For
                End If
            Next i
            'Si on termine la boucle sans trouver la valeur, c'est que la colonne n'existe pas, alors nous la créons.
            .Cells(13, i).Value = Mois
            .Cells(14, i).Value = Annees
            .Cells(15, i).Value = UCase(Format(.[p9], "mmmm"))
            .Range(.Cells(16, "q"), .Cells(.[q65000].End(xlUp).Row, "q")).Copy .Cells(16, i)
    End With
End Sub

[janakka-horus]

Bonjour,

Merci pour ta réponse. Elle est quasi parfaite sauf que les données de la colonne solde sont obtenue à partir d'une formule. Je souhaite en faite ne reporter que les valeurs de la colonne et non les formules.

[thebenoit59]

On dira donc que la procédure est parfaite selon la demande de base.

Utilise ce code ci, si tu as des formules:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Explicit
 
'Forumeur : janakka-horus
'Auteur : TheBenoit59
'Lien : http://www.developpez.net/forums/d1587443/logiciels/microsoft-office/excel/macros-vba-excel/recopier-valeurs-fonction-mois/
 
Sub Report_Mensuel()
Dim Annees As String, Mois As Integer, i As Integer
    With Feuil1
        'On enregistre l'année de P9 ainsi que le numéro de mois
        Annees = Format(.[p9], "yyyy"): Mois = Format(.[p9], "mm")
            'On boucle les colonnes depuis la colonne R (18ème colonne), jusqu'à la dernière existante en ligne 13
            For i = 18 To .Range("r13").End(xlToRight).Column
                'Si la valeur contenue en colonne i et ligne 13 concaténé avec celle ligne 14
                'correspond à la valeur concaténée de Mois & Annees
                If .Cells(13, i).Value & .Cells(14, i).Value = Mois & Annees Then
                    'Alors on copie la colonne solde à partir de la ligne 16, à la dernière
                    .Range(.Cells(16, "q"), .Cells(.[q65000].End(xlUp).Row, "q")).Copy
                    .Cells(16, i).PasteSpecial Paste:=xlValues
                    Application.CutCopyMode = False
                    'Et on quitte la procédure
                    Exit Sub
                End If
            Next i
            'Si on termine la boucle sans trouver la valeur, c'est que la colonne n'existe pas, alors nous la créons.
            .Cells(13, i).Value = Mois
            .Cells(14, i).Value = Annees
            .Cells(15, i).Value = UCase(Format(.[p9], "mmmm"))
            .Range(.Cells(16, "q"), .Cells(.[q65000].End(xlUp).Row, "q")).Copy
            .Cells(16, i).PasteSpecial Paste:=xlValues
            Application.CutCopyMode = False
    End With
End Sub

[janakka-horus]

Merci Beaucoup c'est super.