Discussion :

[ericdev67]

Bonjour,

J'utilise assez souvent la méthode ADO (merci au tuto de Silkyroad), mais là, j'ai un souci : il ne rapatrie pas toutes les données, et je ne comprends pas pourquoi.....Ma macro est dans un classeur ("Monclasseur"), et je dois extraire les données du classeur "Tot" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub RequeteClasseurFerme()
    Dim Cn As ADODB.Connection
    Dim Fichier As String
    Dim NomFeuille As String, texte_SQL As String
    Dim Rst As ADODB.Recordset
 
    'Définit le classeur fermé servant de base de données
    Fichier = "C:\Documents and Settings\Administrateur\Bureau\Tot.xls"
    'Nom de la feuille dans le classeur fermé
    NomFeuille = "S 2"
 
    Set Cn = New ADODB.Connection
 
    '--- Connection ---
    With Cn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Data Source=" & Fichier & _
            ";Extended Properties=Excel 8.0;"
        .Open
    End With
    '-----------------
 
 
    texte_SQL = "SELECT * FROM [" & NomFeuille & "$]"
 
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
    'Ecrit l
    Range("A2").CopyFromRecordset Rst
 
    '--- Fermeture connexion ---
    Cn.Close
    Set Cn = Nothing
 
End Sub

Je mets en pièce jointe une partie de mon fichier. Donc, quand je lance la macro, il ne récupère pas les données (enfin pas toutes) de la colonne B.

Quelqu'un pourrait me dire ce qui se passe ? et/ou pourquoi ça ne fonctionne pas ?

Merci,

A+

[Theze]

Bonsoir,

Tu as des champs vides (cellules) dans la colonne B c'est pour cela que ça ne fonctionne pas.

Hervé.

[ericdev67]

Merci Theze,

Donc, si je comprends, à partir du moment où il y a un cellule vide, la méthode ADO ne fonctionne pas ?

Je risque donc de devoir utiliser une boucle à partir de "Monclasseur" et boucler sur toutes les cellules de "Tot" pour récupérer les données .... galère.....j'espérais qu'il y ait une autre solution......

Confirme-me moi juste si j'ai bien compris...avant que je me lance dans un code.....

merci,
A+

[pgz]

Bonsoir.

Les premières lignes sont utilisées pour identifier le type du champ. Si ce travail échoue, le champ entier est ignoré et en résultat ce champ est absent du rst. C'est ton cas?
Plus bas, les vides ne posent pas de pb. Je ne sais pas combien sont ces "premières lignes".

Mais si tu n'es pas dans ce cas, ...

Cordialement,

PGZ

[Theze]

Re,

Je viens de faire des essais et là, il me retourne les valeurs des deux colonnes avec les enregistrements vides ? Teste pour voir mais fait attention de formater le moins possible ton fichier source comme par exemple les retours à la ligne dans les cellules (chose qui ne peut se faire dans Access) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
Sub Test()
 
    Dim ConnectCL As ADODB.Connection
    Dim Rs As ADODB.Recordset
    Dim Champ As ADODB.Field
    Dim Fichier As String
    Dim NomFeuille As String
 
    Fichier = "D:\Tot.xls"
 
    NomFeuille = "S 2"
 
    'ouvre la connexion
    Set ConnectCL = New ADODB.Connection
    ConnectCL.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                   "Data Source=" & Fichier & ";" & _
                   "Extended Properties=""Excel 8.0;HDR=NO;IMEX= 2;"""
 
    Set Rs = New ADODB.Recordset
 
    With Rs
 
        .CursorType = 1
        .LockType = 3
        .Open "SELECT * FROM `" & NomFeuille & "$` ", ConnectCL
 
        .MoveFirst
 
    End With
 
    ActiveSheet.Range("A1").CopyFromRecordset Rs
 
    'ferme la connexion
    ConnectCL.Close
 
 
    Set Rs = Nothing
    Set ConnectCL = Nothing
 
End Sub

Hervé.

[pgz]

Bonsoir Theze.

Attention à

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

HDR = No

car la source a une ligne de titres.
Mais si ça marche, ...

Cordialement,

PGZ

[ericdev67]

Merci Theze,
Merci PGZ,

Désolé pour le retard, mais comme je suis sur MAC, il faut que je me déconnecte, reconnecte en Win, teste, revient, etc....
Alors oui, PGZ, une fois de plus tu avais raison, si la première cellule renseignée (pas le champ) est vide tout le reste est vide, j'ai fait le test en déplaçant une date et en la mettant en B2, ça fonctionnait.

Par contre, j'ai testé ton code Theze, il ne fonctionnait pas ...

Néanmoins, en essayant de le tester, j'ai pris une de tes idées (IMEX) et je l'ai mixé avec le code initial :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub RequeteClasseurFerme()
    Dim Cn As ADODB.Connection
    Dim fichier As String
    Dim NomFeuille As String, texte_SQL As String
    Dim Rst As ADODB.Recordset
 
    'Définit le classeur fermé servant de base de données
    fichier = "C:\Documents and Settings\Administrateur\Bureau\Tot.xls"
    'Nom de la feuille dans le classeur fermé
    NomFeuille = "S 2"
 
    Set Cn = New ADODB.Connection
 
    '--- Connection ---
    With Cn
      Cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & fichier & ";" & _
        "Extended Properties=""Excel 8.0;HDR=No;IMEX=1;"";"
 
    End With
    '-----------------
 
    'Définit la requête.
    '/!\ Attention à ne pas oublier le symbole $ après le nom de la feuille.
    texte_SQL = "SELECT * FROM [" & NomFeuille & "$]"
 
    Set Rst = New ADODB.Recordset
    Set Rst = Cn.Execute(texte_SQL)
 
    'Ecrit le résultat de la requête dans la cellule A2
    Range("A1").CopyFromRecordset Rst
 
    '--- Fermeture connexion ---
    Cn.Close
    Set Cn = Nothing
 
End Sub

et.....ça fonctionne !!!!

Donc, combinaison de Hdr=No + IMEX=1, tout va béné béné

Merci à tous les 2, une fois de plus, je commence à mieux comprendre certains fonctionnements VBA

Merci et A+ pour de prochaines aventures

[Theze]

Bonsoir,

Heureux que tu es pus faire ce que tu désirais. Une petite précision :
HDR = YES ou NO; entêtes de colonnes ou non
IMEX = 1 lecture seule, 2 lecture/écriture

Hervé.

[ericdev67]

Ok, merci Theze pour les précisions

Au moins j'ai compris la signification de IMEX.....

Merci,

A+ pour de prochaines aventures

[pgz]

Bonjour.

Avec IMEX = 1, s'il y a conflit de type, c'est le type texte qui est choisi, alors que tu as des dates.
Avec HDR = No, tu considères que la première ligne c'est déjà des valeurs, alors que ce sont des titres.
Le .copyFromRecordset masque un peu les choses. Si tu ne fais rien de plus, ce n'est pas grave. Mais si tu utilises le jeu d'enregistrement tu vas avoir sur le premier enregistrement les noms des champs et non pas les valeurs.

Cordialement,

PGZ

[ericdev67]

Merci PGZ,

Lors de mes tests, j'ai fait des essais avec HDR=NO et comme j'avais des colonnes vides, j'ai essayé en mettant IMEX=1, et là, les dates apparaissaient....mais je pense que j'ai de la "chance" : le fichier d'où je rapatrie mes données, "interprète" les dates comme du texte, d'où certaines difficultés que j'ai eu à une certaine époque (http://www.developpez.net/forums/d10...es-date-vides/), donc, la combinaison fonctionne.....

Mais je te remercie pour cette alerte, car j'ai un autre fichier, qui lui, reprend le format date, donc il va falloir que j'enlève IMEX dans le code que j'utiliserai pour rapatrier ce fichier.

Merci à toi, Une fois de plus !!!

A+