Discussion :

[Obelix77]

Bonsoir,

Tout est dans le titre.

Je souhaite que des mots ou des séries de mots se mettent en couleur dans une cellule ou une plage de cellules.
Il faut que les seuls mots ou séries de mots voulus soient en couleur; pas toute la cellule; ça, je sais le faire

Dans l'idéal, je souhaiterais mettre en place une fonction du type mise en forme conditionnelle :
=("cellule ou plage de cellule";"texte";"code couleur").

Idéalement, je souhaiterais pouvoir combiner des ET et des OU, pour le texte; dans l'idéal ...

Est ce faisable par le VBA?

Merci d'avance à tous ceux qui auront pris le temps de lire et encore plus à ceux qui répondront .

Bonne soirée,

[BDA53]

Tu peux le faire en VBA mais je te conseille de le faire plutôt par mise en forme conditionnelle.
Tout dépend si tu veux le faire une fois sur toute ta plage ou plusieurs fois.

Si tu veux le faire en VBA, voici les options qui gèrent le format d'une cellule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Range("A32:A41").Select
With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorDark1
        .TintAndShade = 0
        .PatternTintAndShade = 0
End With

Voilà un exemple de couleur.
Je te laisse tester pour trouver ta couleur.
Tu as une liste du code couleur sur ce site (je n'ai plus le lien) ou tu peux taper "code couleur vba" sur google

[Menhir]

Bin... Tu double cliques sur ta cellule, tu surlignes la partie de texte que tu veux mettre en couleur, tu cliques sur l'icone Couleur de police et tu valides.
Je ne comprends pas où est le problème.

[Obelix77]

Menhir :
Merci pour ta réponse mais il s'agit de traiter des milliers de lignes avec des textes spécifiques. Donc infaisables manuellement, bien sur.v Je n'aurais pas créer un sujet pour un truc si simple.

Zela77:
La mise en forme conditionnelle est effectivement top mais elle met en couleur tout le texte de la cellule.
Dans mon cas, seul le texte sélectionné doit se mettre en couleur.
Merci pour ta liste de code; j'ai juste un "petit problème" : je ne maîtrise pas du tout le VBA Je suis juste un utilisateur ++ dans Excel

[BDA53]

C'est xela57

1) Ajoute le ruban développeur dans option de Excel
2) Mode création => Bouton de commande
3) Clic droit => visualiser le code
4) copier coller le code que je t'ai donné. En prenant soin d'adapter le code à ta feuille ( Range("A32:A41") à modifier par ta plage)
5) Enjoy it !

[Obelix77]

Merci Xela57 pour ta réponse

J'ai fait tout comme tu m'as dit mais, après, je fais comment pour lancer?

De plus, je m'adresse à des utilisateurs basiques (encore plus que moi ). Il faudrait donc qu'ils sélectionnent une cellule ou une plage de cellule et que cette sélection rentre directement dans le code.

Puis, une fois qu'ils ont sélectionné et lancer la macro, qu'une fenêtre s'ouvre où ils pourraient renseigner le texte à coloriser et le code couleur voulu.
Faisable?

Merci et bonne après midi

[Menhir]

il s'agit de traiter des milliers de lignes avec des textes spécifiques.

Si tu ne le dis pas, comment veux-tu qu'on le devine ?
De même, tu ne dis pas comment repérer la partie de texte à colorer.

Je ne pense pas que c'est une fonction (même personnalisée en VBA) qui permettra de faire ça.
Il faudra une macro. Mais sans explications complémentaires, il est impossible de donner plus d'indications.

[Obelix77]

Si tu ne le dis pas, comment veux-tu qu'on le devine ?
De même, tu ne dis pas comment repérer la partie de texte à colorer.

Je ne pense pas que c'est une fonction (même personnalisée en VBA) qui permettra de faire ça.
Il faudra une macro. Mais sans explications complémentaires, il est impossible de donner plus d'indications.

Merci pour ta GRANDE aide Mehnir.
Je viens de relire mon texte : "Je souhaite que des mots ou des séries de mots se mettent en couleur dans une cellule ou une plage de cellules.
Il faut que les seuls mots ou séries de mots voulus soient en couleur; pas toute la cellule; ça, je sais le faire"
Mon texte me semble pourtant parfaitement clair, si on prend le temps de le lire jusqu'au bout.
Bon week-end et encore un grand merci

[Philippe Tulliez]

Bonjour,
Voici une procédure VBA qui met dans la couleur déterminé par l'argument optionnel CodeRG (rouge par défaut), les caractères compris dans la liste des mots placés dans l'argument TextColoring et ce dans la plage de cellules passé à l'argument AreaText.
La recherche des mots à mettre en forme n'est pas sensible à la casse.

Code de la procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub CharacterColor(AreaText, TextColoring, Optional RGBCode As Long = vbRed)
 Dim Cel As Range, nbWord As Integer, tbl() As String, Start As Integer
 TextColoring = LCase(TextColoring)
 tbl = Split(TextColoring, ";")
 For Each Cel In AreaText
  For nbWord = 0 To UBound(tbl)
   Start = InStr(LCase(Cel), tbl(nbWord))
    Do While Start
     Cel.Characters(Start, Len(tbl(nbWord))).Font.Color = RGBCode
     Start = InStr(Start + 1, LCase(Cel), tbl(nbWord))
    Loop
  Next
 Next
End Sub

Exemple de son utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub TestCharacterColor()
 Dim rng As Range
 Set rng = Range("A1:A4")
 rng.Font.Color = 0
 CharacterColor rng, "Automne;Hiver;Printemps;Eté;Saisons"
End Sub

[Obelix77]

Bonjour,
Voici une procédure VBA qui met dans la couleur déterminé par l'argument optionnel CodeRG (rouge par défaut), les caractères compris dans la liste des mots placés dans l'argument TextColoring et ce dans la plage de cellules passé à l'argument AreaText.
La recherche des mots à mettre en forme n'est pas sensible à la casse.

Code de la procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub CharacterColor(AreaText, TextColoring, Optional RGBCode As Long = vbRed)
 Dim Cel As Range, nbWord As Integer, tbl() As String, Start As Integer
 TextColoring = LCase(TextColoring)
 tbl = Split(TextColoring, ";")
 For Each Cel In AreaText
  For nbWord = 0 To UBound(tbl)
   Start = InStr(LCase(Cel), tbl(nbWord))
    Do While Start
     Cel.Characters(Start, Len(tbl(nbWord))).Font.Color = RGBCode
     Start = InStr(Start + 1, LCase(Cel), tbl(nbWord))
    Loop
  Next
 Next
End Sub

Exemple de son utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub TestCharacterColor()
 Dim rng As Range
 Set rng = Range("A1:A4")
 rng.Font.Color = 0
 CharacterColor rng, "Automne;Hiver;Printemps;Eté;Saisons"
End Sub

Merci Philippe mais impossible à mettre en place. Je dois être vraiment trop nul

[Philippe Tulliez]

Bonjour,

Merci Philippe mais impossible à mettre en place. Je dois être vraiment trop nul

Mais encore ?

[Obelix77]

Merci Philippe mais impossible à mettre en place. Je dois être vraiment trop nul

Je copie/colle ton code dans une macro puis j'enregistre et la macro n'apparait pas dans la liste des macros.
Elle apparaît quand je rajoute Sub CharacterColor() au début mais elle plante dès la 1ère ligne.
Je t'avis dit : plutôt nul

[Philippe Tulliez]

Bonjour,
Il y a deux procédures à placer dans un module.
L'une qui effectue le travail (CharacterColor) et l'autre qui invoque celle-ci et qui se nomme TestCharacterColor.
Il est normal que la première ne soit pas visible dans la liste des macros puisqu'elle a des arguments.
Il faut bien entendu adapter la deuxième.
J'ai refait le code de cette dernière et tu remplaces les valeurs des trois constantes afin de l'adapter à ton classeur.
Ensuite tu appelles cette macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub TestCharacterColor()
 Const SheetName As String = "Textes"    ' Nom de la feuille où se trouve les textes à mettre en forme
 Const RangeAddress As String = "A1:A4" ' Plage de cellules où se trouve les textes à mettre en forme (de la feuille SheetName)
 Const WordList As String = "Esprit;idée" ' Liste des mots qui doivent être mis en évidence
 Dim rng As Range
 Set rng = ThisWorkbook.Worksheets(SheetName).Range(RangeAddress)
 rng.Font.Color = 0 ' Efface la mise en forme précedente
 CharacterColor rng, WordList ' Appel de la procédure qui souligne en rouge les mots des textes des cellules définies dans RangeAddress
End Sub

Si on ajoute l'argument optionnel RGBCode on aura la mise en évidence dans la couleur choisie
Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

CharacterColor rng, WordList, vbBlue

J'espère que c'est plus clair.

[Obelix77]

Merci Philippe
Je teste demain et je te dis
Bonne soirée,

[Obelix77]

Merci Philippe
Je teste demain et je te dis
Bonne soirée,

j'ai testé et j'arrive à ce que je veux. Un grand merci
Bonne journée,

[Menhir]

De même, tu ne dis pas comment repérer la partie de texte à colorer.

Je souhaite que des mots ou des séries de mots se mettent en couleur dans une cellule ou une plage de cellules.
Il faut que les seuls mots ou séries de mots voulus soient en couleur; pas toute la cellule; ça, je sais le faire"

Même écrit en rouge, "les mots voulus", je ne vois pas comment on peut coder ça en VBA, la fonction lecture de pensée n'existant pas encore.

On en revient donc à ma question : comment repérer les mots que tu veux mettre en couleur ?

[rfesc]

Merci Philippe Tulliez, elle est super ta macro !!!

[Philippe Tulliez]

Bonjour rfesc,
Merci pour ton appréciation, cela fait toujours plaisir à lire.