Automatisation de formules

**alex49520** · 04/08/2011, 14h57

Bonjour,

Je me trouve de nouveau confronté à un problème.

Je me retrouve avec une formule : ='[Classeur 1.xls]feuille 1'!$H$11 qui fonctionne normalement. Mais je souhaiterais désormais modifier cette formule car le Classeur 1 peut être amené à être modifié au fil des années, et je souhaiterais avoir une formule unique me permettant de toujours retrouver les infos que je veux.

Je m'explique : je voudrais savoir s'il est possible de créer une formule disant qu'au lieu de trouver H11, il faudrait trouver la case à l'intersection de la ligne où l'on retrouve (en A1) Marketing avec la colonne où l'on retrouve Janvier (H12), sans pour autant faire apparaitre A1 et H12 mais plus janvier et marketing.

Pensez vous que cela est possible ?

Merci d'avance,
Cdt,
Alex

**jfontaine** · 04/08/2011, 15h03

Bonjour,

Une solution en combinant les formules rechercheV et Equiv

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEV("marketing";A1:J5;EQUIV("janvier";A1:J1;0);0)

**alex49520** · 04/08/2011, 15h30

J'ai essayé ça =RECHERCHEV("Marketing - structure ETC";'[Classeur 1.xls]effectif'!$A:$A;EQUIV("31/01/2011";'[Classeur 1.xls]effectif'!$H$7:$S$1052;0);0), mais il m'affiche #N/A.

Vois tu ou est le problème ?

Merci d'avance,
Alex

**jfontaine** · 04/08/2011, 15h35

La matrice de recherche du recherchev ne contient qu'une colonne A ('[Classeur 1.xls]effectif'!$A:$A)

de plus le equiv contient plusieurs ligne

les dates ne devraient elles pas etre sur une seule ligne?
([Classeur 1.xls]effectif'!$H$7:$S$1052)

**alex49520** · 04/08/2011, 16h22

Est ce grave si la matrice ne contient qu'une colonne ? Car cette colonne ne devrait pas changer.

Pour le equiv, j'ai mis ça car je ne suis pas censé savoir que la cellule que je cherche se trouve en H11, elle pourrait très bien être amené à se trouver en H12.

Du coup, j'arrive à ça maintenant, mais aucun changement: =RECHERCHEV("Marketing";'[Classeur 1.xls]effectif'!$A$9:$A$1104;EQUIV("31/01/2011";'[Classeur 1.xls]effectif'!$H$4:$S$4;0);0). Toujours le même résultat !!

Une idée ?
Merci d'avance,
Cdt,
Alex

**jfontaine** · 04/08/2011, 16h37

Est ce grave si la matrice ne contient qu'une colonne ? Car cette colonne ne devrait pas changer.

la matrice de recherche (ou plage de recherche) doit contenir toute la plage de données de ton tableau dont en colonne de gauche l'information a rechercher (soit pour un tableau contenant 12 mois => 13 colonnes)

Essai comme cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEV("Marketing";'[Classeur 1.xls]effectif'!$A$9:$S$1104;EQUIV("31/01/2011";'[Classeur 1.xls]effectif'!$A$4:$S$4;0);0)

**alex49520** · 04/08/2011, 16h43

Changements effectués, mais toujours le même problème.

**jfontaine** · 04/08/2011, 16h50

ci joint un exemple
rechercheV + equiv.xls

**alex49520** · 04/08/2011, 17h00

Voila une partie de mon fichier je n'y arrive toujours pas

**jfontaine** · 04/08/2011, 17h15

Voila, le problème se situait dans le format de date du equiv
28/02/2011 dans equiv n'étant pas considéré comme une date mais du texte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEV("Marketing - voierie ETC";A8:S19;EQUIV(DATE(2011;2;28);A4:S4;0);0)

**alex49520** · 04/08/2011, 17h21

Merci beaucoup a toi!!
A bientôt !
Cdt,
Alex

**jfontaine** · 04/08/2011, 17h27

Un peu de lecture sur le recherchev http://fauconnier.developpez.com/tut...el/recherchev/

**alex49520** · 09/08/2011, 16h29

Bonjour, bonjour,

Petit problème supplémentaire, je souhaiterais faire non pas une recherchev mais deux, est ce possible ? (voir pièce jointe)

Merci d'avance,
Cdt,
Alex

**jfontaine** · 09/08/2011, 16h56

Un beau tableau, mais aucune explication de ce que tu souhaites au final

**alex49520** · 09/08/2011, 17h12

Désolé je pensais l'avoir expliqué.
En fait, je souhaiterais faire une recherche par tata, toto et tutu et à l'intérieur de ces recherches faire une recherche par unité, quantité et total. Vois tu ce que je veux dire ?

Je souhaiterais en une formule trouver ce qui correspond en janvier à l'unité de toto par exemple, tu vois ?

Merci d'avance, encore désolé,
Alex

**jfontaine** · 09/08/2011, 22h30

Tu trouveras ci joint une solution.

1. Ajouter en colonne A les mots tata, tutu, toto devant les mots a chercher en colonne B, en prenant en couleur de police la couleur de la cellule (Par défaut blanc

2. Utiliser la formule suivante en sachant les critères se trouvent :
D19 => tutu
D20 => janvier
D21 => unité

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(DECALER(A1:A13;0;EQUIV(D20;A1:N1;0)-1);EQUIV(1;(A1:A13=D19)*(B1:B13=D21);0))

Formule matricielle a valider par CTRL + MAJ + ENTREE

rechercheV + equiv(1).xls

**alex49520** · 10/08/2011, 08h51

Merci beaucoup pour toutes ces réponses.
Je suppose donc que si les mots unité, quantité, total se trouvent dans la même colonne que toto, tutu et tata (colonne A) ça ne peut fonctionner ? Si ?

Merci d'avance,
Cdt,
Alex

**jfontaine** · 10/08/2011, 08h57

Si tu veux faire cela rien ne t’empêche de masquer la colonne A et d'ajouter les toto en colonne B au dessus d'unité.
Comme cela pas de modification de formule

**alex49520** · 10/08/2011, 09h07

Bonne idée !!
Par contre j'ai essayé d'appliquer ta formule sur un cas un peu plus complexe et j'ai en résultat #N/A :

=INDEX(DECALER('[Classeur 1.xls]total mois'!A1:A375;0;EQUIV(DATE(2011;1;31);'[Classeur 1.xls]total mois'!A1:S4;0)-1);EQUIV(1;('[Classeur 1.xls]total mois'!A1:A375=A3)*('[Classeur 1.xls]total mois'!B1:B377="Brut");0))

Vois tu où pourrait se trouver l'erreur ?

Merci de ta patience,
Cdt,
Alex

**jfontaine** · 10/08/2011, 09h21

dans ta formule, la dernière matrice va jusqu'à la ligne 377 alors que les autres vont à la ligne 375.
Toutes les matrices doivent avoir la même taille

Automatisation de formules

Excel

Discussions similaires

Partager

Partager