Discussion :

[thomanneca]

Bonjour,
J'ai 24 checkbox et j'aimerais simplifier les codes, est-ce possible?
Peut-on simplifier le code qui suit comme tel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub checkboxi_click()
For i = 1 To 24
  If CheckBoxi.Value = True Then
    Range(Range("numcentrale").Cells(ComboBox1.ListIndex + 1, 1).Address).Offset(0, i + 1).Value = "8"
  Else
    Range(Range("numcentrale").Cells(ComboBox1.ListIndex + 1, 1).Address).Offset(0, i + 1).Value = ""
  End If
Next
 
End Sub

Peut-on intégrer For i = 1 to 24 d'une manière ou d'une autre ?
Merci beaucoup

[parmi]

Bonjour,

Il faudrait d'abord savoir quelle sorte de checkbox il s'agit.
Est-ce sur un UserForm ou une feuille ?
Si sur une feuille, de quel type s'agit-il ? contrôle formulaire ou ActiveX ?

[parmi]

J'imagine que c'est sur un UserForm, donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.Controls("CheckBox" & I).Value

[thomanneca]

C'est en effet bien sur une userform..

Je vais essayer ce dernier code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

me.controls("checkbox"&I).value

mais comment dois-je l'introduire? dans une procédure?
et avec cela, je suppose que je suis quand même obligé d'ajouter :
sub checkbox1_click () et ce pour les 24 checkboxs ?

Merci pour votre aide

[parmi]

Oui, tu auras à mettre du code dans chaque ChekboxXYZ_Click()
Par contre, il y a des gens qui créent leurs contrôles par code et, en passant par une classe, tu pourrais réduire cette tâche de multiples _Click(), je pense...

Il y a eu des discussions là-dessus il n'y a pas très longtemps.
Tu pourrais faire une recherche sur WithEvents..
Mais comme je ne suis pas un expert dans ce domaine, je laisserai le soin à d'autres de t'expliquer.

[MarcelG]

Bonjour, et Bonjour au Forum,

Les modules de classe.

Je voulais mentionner le tutoriel de Pierre FAUCONNIER, mais je ne parviens pas à y accéder. Si quelqu'un peut me l'indiquer...

Utiliser un module de classe consiste, pour ce qui nous concerne ici, à définir une collection (classe) d'objets répondant au critère de leur nature (CheckBox).
Cette classe est alimentée via une variable Tableau à l'initialisation du formulaire (Userform).
C'est elle qui gère les évènements par rapport à ses occurences, ici tous les CheckBox.

Ce qui se traduit comme suit.

Dans le module du formulaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
'Module de classe
'ClassCheckBox est le nom de la classe d'objets Textbox
Dim CTB() As New ClassCheckBox
 
 
Private Sub UserForm_Initialize()
 
Dim ct As Control
Dim n As Byte
 
n = 0
'balayage des contrôles
For Each ct In Me.Controls
        If TypeName(ct) = "CheckBox" Then
                n = n + 1
                ReDim Preserve CTB(1 To n)
                'alimentation de la classe si le contrôle est un CheckBox
                Set CTB(n).TB = ct
        End If
Next ct
 
End Sub
 
Private Sub Btn_Valider_Click()
 
Me.Hide
Unload Me
 
End Sub

Attention à l'homogénéisation de nom des divers objets(TB, CTB, ClassCheckBox..)

Création d'un module de classe nommé ClassCheckBox.
Dans le module y afférant, coder (bien entendu, évènement à adapter):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Option Explicit
 
Public WithEvents TB As MSForms.CheckBox
 
Private Sub TB_Click()
 
MsgBox TB.Caption
 
End Sub

Personnellement, c'est mon seul emploi des modules de classe. Pour l'instant.
Mais il y de nombreux types d'utilisation, plus puissants mais plus compliqués (Je débute en la matière)

[Marc-L]

Bonjour, bonjour,

tout est dans la FAQ Excel : les modules de classe …