Discussion :

[crauwels]

bonjour,
j'ai une base de donnée qui ouvre d'autre base par un bouton, dont le code comme ceci...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Call fOpenRemoteForm("C:\Users\marc\Desktop\....\.....\....\.....\.....mdb", "fml_demarrage")

cela fonctionne très bien ,
mais quand je veux refermer cette nouvelle base de donnée avec mon bouton quitter dont le code est " Application.quit " pour retourner sur ma première base ouverte
j'ai l'erreur " erreur d'exécution 91 : variable objet ou variable de bloc with non définie "

comment puis-je supprimer cette fenêtre d'erreur ?
quel est le code ?
et ou faut il le mettre ?

en vous remerciant d'avance

Marcmarc

[ClaudeLELOUP]

Bonjour,

comment puis-je supprimer cette fenêtre d'erreur ?

En ajoutant le cas « 91 » dans la gestion d'erreur :

[crauwels]

merci Claude ,
cela fonctionne mais je reçois une autre fenêtre qui me dit que la base que je ferme est en mode exclusif ...
et me demande de rouvrir en mode normal,.

please reopen in shared mode try again
j'ai 4 autres fichiers access que j'ouvre 1 à la fois avant d'ouvrir un autre pour ne pas faire une usine a gaz, ainsi, j'ai passer les 4 fichiers en revue manuellement à l'ouverture et même dans les options avancées de chaque fichiers également
mais après tout cela, j'ai toujours cette fenêtre...

que puis-je faire...

merci

Marcmarc

[ClaudeLELOUP]

Je ne rencontre pas ce problème.

Voici le code que j'utilise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
 
Option Compare Database
Option Explicit
 
 
Private Declare Function apiSetForegroundWindow Lib "user32" _
 Alias "SetForegroundWindow" _
 (ByVal hwnd As Long) _
 As Long
 
Private Declare Function apiShowWindow Lib "user32" _
 Alias "ShowWindow" _
 (ByVal hwnd As Long, _
 ByVal nCmdShow As Long) _
 As Long
 
Private Const SW_MAXIMIZE = 3
Private Const SW_NORMAL = 1
 
Function fOpenRemoteForm(strMDB As String, _
 strForm As String, _
 Optional intView As Variant) _
 As Boolean
Dim objAccess As Access.Application
Dim lngRet As Long
 
 On Error GoTo fOpenRemoteForm_Err
 
 If IsMissing(intView) Then intView = acViewNormal
 
 If Len(Dir(strMDB)) > 0 Then
 Set objAccess = New Access.Application
 With objAccess
 lngRet = apiSetForegroundWindow(.hWndAccessApp)
 lngRet = apiShowWindow(.hWndAccessApp, SW_NORMAL)
 'the first call to ShowWindow doesn't seem to do anything
 lngRet = apiShowWindow(.hWndAccessApp, SW_NORMAL)
 .OpenCurrentDatabase strMDB
 .DoCmd.OpenForm strForm, intView
 Do While Len(.CurrentDb.Name) > 0
 DoEvents
 Loop
 End With
 End If
fOpenRemoteForm_Exit:
 On Error Resume Next
 objAccess.Quit
 Set objAccess = Nothing
 Exit Function
fOpenRemoteForm_Err:
 fOpenRemoteForm = False
 Select Case Err.Number
 Case 7866:
 'mdb is already exclusively opened
 MsgBox "The database you specified " & vbCrLf & strMDB _
        & vbCrLf & "is currently open in exclusive mode. " & vbCrLf _
        & vbCrLf & "Please reopen in shared mode and try again", vbExclamation + vbOKOnly, "Could not open database."
 Case 2102:
 'form doesn't exist
 MsgBox "The Form '" & strForm & _
 "' doesn't exist in the Database " _
 & vbCrLf & strMDB, _
 vbExclamation + vbOKOnly, "Form not found"
 Case 7952, 91:
 'user closed mdb
 fOpenRemoteForm = True
 Case Else:
 MsgBox "Error#: " & Err.Number & vbCrLf & Err.Description, _
 vbCritical + vbOKOnly, "Runtime error"
 End Select
 Resume fOpenRemoteForm_Exit
End Function

[crauwels]

Merci Claude,
cela fonctionne

j'ai comparer ce que j'avais copier coller antérieurement avec ton module que je viens de recevoir, et il me manquait les deux premières lignes
j'avais été trop vite pour le copier coller sans vérifier.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
Option Compare Database
Option Explicit

merci à toi

Marcmarc et je te souhaites bon weekend