Discussion :

[carrera56650]

Bonjour,

je travail depuis un certain temps sur un chrono avec temps intermédiaire via excel 2010.
En fouillant sur le net j'ai trouvé différentes macros que j'ai réussi à adapter à mes besoins (je suis novice en macro).
J'ai un soucis lorsque je lance mon chrono, je ne peux plus remplir aucune case dans mon tableau sous peine de créer une erreur 400.
tant que le chrono n'est pas lancé, je peux modifier toutes les cellules comme je veux, par contre lorsque le chrono est lancé je ne peux plus rien modifier.
si je veux mettre quoi que ce soit en A12 par exemple je dois le faire chrono non actif sinon ça bugg.

Merci de votre aide.

[OBO29]

Bonjour, si tu souhaite de l'aide, merci de montrer ton code actuel.
Utilise le bouton # dans cet éditeur de messages, puis colle ton code entre les balises.

[carrera56650]

Bonjour,
voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Dim TpsInter As Variant
Dim ligne, press, press1, press2, memoirerappel As Integer
 
Sub chrono()
depart = Timer
Application.EditDirectlyInCell = False
Do
Tempsfinal = Timer - depart
TpsInter = Tempsfinal / 86400
Range("k1").Value = TpsInter
Range("d10").Value = TpsInter
If Range("k3").Value = 1 Then
Exit Sub
End If
DoEvents
Loop Until Range("a1").Value = 1
End Sub
Sub Intermediaire()
tpsarret = Range("k1").Value
 
If ligne = 1 Then a = Range("l" & ligne).Value Else a = Range("l" & ligne - 1).Value
Range("l" & ligne).Value = tpsarret
Range("m" & ligne).Value = tpsarret - a
ligne = ligne + 1
press1 = 0
press2 = 0
End Sub
Sub Arret()
Range("k3").Value = 1
Application.EditDirectlyInCell = True
End Sub
Sub initialisation()
Range("k1") = Null
Columns("l:q").Select
Selection.ClearContents
Range("d10").Value = Null
Range("k3").Value = Null
ligne = 1
memoirerappel = 0
press = 1
press1 = 0
press2 = 0
End Sub
Sub Worksheet_Change(ByVal Target As Range)
 
    If Target.Column = 13 Then Target.Offset(0, 1).Value = Now
 
End Sub

[OBO29]

Bonjour,

Après lecture du code :

1) Il faut impérativement déclarer toutes tes variables. Le Timer est de type Single, les résultant de calcules doivent l'être aussi.

Astuce :
- Met une majuscule à tes variable (déclaration)
- Pendant que tu édite ton programme, tape en minuscules.
- Si il n'y a pas d'erreur, le compilateur fait l'association et met automatiquement la majuscule en place.
- Ainsi, si tu vois une variable tout en minuscule, alors il y a un problème de frappe ou de déclaration.

2) Le VBA est orienté évènements. je te déconseille donc de rester attendre dans une boucle quand se n'est pas strictement necessaire.

Je ne sais pas comment sont appelés tes différents programmes.
Je ne connais pas la finalité du prog, mais voici une adaptation :

Mettre à 1 E1 pour initaliser ton chrono.
Mettre à 1 E2 pour marquer un temps intermédiaire.

Le temps initial est indiqué en K1.
Chaque temps intermédiare est indiqué en Lx.
Chaque delta par rapport au dernier temps intermédiaire est indiqué en Mx.


J'espère que ça correspond à ton besoin. Bonne continuation.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
Dim Ligne As Integer
 
Sub Worksheet_Change(ByVal Target As Range)
    If (Target.Column = 5) And (Cells(Target.Row, Target.Column) = 1) Then 'Colonne "E" choisie pour piloter le chrono
        If Target.Row = 1 Then ' E1=1 : Initialiser
            initialisation
            Cells(Target.Row, Target.Column) = 0
        End If
        If Target.Row = 2 Then ' E2=1 : Temps intermédiaire
            Intermediaire
            Cells(Target.Row, Target.Column) = 0
            Cells(Target.Row, Target.Column).Select
        End If
    End If
End Sub
 
Sub initialisation()
    Range("k1") = 0 '
    Columns("l:q").Select
    Selection.ClearContents
    Ligne = 1
    Range("k1").Value = Timer  'Début Chrono
    Range("E2").Select
End Sub
 
Sub Intermediaire()
    Range("l" & Ligne).Value = Timer
    If Ligne = 1 Then Range("m" & Ligne).Value = Timer - Range("k1").Value
    If Ligne > 1 Then Range("m" & Ligne).Value = Timer - Range("l" & Ligne - 1).Value
    Ligne = Ligne + 1
End Sub

[carrera56650]

Bonjour,

Merci pour ton aide.
Ne connaissant pas le langage VBA, tes explications sont un peu floues pour moi.
Le but de mon fichier excel est pour établir un suivi de course automobile.
J'ai besoin de connaître régulièrement les temps entre 2 événements afin de calculer les consommations d'essence, les temps de pilotage des pilotes, les temps d'utilisation des pneus, ...
Jusqu'à présent je rentre les temps manuellement dans mon fichier mais je perds un temps fou.
Ce dont j'ai besoin:
L'affichage d'un chrono dans une cellule avec 4 boutons de commandes (départ, stop, intermédiaire et RAZ)
Le bouton intermédiaire me servirait à déterminer un événement (entrée ou sortie des stands, safety car, changement de pilote, changement de pneus, refueling ...)
Le code que j'ai donné en début de message fonctionne très bien mais je ne peux pas accéder à mon tableau lorsque le chrono est en route. J'ai besoin de remplir régulièrement les événements.
D'après quelques recherches que j'ai faites, le problème viendrait des lignes de commandes Doevents mais je ne sais pas du tout comment modifier.
Peut-être que je ne colle pas les lignes de commandes au bon endroit. J'ai essayé dans objet (feuil2) --> erreur 400 ou dans un module --> pas d'erreur mais le chrono se freeze.

OBO29 Le travail que tu me proposes fonctionne bien par contre lorsque je mets la case K1 en format hh:mm:ss ou jj/mm/aaaa hh:mm:ss, j'ai des valeurs complètement erronées. idem pour les colonnes L et M.
Et je préférerai avoir un bouton à cliquer plutôt qu'une case à modifier.

Patrice

[OBO29]

Bonjour,

J'ai ajouté 4 boutons sur la feuille; partons de ça comme base d'avancement.

Il faut bien comprendre :

Timer est le nombre de secondes écoulées depuis minuit avec précision au centième.
Timer n'est pas un format Date; pas la peine de chercher à mettre en format hh:mm:ss ou jj/mm/aaaa hh:mm:ss.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
Dim Ligne As Integer
 
Private Sub Cmd_RAZ_Click() 'Appui sur "RAZ"
    Range("J1") = 0         'Case de mémorisation de l'instant "Start"
    Columns("k:q").Select
    Selection.ClearContents
    Range("k1").Select
    Ligne = 1
 
    Cmd_Start.Enabled = True
    Cmd_Stop.Enabled = False
    Cmd_Inter.Enabled = False
    Cmd_RAZ.Enabled = True
End Sub
 
Private Sub Cmd_Start_Click()   'Appui sur "START"
    Cmd_Inter.Enabled = True
    Range("J1").Value = Timer                           'Mémorisation de l'instant "Start"
    Range("k" & Ligne).Value = Timer                    'L'instant "Start sert de repère de chrono
    Range("l" & Ligne).Value = Range("k" & Ligne).Value 'Pour Calcul des intervals de temps
    Range("m" & Ligne).Value = "Start Chrono"           'Commentaire
    Ligne = Ligne + 1
    'Gestion des boutons
    Cmd_Start.Enabled = False
    Cmd_Stop.Enabled = True
    Cmd_Inter.Enabled = True
    Cmd_RAZ.Enabled = False
End Sub
 
Private Sub Cmd_Inter_Click()   'Appui sur "Intermédiaire"
 
    Range("K" & Ligne).Value = Range("J1").Value    'Sauvegarde instant du start Chrono
    Range("L" & Ligne).Value = Timer                'Sauvegarde instant actuel
 
    If Range("k" & Ligne).Value = Range("k" & Ligne - 1).Value Then 'Alors on est sur le même cycle de Chrono
        Range("m" & Ligne).Value = Range("l" & Ligne).Value - Range("l" & Ligne - 1).Value  'Ecart avec le dernier intermédaire
    End If
 
    Ligne = Ligne + 1
End Sub
 
Private Sub Cmd_Stop_Click()    'Appui sur "STOP"
    Range("k" & Ligne).Value = Range("J1").Value        'Sauvegarde instant du start Chrono
    Range("l" & Ligne).Value = Range("k" & Ligne).Value 'Sauvegarde instant actuel
    Range("m" & Ligne).Value = "Stop Chrono"            'Commentaire
    Ligne = Ligne + 1
 
    Cmd_Start.Enabled = True
    Cmd_Stop.Enabled = False
    Cmd_Inter.Enabled = False
    Cmd_RAZ.Enabled = True
End Sub

-> "RAZ" efface les données présentes.

-> "Départ" place la valeur Timer dans "J1"

-> Intermédiaire :
- Met le point de repère en place (instant où on a démarré le Chrono)
- Place la valeur Timer dans "Lx"
- Calcule en "Mx" l'intervale de temps (au 100ème) avec l'évènement précédent.

-> Stop : Met fin au Chrono en cours. Il faudra repasser par "Start"


Résumé :
"J1" Repère de Chrono actuellement en cours
"K" Mémorisation du repère du Chrono
"L" Mémorisation du temps actuel
"M" Interval de temps avec l'intermédaire précédent.


Bonne continuation,

[carrera56650]

Bonsoir,

a première vue c'est bien ce dont j'avais besoin.
Par contre j'ai toujours le même problème d'affichage dans les cellules temps.
Je joins une impression d'écran.

Merci

[OBO29]

Il n'y a pas de problème d'affichage.

Timer est le nombre de secondes écoulées depuis minuit avec précision au centième.
Timer n'est pas un format Date; pas la peine de chercher à mettre en format hh:mm:ss ou jj/mm/aaaa hh:mm:ss.

76507,1875 est le nombre de secondes depuis minuit.

[carrera56650]

Bonjour,

Désolé de ne redonner des nouvelles seulement maintenant mais je n'ai pas eu le temps de m'occuper du fichier durant les vacances.
Comme je le disais précédemment, le type de fonctionnement est exactement ce dont j'ai besoin.
Par contre, je ne m'en sors pas avec l'affichage des cellules des colonnes K et L. Il faut impérativement que celles-ci soient sous la forme jj/mm/aaaa hh:mm:ss.
Il faudrait aussi que les cellules de la colonne M soit sous la forme hh:mm:ss. Je pense que si les colonnes K et L sont sous la forme jj/mm/aaaa hh:mm:ss, en faisant une simple soustraction je devrais trouver ce qui m'intéresse.
Si J1 est sous cette forme, cela me permet de déclencher un chrono en faisant {=MAINTENANT()-J1} et en actualisant le fichier toutes les secondes.
Je ne sais pas si c'est possible à réaliser.
De plus, j'utilise ce fichier sur des courses d'endurances de 24h. Il se pose donc un problème lorsque l'heure passe à minuit (remise à zéro).

J'espère que mes explications ne sont pas trop confuses.

Patrice

[OBO29]

Bonjour,

Voici une adaptation très simple : Utilisation de "Now" à la place de "Timer".
Note : je n'affiche pas le chrono (avec actualisation toutes les secondes). Je te laisses ce travail si tu le souhaites.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
 
Dim Ligne As Integer
 
Private Sub Cmd_RAZ_Click() 'Appui sur "RAZ"
    Range("J1") = 0         'Case de mémorisation de l'instant "Start"
    Columns("K:R").Select
    Selection.ClearContents
    Range("k1").Select
    Ligne = 1
    'Lignes de titre
    Range("N" & Ligne).Value = "Ecart total en secondes" 'temps
    Range("O" & Ligne).Value = "Jours"
    Range("P" & Ligne).Value = "Heures"
    Range("Q" & Ligne).Value = "Minutes"
    Range("R" & Ligne).Value = "Secondes"
 
    Cmd_Start.Enabled = True
    Cmd_Stop.Enabled = False
    Cmd_Inter.Enabled = False
    Cmd_RAZ.Enabled = True
End Sub
 
Private Sub Cmd_Start_Click()   'Appui sur "START"
    Cmd_Inter.Enabled = True
    'Range("J1").Value = Timer                           'Mémorisation de l'instant "Start"
    Range("J1").Value = Now                           'Mémorisation de l'instant "Start"
    'Range("k" & Ligne).Value = Timer                    'L'instant "Start sert de repère de chrono
    Range("k" & Ligne).Value = Now                      'L'instant "Start sert de repère de chrono
    Range("l" & Ligne).Value = Range("k" & Ligne).Value 'Pour Calcul des intervals de temps
    Range("m" & Ligne).Value = "Start Chrono"           'Commentaire
    Ligne = Ligne + 1
    'Gestion des boutons
    Cmd_Start.Enabled = False
    Cmd_Stop.Enabled = True
    Cmd_Inter.Enabled = True
    Cmd_RAZ.Enabled = False
End Sub
 
'MERCI à  LedZeppII pour une partie de ce code :
'http://www.developpez.net/forums/d598919/logiciels/microsoft-office/access/vba-access/calcul-d-duree/
Private Sub Cmd_Inter_Click()   'Appui sur "Intermédiaire"
    Dim Date_Debut As Date, Date_Fin As Date
    Dim temps As Long, jours As Long, heures As Long, minutes As Long, secondes As Long
 
    Range("K" & Ligne).Value = Range("J1").Value    'Sauvegarde instant du start Chrono
    'Range("L" & Ligne).Value = Timer                'Sauvegarde instant actuel
    Range("L" & Ligne).Value = Now                  'Sauvegarde instant actuel
 
    If Range("k" & Ligne).Value = Range("k" & Ligne - 1).Value Then 'Alors on est sur le même cycle de Chrono
        Range("m" & Ligne).Value = Range("l" & Ligne).Value - Range("l" & Ligne - 1).Value  'Ecart avec le dernier intermédaire
 
        Date_Debut = Range("l" & Ligne - 1).Value
        Date_Fin = Range("l" & Ligne).Value
        temps = DateDiff("s", Date_Debut, Date_Fin)
        jours = temps \ 86400: temps = temps - jours * 86400
        heures = temps \ 3600: temps = temps - heures * 3600
        minutes = temps \ 60
        secondes = temps - minutes * 60
        Range("N" & Ligne).Value = temps
        Range("O" & Ligne).Value = jours
        Range("P" & Ligne).Value = heures
        Range("Q" & Ligne).Value = minutes
        Range("R" & Ligne).Value = secondes
 
    End If
 
    Ligne = Ligne + 1
End Sub
 
Private Sub Cmd_Stop_Click()    'Appui sur "STOP"
    Range("k" & Ligne).Value = Range("J1").Value        'Sauvegarde instant du start Chrono
    Range("l" & Ligne).Value = Range("k" & Ligne).Value 'Sauvegarde instant actuel
    Range("m" & Ligne).Value = "Stop Chrono"            'Commentaire
    Ligne = Ligne + 1
 
    Cmd_Start.Enabled = True
    Cmd_Stop.Enabled = False
    Cmd_Inter.Enabled = False
    Cmd_RAZ.Enabled = True
End Sub

J'espère que ça convient.

Bonne continuation.

N'oublie pas le si c'est OK pour toi.

[kiki29]

Salut, si cela peut aider : 2 exemples de chronos, à adapter à ton contexte, sinon juste pour info.

[carrera56650]

Bonsoir,

Merci kiki29 pour le lien.

Un très grand merci à OBO29 pour ton aide j'ai fais un énorme pas en avant grâce à ton aide.

Au plaisir.

Patrice