Exportation cellules Excel vers cellules Access

**alineleleu** · 11/06/2014, 11h41

Bonjour,

J'aimerais récupérer des données présentes dans certaines cellules Excel dans ma base Access (pour certaines cellules également). Comment puis-je m'y prendre?

Merci d'avance!

**madefemere** · 11/06/2014, 13h24

Bonjour,

La commande la plus simple à partir de VBA Access pour interagir avec Excel est TransferSpreadsheet. Si vous arrivez à bien la manipuler et bien paramétrer le fichier Excel, vous devrez arrivez à vos fins.

Sinon, en un peu plus poussé, vous avez ici un tuto pour piloter un fichier excel à partir d'Access.
Et en résumé les commandes usuelles explicitées dans le FAQ.

Bonne continuation

**alineleleu** · 12/06/2014, 09h50

Merci.

Est-il possible de le faire cellule par cellule avec la commande transferspreadsheet?

**paidge** · 12/06/2014, 12h00

Bonjour,
Avec la bibliothèque Microsoft Excel (menu outils/références dans l'éditeur VBA), on peut faire à peu près tout ce qu'on veut.
Voir le tuto

**alineleleu** · 12/06/2014, 13h26

Bonjour,

J'ai lu ce tuto mais je n'y ai pas trouvé la réponse à ma question. Je débute en VBA

**paidge** · 12/06/2014, 13h58

C'est donc le moment d'apprendre

Voici encore un peu d'aide dans la FAQ

**alineleleu** · 12/06/2014, 14h24

Merci, j'ai déjà lu tout ça hier et n'ai rien trouvé. Je veux bien apprendre, mais sans trouver les réponses, ça va être difficile

**paidge** · 12/06/2014, 15h08

La réponse tu l'as eue : C'est possible !
Par programmation VBA, tu ouvres le fichier Excel tel que c'est expliqué dans les tutos (qui sont clairs et dont le code est largement commenté pour faciliter la compréhension).
Ensuite tu récupères les données des cellules qui t'intéresses, tu construis une requête d'insertion à partir de ces données pour les insérer dans la table Access de ton choix...Et le tour est joué. Y'a vraiment rien de bien compliqué si tu te bases sur les tutos...
Moi aussi je suis parti de zéro en m'inscrivant sur ce site et j'ai (presque) tout appris ici, dans la FAQ et les tutos.
Maintenant si vraiment tu ne connais rien au VBA, vas faire un tour par ici

**paidge** · 12/06/2014, 16h17

Vu que j'ai eu un petit quart d'heure de libre, voici un exemple de code qui fait ce que j'ai dit plus haut. Je viens de tester et ça marche au poil

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Private Sub monBouton_Click()
    On Error GoTo Err_monBouton_Click
    Dim xlApp As Excel.Application
    Dim xlBook As Excel.Workbook
    Dim xlSheet As Excel.Worksheet
    Dim maVariable1 As String
    Dim maVariable2 As String
    Dim strSQL As String
 
    ' Instanciation d'une session Excel en mode invisible
    Set xlApp = CreateObject("Excel.Application")
    xlApp.Visible = False
    ' Ouverture du classeur
    Set xlBook = xlApp.Workbooks.Open("D:\EXCEL\monClasseur.xls")
    ' Récupération de la feuille Feuil1
    Set xlSheet = xlBook.Sheets("Feuil1")
 
    ' ===== Deux manières de récupérer des valeurs dans une cellule =====
    ' Récupération de la valeur de la case qui se trouve à la 3ème ligne et la 2ème colonne
    maVariable1 = xlSheet.Cells(3, 2)
    ' Récupération de la valeur de la case qui se trouve en C3
    maVariable2 = xlSheet.Range("C3")
 
    ' Construction et exécution de la requête d'insertion
    strSQL = "INSERT INTO maTable (monChamp1,monChamp2) VALUES ('" & maVariable1 & "'    , '" & maVariable2 & "')"
    CurrentDb.Execute strSQL
 
Exit_monBouton_Click:
    ' Code de fermeture
    xlBook.Save
    xlBook.Close
    xlApp.Quit
    Set xlSheet = Nothing
    Set xlBook = Nothing
    Set xlApp = Nothing
    Exit Sub
 
Err_monBouton_Click:
    ' Gestion des erreurs
    Select Case Err.Number
        Case Else
            MsgBox "Error n°" & Err.Number & vbCrLf & "Description : " & Err.Description & vbCrLf & "Source : " & Err.Source, vbCritical, "Error"
    End Select
    Resume Exit_monBouton_Click
End Sub

**alineleleu** · 12/06/2014, 16h23

Je vais tester ça!

Merci beaucoup

**madefemere** · 12/06/2014, 17h20

Bonjour,

Si je peux me permettre un petit conseil à alineleu :
1- n'ayez pas peur de vous tromper quand vous essayez les exercices dans les tutos.
2- essayez de simuler "hors informatique" l'action que vous voulez faire.
Ici, on va vous donner des solutions sur les outils et les moyens de faire, mais tant que vous même avez du mal à comprendre le but (ou expliciter le souci), toutes les explications techniques ne voudront rien dire.

Bonne continuation

**alineleleu** · 25/06/2014, 16h43

Bonjour,

J'ai essayé ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Option Compare Database
Private Sub monBouton_Click()
    On Error GoTo Err_monBouton_Click
    Dim xlApp As Excel.Application
    Dim xlBook As Excel.Workbook
    Dim xlSheet As Excel.Worksheet
    Dim maVariable1 As String
    Dim maVariable2 As String
    Dim strSQL As String
 
    ' Instanciation d'une session Excel en mode invisible
    Set xlApp = CreateObject("Excel.Application")
    xlApp.Visible = False
    ' Ouverture du classeur
    Set xlBook = xlApp.Workbooks.Open("C:\Users\RRFH3332\Documents\Tableau de bord\Exports CLIP Pour Access.xls")
    ' Récupération de la feuille Indicateurs
    Set xlSheet = xlBook.Sheets("Indicateurs")
 
    ' Récupération de la valeur de la case qui se trouve en C3
    maVariable2 = xlSheet.Range("A2:P29")
 
    ' Construction et exécution de la requête d'insertion
    strSQL = "INSERT INTO Export_CLIP (N°conseiller:Complétude_V1) VALUES ('" & maVariable1 & "'    , '" & maVariable2 & "')"
    CurrentDb.Execute strSQL
 
Exit_monBouton_Click:
    ' Code de fermeture
    xlBook.Save
    xlBook.Close
    xlApp.Quit
    Set xlSheet = Nothing
    Set xlBook = Nothing
    Set xlApp = Nothing
    Exit Sub
 
Err_monBouton_Click:
    ' Gestion des erreurs
    Select Case Err.Number
        Case Else
            MsgBox "Error n°" & Err.Number & vbCrLf & "Description : " & Err.Description & vbCrLf & "Source : " & Err.Source, vbCritical, "Error"
    End Select
    Resume Exit_monBouton_Click
End Sub

Ca ne fonctionne pas. Il y a une erreur sur : Dim xlApp As Excel.Application

Je ne comprend pas pourquoi?

**paidge** · 30/06/2014, 09h17

A mon avis, tu as oublié d'activer la référence "Microsoft Excel X.X Object Library" où X.X est le numéro de version.
ALT+F11 pour entrer dans le VBE puis menu Outils/Références.
Et, un petit conseil : Quand tu as une erreur, indiques au moins le message, ça peut aider