Discussion :

[Kalas22]

Bonjour,

J'ai un petit compte rendu à faire, avec un maquettage.

Ce que j'aimerais bien, c'est insérer une image, qu'elle ai la taille d'une cellule, et qu'au clique, POUF, sa zoom.

Est-ce possible avec excel? je n'ai rien trouver sur internet...

Sinon j'ai essayer avec un lien hypertexte, mais il m'ouvre l'image avec IE >.<'

Merci

[Arkham46]

bjr,

on peut dupliquer l'image et l'agrandir pour qu'elle remplisse la feuille.

à copier dans un module de code standard (insertion => module dans VBA) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
' Supprime les images zoomées d'une feuille
Public Sub UnZoomImage(ParentSheet As Excel.Worksheet)
Dim loShape As Excel.Shape
' Supprime toutes les formes dont le nom commence par Zoom
For Each loShape In ParentSheet.Shapes
    If loShape.Name Like "Zoom*" Then
        loShape.Delete
    End If
Next
End Sub
 
' Zoom une image, ou supprime l'image zoomée
Public Sub ZoomUnZoomImage()
Dim oImg As Excel.Shape
' Supprime toutes les images zoomées
UnZoomImage ActiveSheet
If Not Application.Caller Like "Zoom*" Then
    ' => Si clic sur miniature
    ' oImg = Shape sur laquelle on a cliqué
    Set oImg = ActiveSheet.Shapes(Application.Caller)
    ' Travail sur une image dupliquée
    With oImg.Duplicate
        ' Positionne et redimensionne l'image pour couvrir la surface visible
        .Left = ActiveWindow.VisibleRange.Left
        .Top = ActiveWindow.VisibleRange.Top
        .Width = ActiveWindow.VisibleRange.Width
        .Height = ActiveWindow.VisibleRange.Height
        ' Renomme l'image zoomée = Zoom + nom de la miniature
        .Name = "Zoom" & oImg.Name
    End With
End If
End Sub

Puis affecter à chaque image la macro ZoomUnZoomImage.

Sur clic sur une image, elle est dupliquée et cette image dupliquée est agrandie et son nom est préfixé par "Zoom" (il ne faut donc pas que le nom des miniatures commence par Zoom).
Si on clic sur l'image agrandie, la macro est exécutée et supprime l'image zoomée.

On peut aussi ajouter la suppression des image zoomée sur modification de la sélection dans la feuille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
UnZoomImage Target.Parent
End Sub

Comme ça le zoom disparaît lorsqu'on clique dans la feuille à côté de l'image.

[turbo_sophie]

j'ai crée un évènement sur clic de l'image

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
 Sub Image_Clic()
 
    Dim sNomObjet As String
 
    sNomObjet = "MonImage"
     ThisWorkbook.Sheets("MaFeuille").DrawingObjects(sNomObjet).Select
 
 If Application.Selection.Height = 100 Then
 
       With Application.Selection
        .Height = 10
        .Width = 10
    End With
 
  Else
 
     With Application.Selection
        .Height = 100
        .Width = 100
    End With
 
 End If

mais selon la taille désirée, la qualité de l'image n'est pas tip top